[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     8a43cf909f5cffea94462f49fb97a31fa71d112b
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 14 09:56:14 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Oct 14 09:56:14 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8a43cf90

sys-kernel/gentoo-kernel-bin: add 5.14.12-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.14.12-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index e81fd9f5987..9559266d67d 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -64,6 +64,7 @@ DIST gentoo-kernel-5.14.11-1.amd64.xpak 68067146 BLAKE2B 8ce01c1f9003c298f262c23
 DIST gentoo-kernel-5.14.11-1.arm64.xpak 63292538 BLAKE2B a4e485ebd2c1e757fabf159d676b52dbdb8be4ff3613ef1c4be4dff1cdcc928fbcaa2e7b223ed906b76d6eac559930a8da9b48c25b927b7d82ca5c5eeb0a31fe SHA512 fd2a6c74f35d9ac4843be51a8cb015af65cff36b7479b09e861fc5eae5333327792e8b4c013809e2880c7386ff00221fff02647b059842ae0b178b585c9f3ca7
 DIST gentoo-kernel-5.14.11-1.x86.xpak 59165591 BLAKE2B 870935f0eddc88cb23aac651f92663a963e148a3c526bd30daa17ed3b63175c16553e8a8fc7edb7a728859d436199a12cf4bc230490805b0342de1a4a0033e39 SHA512 0ddd7b81473cb552ffd1bb20fee14191cff033145fac4ce1d6688a674db2e3f401c851021c2d39fdb05ef1b034a210adae8196c718220fc8d38508bfac1102c8
 DIST gentoo-kernel-5.14.12-1.amd64.xpak 68076172 BLAKE2B cbe6725fbbd725a2effedf4f17f6d1a91e5ebc37e355b378d4e5d4075b3d36200c3d7c0c5e0e92300c0862a49362bf182dcf23b2cb6c58a15579e4120a28978f SHA512 3c1af75b0c4215d30563b72f6e363f9d1631f2b36686740720b52c5468f59c3ddfb500cdfc95d9fab0333e7381b8fa81a4e4d45e401374f6765906feb6c41847
+DIST gentoo-kernel-5.14.12-1.arm64.xpak 63328712 BLAKE2B 82d66c33182546f1ad2b0285fdad24d6f378616a6557a73a2fe3669619ffdf7e091fce2c43764c921be852415e782799e729229dca6d52f0c7f722726bbb7b6a SHA512 7ad95019bc3a80764c94ce57f432a46f6b69dd8b0684fca39e6b86ed7f67f4d1264261ffd7349b1a3793df7e7b6c8a0ce5a2e56ce53bf92565d2e19b7447b9e2
 DIST gentoo-kernel-5.14.12-1.x86.xpak 59179955 BLAKE2B b94956dae8d21e1a538252f402045d99ca9b464810d8df51cf3f86c4a29f7c21512fd944086711dd5e432245259233dedc068e1d1bd9e8a5de74824396a67b66 SHA512 227bce0cc990d9943a4310c5edccda99acfb71e69fa414a800a138e0c16ceb780e61fb68529680a93b72d64851914fdbb4cbff7ad70f8dafdd88d8ca82e3dccb
 DIST gentoo-kernel-5.14.7-1.amd64.xpak 68031586 BLAKE2B 7cc01200f01a93daf5f0c84b09e066474dc5dcef76ddadf5e43843a3bb8a69710134ee9546cbfc6da0149b96e480d59cc0ceb610608c7e6710dccbb9e9e185f2 SHA512 595ce0155ef9df5809d7c27ee310d3978bde477e6778468f467c9f07a60c43dd7ce6e39320d3e298639f01c18cfed5811de480d0afd884586d13f434c533fe6b
 DIST gentoo-kernel-5.14.7-1.arm64.xpak 63383693 BLAKE2B d8780cdd6306f36530d82b9a5b6a74e1d2caf9c4e9db31d6816020bc9415fe92891e418dd08f89628f3d36189c84f97c10b570091c2d1a94a494f37a21286706 SHA512 90ef111ef0ef68dd362c458c9e6ea15959713118787ebd8c68492bd204da83a212e5def456fd550c3f175565c262581855599adeb34692c65f54c2f2d7f1d06c

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.12-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.12-r1.ebuild
new file mode 100644
index 00000000000..c4534b7e4c4
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.12-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+		-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}