[gentoo-commits] repo/gentoo:master commit in: dev-util/sysdig-kmod/

[Michał Górny]

commit:     8e76051df35c1c18b163a02a466222bf5030692f
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  3 14:56:00 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Oct  3 17:00:38 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e76051d

dev-util/sysdig-kmod: Bump to 0.27.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-util/sysdig-kmod/Manifest                  |  1 +
 dev-util/sysdig-kmod/sysdig-kmod-0.27.1.ebuild | 47 ++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)

diff --git a/dev-util/sysdig-kmod/Manifest b/dev-util/sysdig-kmod/Manifest
index 3581d465663..2e5405a0486 100644
--- a/dev-util/sysdig-kmod/Manifest
+++ b/dev-util/sysdig-kmod/Manifest
@@ -1 +1,2 @@
 DIST sysdig-0.27.0.tar.gz 933094 BLAKE2B e412bd2a35a62b580344a49e2deee85764710f91327cd63b42913dc361ee96943ffe51b90ee745c420454f0a4be455606d486a91ab3e103d7e396f04dc3f1ff4 SHA512 102150cc641165a6c18ce71e3c6148dc10700f614fec7e1909c29172e3cce02dfa16af56aabdcd420499d0aa89f90fee8f26d92a250b0a521d1b9d416c6a678f
+DIST sysdig-0.27.1.tar.gz 936415 BLAKE2B f4c15e3a2d4b974c5eafc8374f927dd82f123c05cc1976d04b08e77e1a7c0ff53f37c4e2c0022b7073fcc936310daf76ca3c3611141799ae4f51991bc6f3a0a3 SHA512 690f012c7db0a75ec2eb78fae17aae0f422aa1db0d4c2b15c4a09153fd2f60bd3c00d62238976fdcff2a906d87b2e34b81d02c0c78ad2684a1d6016a9988eb08

diff --git a/dev-util/sysdig-kmod/sysdig-kmod-0.27.1.ebuild b/dev-util/sysdig-kmod/sysdig-kmod-0.27.1.ebuild
new file mode 100644
index 00000000000..ba7201399d5
--- /dev/null
+++ b/dev-util/sysdig-kmod/sysdig-kmod-0.27.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake linux-mod
+
+MY_P=${P/-kmod}
+DESCRIPTION="Kernel module for dev-util/sysdig"
+HOMEPAGE="https://sysdig.com/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="|| ( MIT GPL-2 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="!<=dev-util/sysdig-0.26.4[modules]"
+
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+pkg_pretend() {
+	linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e '/USE_BUNDLED_DEPS/,$d' CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+	)
+
+	cmake_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${BUILD_DIR}/driver/src:)"
+	BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
+	BUILD_TARGETS="all"
+}