[gentoo-commits] repo/gentoo:master commit in: media-gfx/geeqie/

[Bernard Cafarelli]

commit:     0cdab62709c862dc0582f4662a6ae3739dc8942e
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 28 21:40:52 2018 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Fri Dec 28 21:41:07 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0cdab627

media-gfx/geeqie: add live ebuild

Thanks grumpytetra <grumpytetra <AT> teknik.io> for original PR

Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 media-gfx/geeqie/geeqie-9999.ebuild | 90 +++++++++++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)

diff --git a/media-gfx/geeqie/geeqie-9999.ebuild b/media-gfx/geeqie/geeqie-9999.ebuild
new file mode 100644
index 00000000000..a4b9efab87e
--- /dev/null
+++ b/media-gfx/geeqie/geeqie-9999.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools git-r3 xdg-utils
+
+DESCRIPTION="A lightweight GTK image viewer forked from GQview"
+HOMEPAGE="http://www.geeqie.org"
+SRC_URI=""
+# Using github mirror, as geeqie.org does not have a valid SSL certificate
+EGIT_REPO_URI="https://github.com/BestImageViewer/geeqie.git"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="debug doc exif ffmpegthumbnailer gpu-accel gtk3 jpeg lcms lirc lua map tiff xmp"
+
+RDEPEND="gtk3? ( x11-libs/gtk+:3 )
+	!gtk3? ( x11-libs/gtk+:2 )
+	virtual/libintl
+	doc? ( app-text/gnome-doc-utils )
+	ffmpegthumbnailer? ( media-video/ffmpegthumbnailer )
+	gpu-accel? ( media-libs/clutter-gtk )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	lirc? ( app-misc/lirc )
+	lua? ( >=dev-lang/lua-5.1:= )
+	map? ( media-libs/libchamplain:0.12 )
+	xmp? ( >=media-gfx/exiv2-0.17:=[xmp] )
+	!xmp? ( exif? ( >=media-gfx/exiv2-0.17:= ) )
+	tiff? ( media-libs/tiff:0 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	dev-util/intltool
+	sys-devel/gettext"
+
+REQUIRED_USE="gpu-accel? ( gtk3 )
+	map? ( gpu-accel )"
+
+src_prepare() {
+	default
+
+	# Remove -Werror (gcc changes may add new warnings)
+	sed -e '/CFLAGS/s/-Werror //g' -i configure.in || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf="--disable-dependency-tracking
+		--with-readmedir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable debug debug-log)
+		$(use_enable ffmpegthumbnailer)
+		$(use_enable gpu-accel)
+		$(use_enable gtk3)
+		$(use_enable jpeg)
+		$(use_enable lcms)
+		$(use_enable lua)
+		$(use_enable lirc)
+		$(use_enable map)
+		$(use_enable tiff)"
+
+	if use exif || use xmp; then
+		myconf="${myconf} --enable-exiv2"
+	else
+		myconf="${myconf} --disable-exiv2"
+	fi
+
+	econf ${myconf}
+}
+
+src_install() {
+	default
+
+	rm -f "${D}/usr/share/doc/${PF}/COPYING"
+	# Application needs access to the uncompressed file
+	docompress -x /usr/share/doc/${PF}/README.md
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+
+	elog "Some plugins may require additional packages"
+	elog "- Image rotate plugin: media-gfx/fbida (JPEG), media-gfx/imagemagick (TIFF/PNG)"
+	elog "- RAW images plugin: media-gfx/ufraw"
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}