[gentoo-commits] gentoo-x86 commit in net-libs/libsoup-gnome: libsoup-gnome-2.34.1.ebuild ChangeLog

[Nirbheek Chauhan (nirbheek)]

nirbheek    11/04/29 17:58:25

  Modified:             ChangeLog
  Added:                libsoup-gnome-2.34.1.ebuild
  Log:
  Move libsoup-gnome-2.34.1 from the gnome overlay, introspection unmasked
  
  (Portage version: 2.1.9.46/cvs/Linux x86_64)

Revision  Changes    Path
1.48                 net-libs/libsoup-gnome/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup-gnome/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup-gnome/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup-gnome/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libsoup-gnome/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	22 Mar 2011 19:42:53 -0000	1.47
+++ ChangeLog	29 Apr 2011 17:58:25 -0000	1.48
@@ -1,6 +1,13 @@
 # ChangeLog for net-libs/libsoup-gnome
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libsoup-gnome/ChangeLog,v 1.47 2011/03/22 19:42:53 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libsoup-gnome/ChangeLog,v 1.48 2011/04/29 17:58:25 nirbheek Exp $
+
+*libsoup-gnome-2.34.1 (29 Apr 2011)
+
+  29 Apr 2011; Nirbheek Chauhan <nirbheek@g.o>
+  +libsoup-gnome-2.34.1.ebuild,
+  +files/libsoup-gnome-2.34.1-system-lib.patch:
+  Move libsoup-gnome-2.34.1 from the gnome overlay, introspection unmasked
 
   22 Mar 2011; Brent Baude <ranger@g.o> libsoup-gnome-2.32.2.ebuild:
   Marking libsoup-gnome-2.32.2 ppc stable for bug 353436



1.1                  net-libs/libsoup-gnome/libsoup-gnome-2.34.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup-gnome/libsoup-gnome-2.34.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup-gnome/libsoup-gnome-2.34.1.ebuild?rev=1.1&content-type=text/plain

Index: libsoup-gnome-2.34.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libsoup-gnome/libsoup-gnome-2.34.1.ebuild,v 1.1 2011/04/29 17:58:25 nirbheek Exp $

EAPI="3"
GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes"

inherit autotools eutils gnome2

MY_PN=${PN/-gnome}
MY_P=${MY_PN}-${PV}

DESCRIPTION="GNOME plugin for libsoup"
HOMEPAGE="http://live.gnome.org/LibSoup"
SRC_URI="${SRC_URI//-gnome}"

LICENSE="LGPL-2"
SLOT="2.4"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-solaris"
IUSE="debug doc +introspection"

RDEPEND="~net-libs/libsoup-${PV}
	|| ( gnome-base/libgnome-keyring <gnome-base/gnome-keyring-2.29.4 )
	dev-db/sqlite:3
	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9
	>=dev-util/gtk-doc-am-1.10
	doc? ( >=dev-util/gtk-doc-1.10 )"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-static
		--disable-tls-check
		$(use_enable introspection)
		--with-libsoup-system
		--with-gnome"
	DOCS="AUTHORS NEWS README"
}

src_configure() {
	# FIXME: we need addpredict to workaround bug #324779 until
	# root cause (bug #249496) is solved
	addpredict /usr/share/snmp/mibs/.index
	gnome2_src_configure
}

src_prepare() {
	gnome2_src_prepare

	# Use lib present on the system
	epatch "${FILESDIR}"/${PN}-2.34.1-system-lib.patch
	eautoreconf
}