[gentoo-commits] repo/gentoo:master commit in: dev-python/doit/

[Sam James]

commit:     1e77158c0ccfec4f005ee9955e54b3fb23f26c70
Author:     Azamat H. Hackimov <azamat.hackimov <AT> gmail <DOT> com>
AuthorDate: Tue Sep  8 19:46:02 2020 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Sep 17 20:22:17 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1e77158c

dev-python/doit: update to 0.33.1

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Azamat H. Hackimov <azamat.hackimov <AT> gmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/doit/Manifest           |  1 +
 dev-python/doit/doit-0.33.1.ebuild | 49 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/dev-python/doit/Manifest b/dev-python/doit/Manifest
index eacb778f78b..92bee65c44e 100644
--- a/dev-python/doit/Manifest
+++ b/dev-python/doit/Manifest
@@ -1 +1,2 @@
 DIST doit-0.32.0.tar.gz 1437939 BLAKE2B 39134341582cd964630a1667c78b0e44eeb32406a06e3567123b820fb61cbee0f6a7c8879a84eed750860a365aa4c792e461bb1534c66e4f20a6289522dc8183 SHA512 d5c28a0c6a38648aeef58027b2246fc26360e133e91933f2244bd484f70d6d26110acbfec19c74d53c796e0bbae07a4bf6d76542d45e8b1a6b503c186bf2a68a
+DIST doit-0.33.1.tar.gz 1436620 BLAKE2B be294246447d36011274d57b5300b4451847751f228622bcd5a45f91367371ed5dd9c40a2476e558be8137b16fefda4bf6f1795108d0c982990abc62db5560e6 SHA512 852efa3b770ec5de7def1fad1167b8cdce1de7435b2ba5e4af43a84c84df0cbf960d8d5c4c9f526f303d19c7536f745c2c7700daaced984ec86fb4202f894170

diff --git a/dev-python/doit/doit-0.33.1.ebuild b/dev-python/doit/doit-0.33.1.ebuild
new file mode 100644
index 00000000000..b32d380528b
--- /dev/null
+++ b/dev-python/doit/doit-0.33.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Automation tool"
+HOMEPAGE="https://pydoit.org/ https://pypi.org/project/doit/"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	dev-python/pyinotify[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="
+	test? (
+		${RDEPEND}
+		$(python_gen_impl_dep sqlite)
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pyflakes[${PYTHON_USEDEP}]
+		>=dev-python/pytest-5.4[${PYTHON_USEDEP}]
+	)"
+PDEPEND=">=dev-python/doit-py-0.4.0[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc dev-python/sphinx_rtd_theme
+
+src_prepare() {
+	default
+	# Replace custom theme with builtin for documentation
+	sed -i -e "s:'press':'sphinx_rtd_theme':" doc/conf.py || die
+	# Disable test failing due to impact on PATH run in a sandbox
+	sed -i -e "s:test_target:_&:" tests/test_cmd_strace.py || die
+}
+
+src_install() {
+	distutils-r1_src_install
+	newbashcomp bash_completion_doit ${PN}
+	insinto /usr/share/zsh/site-functions
+	newins zsh_completion_doit _${PN}
+}