[gentoo-commits] gentoo-x86 commit in net-misc/wget: ChangeLog wget-1.12-r2.ebuild

[Mike Frysinger (vapier)]

vapier      10/08/21 22:18:17

  Modified:             ChangeLog
  Added:                wget-1.12-r2.ebuild
  Log:
  Add fix from upstream for CVE-2010-2252 #329941 by Stefan Behte.  Tweak by Sergei Trofimovich for IPv6 behavor in SNI patch #333839.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.123                net-misc/wget/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wget/ChangeLog?rev=1.123&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wget/ChangeLog?rev=1.123&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wget/ChangeLog?r1=1.122&r2=1.123

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/wget/ChangeLog,v
retrieving revision 1.122
retrieving revision 1.123
diff -u -r1.122 -r1.123
--- ChangeLog	14 Feb 2010 00:43:08 -0000	1.122
+++ ChangeLog	21 Aug 2010 22:18:17 -0000	1.123
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/wget
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/wget/ChangeLog,v 1.122 2010/02/14 00:43:08 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/wget/ChangeLog,v 1.123 2010/08/21 22:18:17 vapier Exp $
+
+*wget-1.12-r2 (21 Aug 2010)
+
+  21 Aug 2010; Mike Frysinger <vapier@g.o> +wget-1.12-r2.ebuild,
+  +files/wget-1.12-CVE-2010-2252.patch, files/wget-1.12-sni.patch:
+  Add fix from upstream for CVE-2010-2252 #329941 by Stefan Behte. Tweak by
+  Sergei Trofimovich for IPv6 behavor in SNI patch #333839.
 
   14 Feb 2010; Mike Frysinger <vapier@g.o> wget-1.12-r1.ebuild:
   Upgrade to EAPI=2 so we can set +ssl in IUSE #304887 by Kerin Millar.



1.1                  net-misc/wget/wget-1.12-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wget/wget-1.12-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wget/wget-1.12-r2.ebuild?rev=1.1&content-type=text/plain

Index: wget-1.12-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/wget/wget-1.12-r2.ebuild,v 1.1 2010/08/21 22:18:17 vapier Exp $

EAPI="2"

inherit eutils flag-o-matic

DESCRIPTION="Network utility to retrieve files from the WWW"
HOMEPAGE="http://www.gnu.org/software/wget/"
SRC_URI="mirror://gnu/wget/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="debug idn ipv6 nls ntlm +ssl static"

RDEPEND="idn? ( net-dns/libidn )
	ssl? ( >=dev-libs/openssl-0.9.6b )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

pkg_setup() {
	if ! use ssl && use ntlm ; then
		elog "USE=ntlm requires USE=ssl, so disabling ntlm support due to USE=-ssl"
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-CVE-2010-2252.patch #329941
	epatch "${FILESDIR}"/${PN}-1.12-linking.patch
	epatch "${FILESDIR}"/${PN}-1.12-sni.patch #301312
	epatch "${FILESDIR}"/${P}-debug-tests.patch #286173
}

src_configure() {
	# openssl-0.9.8 now builds with -pthread on the BSD's
	use elibc_FreeBSD && use ssl && append-ldflags -pthread

	use static && append-ldflags -static
	econf \
		--disable-rpath \
		$(use_with ssl) $(use_enable ssl opie) $(use_enable ssl digest) \
		$(use_enable idn iri) \
		$(use_enable ipv6) \
		$(use_enable nls) \
		$(use ssl && use_enable ntlm) \
		$(use_enable debug)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog* MAILING-LIST NEWS README
	dodoc doc/sample.wgetrc

	use ipv6 && cat "${FILESDIR}"/wgetrc-ipv6 >> "${D}"/etc/wgetrc

	sed -i \
		-e 's:/usr/local/etc:/etc:g' \
		"${D}"/etc/wgetrc \
		"${D}"/usr/share/man/man1/wget.1 \
		"${D}"/usr/share/info/wget.info
}

pkg_preinst() {
	ewarn "The /etc/wget/wgetrc file has been relocated to /etc/wgetrc"
	if [[ -e ${ROOT}/etc/wget/wgetrc ]] ; then
		if [[ -e ${ROOT}/etc/wgetrc ]] ; then
			ewarn "You have both /etc/wget/wgetrc and /etc/wgetrc ... you should delete the former"
		else
			einfo "Moving /etc/wget/wgetrc to /etc/wgetrc for you"
			mv "${ROOT}"/etc/wget/wgetrc "${ROOT}"/etc/wgetrc
			rmdir "${ROOT}"/etc/wget 2>/dev/null
		fi
	fi
}