[gentoo-commits] gentoo-x86 commit in kde-base/kdm: ChangeLog kdm-4.0.1.ebuild

[Wulf Krueger (philantrop)]

philantrop    08/02/07 00:12:23

  Modified:             ChangeLog
  Added:                kdm-4.0.1.ebuild
  Log:
  Version bump to KDE 4.0.1.
  (Portage version: 2.1.4.1)

Revision  Changes    Path
1.123                kde-base/kdm/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/ChangeLog?rev=1.123&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/ChangeLog?rev=1.123&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/ChangeLog?r1=1.122&r2=1.123

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kdm/ChangeLog,v
retrieving revision 1.122
retrieving revision 1.123
diff -u -r1.122 -r1.123
--- ChangeLog	31 Jan 2008 15:31:58 -0000	1.122
+++ ChangeLog	7 Feb 2008 00:12:22 -0000	1.123
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kdm
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdm/ChangeLog,v 1.122 2008/01/31 15:31:58 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdm/ChangeLog,v 1.123 2008/02/07 00:12:22 philantrop Exp $
+
+*kdm-4.0.1 (06 Feb 2008)
+
+  06 Feb 2008; Wulf C. Krueger <philantrop@g.o>
+  +files/kdebase-4.0.1-pam-optional.patch, +kdm-4.0.1.ebuild:
+  Version bump to KDE 4.0.1.
 
   31 Jan 2008; Brent Baude <ranger@g.o> kdm-3.5.8-r1.ebuild:
   Marking kdm-3.5.8-r1 ppc for bug 207634



1.1                  kde-base/kdm/kdm-4.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/kdm-4.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/kdm-4.0.1.ebuild?rev=1.1&content-type=text/plain

Index: kdm-4.0.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kdm/kdm-4.0.1.ebuild,v 1.1 2008/02/07 00:12:22 philantrop Exp $

EAPI="1"

KMNAME=kdebase-workspace
inherit kde4-meta

DESCRIPTION="KDE login manager, similar to xdm and gdm"
KEYWORDS="~amd64 ~x86"
IUSE="debug htmlhandbook kerberos pam"

DEPEND="
	x11-libs/libXau
	x11-libs/libXdmcp
	x11-libs/libXtst
	kerberos? ( virtual/krb5 )
	pam? ( >=kde-base/kcheckpass-${PV}:${SLOT}
		sys-libs/pam )"
RDEPEND="${DEPEND}
	>=kde-base/kdepasswd-${PV}:${SLOT}
	>=x11-apps/xinit-1.0.5-r2
	x11-apps/xmessage"

KMEXTRACTONLY="
	kcontrol/background/
	kcontrol/kdm/
	kdm/frontend/sessions"
# kde-base/kdebase-startkde installs the xession entry, so only extract here
KMEXTRA="libs/kdm/"

# Disable creating dirs in the live file system.
PATCHES="${FILESDIR}/kdebase-${PV}-pam-optional.patch"

src_compile() {
	mycmakeargs="${mycmakeargs}
		$(use kerberos && echo "-DKDE4_KRB5AUTH=ON" || echo "-DKDE4_KRB5AUTH=OFF")
		$(cmake-utils_use_with pam PAM)"

	kde4-meta_src_compile
}

src_install() {
	export GENKDMCONF_FLAGS="--no-old --no-backup"

	kde4-meta_src_install

	# Customize the kdmrc configuration
	sed -i -e "s:^.*SessionsDirs=.*$:#&\nSessionsDirs=/usr/share/xsessions:" \
		"${D}"/${PREFIX}/share/config/kdm/kdmrc \
		|| die "Failed to set SessionsDirs correctly."
}

pkg_postinst() {
	# Set the default kdm face icon if it's not already set by the system admin
	# because this is user-overrideable in that way, it's not in src_install
	if [[ ! -e "${ROOT}${KDEDIR}/share/apps/kdm/faces/.default.face.icon" ]];	then
		mkdir -p "${ROOT}${KDEDIR}/share/apps/kdm/faces"
		cp "${ROOT}${KDEDIR}/share/apps/kdm/pics/users/default1.png" \
			"${ROOT}${KDEDIR}/share/apps/kdm/faces/.default.face.icon"
	fi
	if [[ ! -e "${ROOT}${KDEDIR}/share/apps/kdm/faces/root.face.icon" ]]; then
		mkdir -p "${ROOT}${KDEDIR}/share/apps/kdm/faces"
		cp "${ROOT}${KDEDIR}/share/apps/kdm/pics/users/root1.png" \
			"${ROOT}${KDEDIR}/share/apps/kdm/faces/root.face.icon"
	fi
}



-- 
gentoo-commits@l.g.o mailing list