[gentoo-commits] repo/gentoo:master commit in: dev-python/flit/

[Michał Górny]

commit:     654a45f307f09c6274eb70715ea8b404bd0f18cb
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 13 15:37:49 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jan 16 17:41:56 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=654a45f3

dev-python/flit: Convert to PEP517

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/flit/flit-3.6.0-r2.ebuild | 48 ++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/dev-python/flit/flit-3.6.0-r2.ebuild b/dev-python/flit/flit-3.6.0-r2.ebuild
new file mode 100644
index 000000000000..60a9fbf7f27a
--- /dev/null
+++ b/dev-python/flit/flit-3.6.0-r2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Simplified packaging of Python modules"
+HOMEPAGE="https://github.com/pypa/flit https://flit.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	>=dev-python/flit_core-3.2.0[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/requests_download[${PYTHON_USEDEP}]
+	dev-python/tomli[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+"
+BDEPEND="${RDEPEND}
+	sys-apps/grep
+	test? (
+		dev-python/pip[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/flit-3.2.0-tests.patch"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/pygments-github-lexers \
+
+src_prepare() {
+	# make sure system install is used
+	rm -r flit_core || die
+	distutils-r1_src_prepare
+}