[gentoo-commits] repo/gentoo:master commit in: media-radio/tucnak/

[Thomas Beierlein]

commit:     1c7557a43b495e76f3b38a85383798c729a60e1f
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 28 16:27:19 2020 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Fri Aug 28 16:27:19 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1c7557a4

media-radio/tucnak: Version bump

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 media-radio/tucnak/Manifest           |  1 +
 media-radio/tucnak/tucnak-4.22.ebuild | 68 +++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/media-radio/tucnak/Manifest b/media-radio/tucnak/Manifest
index 3a52761933b..c5438ee5672 100644
--- a/media-radio/tucnak/Manifest
+++ b/media-radio/tucnak/Manifest
@@ -1 +1,2 @@
 DIST tucnak-4.21.tar.gz 3545924 BLAKE2B dabc9647e4fde5c8c3b3e9b2ee5f072ce6e85138c6a45f635c05dcf47763a39e191a6ac3d97e71b79d3913915126261f565f8e273cd257731e04bc5ab7956aab SHA512 73fe2e92a0db3a8e152cfc25bbaefdeec6fd7f11223d02eae6c1ac5526c02404e89ecd4f2f715e7fda1d72fd872fc240694ce674d57a95c03417cf59dbd6532c
+DIST tucnak-4.22.tar.gz 3547159 BLAKE2B 4a08bc0f7cfa5bbef6d367e7d5780707b6500bf35938ba38bab779ab68e379dd48f6f08146c042e10f2fe4eb7c6d807fef4a8c64ab4ddd8d4fff25f9a0765436 SHA512 d4ec3707137e7a79ede5722806f30f6442988b6cf79e15578978344d6f3dc978a4ef7bfff215458a65d7436e6344e7288c911e499ad3c03b9edb754cd390e2fc

diff --git a/media-radio/tucnak/tucnak-4.22.ebuild b/media-radio/tucnak/tucnak-4.22.ebuild
new file mode 100644
index 00000000000..b4c1192a2e4
--- /dev/null
+++ b/media-radio/tucnak/tucnak-4.22.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools flag-o-matic multilib
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/libzia
+	media-libs/libsndfile
+	>=media-libs/libsdl-1.2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}