Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Tomas Chvatal (scarabeus)" <scarabeus@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in x11-base/xorg-server: ChangeLog xorg-server-1.9.0-r1.ebuild xorg-server-1.9.0.ebuild
Date: Tue, 28 Sep 2010 12:43:27
Message-Id: 20100928124319.2700420051@flycatcher.gentoo.org
1 scarabeus 10/09/28 12:43:19
2
3 Modified: ChangeLog
4 Added: xorg-server-1.9.0-r1.ebuild
5 Removed: xorg-server-1.9.0.ebuild
6 Log:
7 Revision bump to fix initscript, thx to Michal Gorny (bug #338837). Apply patch to fix compilation issues, thx to Alexandre Rostovtsev (bug #337020). Update deps per bug #338519.
8
9 (Portage version: 2.2_rc87/cvs/Linux x86_64)
10
11 Revision Changes Path
12 1.536 x11-base/xorg-server/ChangeLog
13
14 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-base/xorg-server/ChangeLog?rev=1.536&view=markup
15 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-base/xorg-server/ChangeLog?rev=1.536&content-type=text/plain
16 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-base/xorg-server/ChangeLog?r1=1.535&r2=1.536
17
18 Index: ChangeLog
19 ===================================================================
20 RCS file: /var/cvsroot/gentoo-x86/x11-base/xorg-server/ChangeLog,v
21 retrieving revision 1.535
22 retrieving revision 1.536
23 diff -u -r1.535 -r1.536
24 --- ChangeLog 26 Sep 2010 19:03:05 -0000 1.535
25 +++ ChangeLog 28 Sep 2010 12:43:19 -0000 1.536
26 @@ -1,6 +1,15 @@
27 # ChangeLog for x11-base/xorg-server
28 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
29 -# $Header: /var/cvsroot/gentoo-x86/x11-base/xorg-server/ChangeLog,v 1.535 2010/09/26 19:03:05 klausman Exp $
30 +# $Header: /var/cvsroot/gentoo-x86/x11-base/xorg-server/ChangeLog,v 1.536 2010/09/28 12:43:19 scarabeus Exp $
31 +
32 +*xorg-server-1.9.0-r1 (28 Sep 2010)
33 +
34 + 28 Sep 2010; Tomáš Chvátal <scarabeus@g.o>
35 + +files/1.9.0-fix-VbeModeInfoBlock-memcpy.patch, -xorg-server-1.9.0.ebuild,
36 + +xorg-server-1.9.0-r1.ebuild, -files/xdm.initd-2, +files/xdm.initd-3:
37 + Revision bump to fix initscript, thx to Michal Gorny (bug #338837). Apply
38 + patch to fix compilation issues, thx to Alexandre Rostovtsev (bug
39 + #337020). Update deps per bug #338519.
40
41 26 Sep 2010; Tobias Klausmann <klausman@g.o>
42 xorg-server-1.7.7-r1.ebuild:
43
44
45
46 1.1 x11-base/xorg-server/xorg-server-1.9.0-r1.ebuild
47
48 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-base/xorg-server/xorg-server-1.9.0-r1.ebuild?rev=1.1&view=markup
49 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-base/xorg-server/xorg-server-1.9.0-r1.ebuild?rev=1.1&content-type=text/plain
50
51 Index: xorg-server-1.9.0-r1.ebuild
52 ===================================================================
53 # Copyright 1999-2010 Gentoo Foundation
54 # Distributed under the terms of the GNU General Public License v2
55 # $Header: /var/cvsroot/gentoo-x86/x11-base/xorg-server/xorg-server-1.9.0-r1.ebuild,v 1.1 2010/09/28 12:43:19 scarabeus Exp $
56
57 EAPI=3
58 inherit xorg-2 multilib versionator
59
60 EGIT_REPO_URI="git://anongit.freedesktop.org/git/xorg/xserver"
61
62 OPENGL_DIR="xorg-x11"
63
64 DESCRIPTION="X.Org X servers"
65 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
66
67 IUSE_SERVERS="dmx kdrive xorg"
68 IUSE="${IUSE_SERVERS} doc ipv6 minimal nptl tslib +udev"
69 RDEPEND=">=app-admin/eselect-opengl-1.0.8
70 dev-libs/openssl
71 media-libs/freetype
72 >=x11-apps/iceauth-1.0.2
73 >=x11-apps/rgb-1.0.3
74 >=x11-apps/xauth-1.0.3
75 x11-apps/xkbcomp
76 >=x11-libs/libpciaccess-0.10.3
77 >=x11-libs/libXau-1.0.4
78 >=x11-libs/libXdmcp-1.0.2
79 >=x11-libs/libXfont-1.4.2
80 >=x11-libs/libxkbfile-1.0.4
81 >=x11-libs/pixman-0.15.20
82 >=x11-libs/xtrans-1.2.2
83 >=x11-misc/xbitmaps-1.0.1
84 >=x11-misc/xkeyboard-config-1.4
85 dmx? (
86 x11-libs/libXt
87 >=x11-libs/libdmx-1.0.99.1
88 >=x11-libs/libX11-1.1.5
89 >=x11-libs/libXaw-1.0.4
90 >=x11-libs/libXext-1.0.5
91 >=x11-libs/libXfixes-4.0.3
92 >=x11-libs/libXi-1.2.99.1
93 >=x11-libs/libXmu-1.0.3
94 >=x11-libs/libXres-1.0.3
95 >=x11-libs/libXtst-1.0.3
96 )
97 kdrive? (
98 >=x11-libs/libXext-1.0.5
99 x11-libs/libXv
100 )
101 !minimal? (
102 >=x11-libs/libX11-1.1.5
103 >=x11-libs/libXext-1.0.5
104 >=media-libs/mesa-7.8_rc[nptl=]
105 )
106 tslib? ( >=x11-libs/tslib-1.0 x11-proto/xcalibrateproto )
107 udev? ( >=sys-fs/udev-150 )"
108
109 DEPEND="${RDEPEND}
110 sys-devel/flex
111 >=x11-proto/bigreqsproto-1.1.0
112 >=x11-proto/compositeproto-0.4
113 >=x11-proto/damageproto-1.1
114 >=x11-proto/fixesproto-4.1
115 >=x11-proto/fontsproto-2.0.2
116 >=x11-proto/glproto-1.4.11
117 >=x11-proto/inputproto-1.9.99.902
118 >=x11-proto/kbproto-1.0.3
119 >=x11-proto/randrproto-1.2.99.3
120 >=x11-proto/recordproto-1.13.99.1
121 >=x11-proto/renderproto-0.11
122 >=x11-proto/resourceproto-1.0.2
123 >=x11-proto/scrnsaverproto-1.1
124 >=x11-proto/trapproto-3.4.3
125 >=x11-proto/videoproto-2.2.2
126 >=x11-proto/xcmiscproto-1.2.0
127 >=x11-proto/xextproto-7.0.99.3
128 >=x11-proto/xf86dgaproto-2.0.99.1
129 >=x11-proto/xf86rushproto-1.1.2
130 >=x11-proto/xf86vidmodeproto-2.2.99.1
131 >=x11-proto/xineramaproto-1.1.3
132 >=x11-proto/xproto-7.0.17
133 dmx? ( >=x11-proto/dmxproto-2.2.99.1 )
134 doc? (
135 >=app-doc/doxygen-1.6.1
136 app-text/xmlto
137 )
138 !minimal? (
139 >=x11-proto/xf86driproto-2.1.0
140 >=x11-proto/dri2proto-2.3
141 >=x11-libs/libdrm-2.4.21
142 )"
143
144 PDEPEND="
145 >=x11-apps/xinit-1.2.1-r1
146 xorg? ( >=x11-base/xorg-drivers-$(get_version_component_range 1-2) )"
147
148 EPATCH_FORCE="yes"
149 EPATCH_SUFFIX="patch"
150
151 # These have been sent upstream
152 #UPSTREAMED_PATCHES=(
153 # "${WORKDIR}/patches/"
154 # )
155
156 PATCHES=(
157 "${UPSTREAMED_PATCHES[@]}"
158 "${FILESDIR}"/${PN}-disable-acpi.patch
159 "${FILESDIR}"/${PN}-1.9-nouveau-default.patch
160 "${FILESDIR}"/1.7.5.902-fix-tslib-1.0-check.patch
161 "${FILESDIR}"/1.9.0-fix-VbeModeInfoBlock-memcpy.patch
162 )
163
164 pkg_setup() {
165 xorg-2_pkg_setup
166
167 use minimal || ensure_a_server_is_building
168
169 # localstatedir is used for the log location; we need to override the default
170 # from ebuild.sh
171 # sysconfdir is used for the xorg.conf location; same applies
172 # --enable-install-setuid needed because sparcs default off
173 # NOTE: fop is used for doc generating ; and i have no idea if gentoo
174 # package it somewhere
175 CONFIGURE_OPTIONS="
176 $(use_enable ipv6)
177 $(use_enable dmx)
178 $(use_enable kdrive)
179 $(use_enable kdrive kdrive-kbd)
180 $(use_enable kdrive kdrive-mouse)
181 $(use_enable kdrive kdrive-evdev)
182 $(use_enable tslib)
183 $(use_enable tslib xcalibrate)
184 $(use_enable !minimal xvfb)
185 $(use_enable !minimal xnest)
186 $(use_enable !minimal record)
187 $(use_enable !minimal xfree86-utils)
188 $(use_enable !minimal install-libxf86config)
189 $(use_enable !minimal dri)
190 $(use_enable !minimal dri2)
191 $(use_enable !minimal glx)
192 $(use_enable xorg)
193 $(use_enable nptl glx-tls)
194 $(use_enable udev config-udev)
195 $(use_with doc doxygen)
196 $(use_with doc xmlto)
197 --sysconfdir=/etc/X11
198 --localstatedir=/var
199 --enable-install-setuid
200 --with-fontrootdir=/usr/share/fonts
201 --with-xkb-output=/var/lib/xkb
202 --disable-config-hal
203 --without-dtrace
204 --without-fop
205 --with-os-vendor=Gentoo
206 ${conf_opts}"
207
208 # Xorg-server requires includes from OS mesa which are not visible for
209 # users of binary drivers.
210 # Due to the limitations of CONFIGURE_OPTIONS, we have to export this
211 mkdir -p "${T}/mesa-symlinks/GL"
212 for i in gl glx glxmd glxproto glxtokens; do
213 ln -s "${EROOT}usr/$(get_libdir)/opengl/xorg-x11/include/$i.h" "${T}/mesa-symlinks/GL/$i.h" || die
214 done
215 for i in glext glxext; do
216 ln -s "${EROOT}usr/$(get_libdir)/opengl/global/include/$i.h" "${T}/mesa-symlinks/GL/$i.h" || die
217 done
218 append-cppflags "-I${T}/mesa-symlinks"
219
220 # (#121394) Causes window corruption
221 filter-flags -fweb
222
223 # Incompatible with GCC 3.x SSP on x86, bug #244352
224 if use x86 ; then
225 if [[ $(gcc-major-version) -lt 4 ]]; then
226 filter-flags -fstack-protector
227 fi
228 fi
229
230 # Incompatible with GCC 3.x CPP, bug #314615
231 if [[ $(gcc-major-version) -lt 4 ]]; then
232 ewarn "GCC 3.x C preprocessor may cause build failures. Use GCC 4.x"
233 ewarn "or set CPP=cpp-4.3.4 (replace with the actual installed version)"
234 fi
235
236 # detect if we should inform user about ebuild breakage
237 if ! has_version "x11-base/xorg-server" ||
238 has_version "<x11-base/xorg-server-$(get_version_component_range 1-2)"; then
239 INFO="yes"
240 fi
241 }
242
243 src_install() {
244 xorg-2_src_install
245
246 dynamic_libgl_install
247
248 server_based_install
249
250 if ! use minimal && use xorg; then
251 # Install xorg.conf.example into docs
252 dodoc hw/xfree86/xorg.conf.example \
253 || die "couldn't install xorg.conf.example"
254 fi
255
256 newinitd "${FILESDIR}"/xdm.initd-2 xdm || die "initd file install failed"
257 newconfd "${FILESDIR}"/xdm.confd-3 xdm || die
258
259 # install the @x11-module-rebuild set for Portage
260 insinto /usr/share/portage/config/sets
261 newins "${FILESDIR}"/xorg-sets.conf xorg.conf || die
262 }
263
264 pkg_postinst() {
265 # sets up libGL and DRI2 symlinks if needed (ie, on a fresh install)
266 eselect opengl set --use-old xorg-x11
267
268 if [[ ${INFO} = yes ]]; then
269 einfo "You should consider reading upgrade guide for this release:"
270 einfo " http://www.gentoo.org/proj/en/desktop/x/x11/xorg-server-$(get_version_component_range 1-2)-upgrade-guide.xml"
271 echo
272 ewarn "You must rebuild all drivers if upgrading from <xorg-server-$(get_version_component_range 1-2)"
273 ewarn "because the ABI changed. If you cannot start X because"
274 ewarn "of module version mismatch errors, this is your problem."
275
276 echo
277 ewarn "You can generate a list of all installed packages in the x11-drivers"
278 ewarn "category using this command:"
279 ewarn " emerge portage-utils; qlist -I -C x11-drivers/"
280 fi
281 }
282
283 pkg_postrm() {
284 # Get rid of module dir to ensure opengl-update works properly
285 if ! has_version x11-base/xorg-server; then
286 if [[ -e ${ROOT}/usr/$(get_libdir)/xorg/modules ]]; then
287 rm -rf "${ROOT}"/usr/$(get_libdir)/xorg/modules
288 fi
289 fi
290 }
291
292 dynamic_libgl_install() {
293 # next section is to setup the dynamic libGL stuff
294 ebegin "Moving GL files for dynamic switching"
295 dodir /usr/$(get_libdir)/opengl/${OPENGL_DIR}/extensions
296 local x=""
297 for x in "${D}"/usr/$(get_libdir)/xorg/modules/extensions/lib{glx,dri,dri2}*; do
298 if [ -f ${x} -o -L ${x} ]; then
299 mv -f ${x} "${D}"/usr/$(get_libdir)/opengl/${OPENGL_DIR}/extensions
300 fi
301 done
302 eend 0
303 }
304
305 server_based_install() {
306 if ! use xorg; then
307 rm "${D}"/usr/share/man/man1/Xserver.1x \
308 "${D}"/usr/$(get_libdir)/xserver/SecurityPolicy \
309 "${D}"/usr/$(get_libdir)/pkgconfig/xorg-server.pc \
310 "${D}"/usr/share/man/man1/Xserver.1x
311 fi
312 }
313
314 ensure_a_server_is_building() {
315 for server in ${IUSE_SERVERS}; do
316 use ${server} && return;
317 done
318 eerror "You need to specify at least one server to build."
319 eerror "Valid servers are: ${IUSE_SERVERS}."
320 die "No servers were specified to build."
321 }
Report Message
Find on MARC Find on Google Groups