[gentoo-commits] gentoo-x86 commit in net-p2p/btg: metadata.xml ChangeLog btg-1.0.0.ebuild

[Ben de Groot (yngwin)]

yngwin      09/07/02 22:55:49

  Modified:             metadata.xml ChangeLog
  Added:                btg-1.0.0.ebuild
  Log:
  Version bump, including patches and various ebuild improvements (see ChangeLog)
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  net-p2p/btg/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/btg/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/btg/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/btg/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/btg/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	12 Mar 2009 05:03:04 -0000	1.4
+++ metadata.xml	2 Jul 2009 22:55:49 -0000	1.5
@@ -4,6 +4,7 @@
   <herd>net-p2p</herd>
   <use>
     <flag name="event-callback">Enable calling a script or executable for certain events</flag>
+	<flag name="upnp">Enable support for UPnP</flag>
     <flag name="webinterface">install webBTG</flag>
   </use>
 </pkgmetadata>



1.14                 net-p2p/btg/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/btg/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/btg/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/btg/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/btg/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	7 Mar 2009 14:54:03 -0000	1.13
+++ ChangeLog	2 Jul 2009 22:55:49 -0000	1.14
@@ -1,6 +1,18 @@
 # ChangeLog for net-p2p/btg
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/btg/ChangeLog,v 1.13 2009/03/07 14:54:03 betelgeuse Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/btg/ChangeLog,v 1.14 2009/07/02 22:55:49 yngwin Exp $
+
+*btg-1.0.0 (02 Jul 2009)
+
+  02 Jul 2009; Ben de Groot <yngwin@g.o> +btg-1.0.0.ebuild,
+  +files/btg-1.0.0-gcc44.patch, +files/btg-1.0.0-gnutls-pc.patch:
+  Version bump, including patches and various ebuild improvements:
+  - patch to use pkgconfig to build with >=gnutls-2.8 (bug 275850)
+  - patch to fix compiling with gcc-4.4 by adding some missing C headers
+  - incorporate some changes from bug 231105 (curl useflag, dep updates)
+  - add upnp useflag, upnp is offered by >=rb_libtorrent-0.14
+  - migrate to eapi-2
+  - expand a bit on description
 
   07 Mar 2009; Petteri Räty <betelgeuse@g.o> -btg-0.9.6-r1.ebuild:
   Remove old version.



1.1                  net-p2p/btg/btg-1.0.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/btg/btg-1.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/btg/btg-1.0.0.ebuild?rev=1.1&content-type=text/plain

Index: btg-1.0.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/btg/btg-1.0.0.ebuild,v 1.1 2009/07/02 22:55:49 yngwin Exp $

EAPI="2"
inherit eutils autotools

MY_P="${P/_/-}"

DESCRIPTION="A bittorrent client using rb_libtorrent with a daemon/client model"
HOMEPAGE="http://btg.berlios.de/"
SRC_URI="mirror://berlios/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="curl debug doc event-callback gtk minimal ncurses session test upnp webinterface"

RDEPEND=">=dev-libs/boost-1.35
	dev-libs/expat
	dev-libs/libgcrypt
	dev-libs/libgpg-error
	dev-libs/libtasn1
	net-libs/gnutls
	net-libs/rb_libtorrent
	curl? ( net-misc/curl )
	gtk? ( dev-cpp/gtkmm:2.4
		dev-libs/libsigc++:2
		sci-libs/plotmm
		x11-libs/pango )
	!minimal? ( dev-util/dialog )
	ncurses? ( sys-libs/ncurses )
	test? ( dev-util/cppunit )
	upnp? ( >=net-libs/rb_libtorrent-0.14 )
	webinterface? ( dev-lang/php:5[xml,zlib] virtual/httpd-cgi )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

S="${WORKDIR}/${P%_*}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gnutls-pc.patch  # bug 275850
	epatch "${FILESDIR}"/${P}-gcc44.patch
	eautoreconf
}

src_configure() {
	econf LIBS="-lboost_thread -lboost_date_time" \
		$(use_enable curl url) \
		$(use_enable debug) \
		$(use_enable gtk gui) \
		$(use_enable ncurses cli) \
		$(use_enable event-callback) \
		$(use_enable session session-saving) \
		$(use_enable test unittest) \
		$(use_enable upnp) \
		$(use_enable webinterface www) \
		$(use_enable !minimal command-list) \
		$(use_enable !minimal btg-config) \
		--disable-dependency-tracking
}

src_install() {
	emake DESTDIR="${D}" install || die 'emake install failed'

	dodoc AUTHORS ChangeLog README TODO

	newinitd "${FILESDIR}/btgd-init" ${PN}
	newconfd "${FILESDIR}/btgd-confd" ${PN}

	use gtk && make_desktop_entry btgui "BTG GUI Client" btg "Network;P2P"
}

pkg_postinst() {
	enewgroup p2p
	enewuser p2p -1 -1 /home/p2p p2p

	echo
	elog "BTG needs a daemon.ini and client.ini. To create them run btg-config and"
	elog "put them in the home of the user running btg (/home/p2p/.btg by default)"
	echo
}