[gentoo-commits] repo/gentoo:master commit in: app-text/calibre/

[Zac Medico]

commit:     d74e998d50080bf540ea722e68c20216772c9447
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 31 21:47:48 2020 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Sat Oct 31 22:00:15 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d74e998d

app-text/calibre: Bump to version 5.4.2

Closes: https://bugs.gentoo.org/744961
Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 app-text/calibre/Manifest             |   2 +
 app-text/calibre/calibre-5.4.2.ebuild | 263 ++++++++++++++++++++++++++++++++++
 2 files changed, 265 insertions(+)

diff --git a/app-text/calibre/Manifest b/app-text/calibre/Manifest
index 69fe6680f2a..14eb9b5daaf 100644
--- a/app-text/calibre/Manifest
+++ b/app-text/calibre/Manifest
@@ -3,3 +3,5 @@ DIST calibre-4.22.0.tar.xz 36924876 BLAKE2B 19576d5cfc1a4ed6a505ef46656675980b67
 DIST calibre-4.23.0.tar.xz 36908740 BLAKE2B 3a950ac2b3aade547bb686cc99b963357e76b5931049ecb4a5e09ddaf1db26c74fa3b4ebd74e42d83f68c5c9827c534c0247a3c6a9b000641a778cfe5ac33599 SHA512 2a512f29ddc2fed7f6a229314a9f7fceac198c9422b3be19078685032f1d1cb3b9258ac2609c33d15da20683c1277ed09419ea1e9bbc70430cdc676f60395719
 DIST calibre-4.9.1-bug-731786.patch 1069 BLAKE2B 8b57fb89c9ec2d3a435fbc90f514d45468ceb96b46428efd5d2084cc9bb6137b49dd90dc2f7e574b6d8b8d536728392863046b068c39c8f9bcc3ae23678ac590 SHA512 acd158923bb369270155b3032b033a8387bcb53d1b0ea3e2c0724a40ec0cff6add5fca85649caaf37db0a0878fc3dafacc98b2b641cf10a8d58dc719642c6be5
 DIST calibre-4.9.1.tar.xz 37529656 BLAKE2B 5d703ca0c398b43cc26a54e0628d0fe938c6a5027a4fd0c9cac83944e5143eb08439bf79b2098182be7727eaa042748f17866788b02c7744178dce131f6b1d1e SHA512 bf06aa3cbc8d255934f3f7f3ce20b4798edf107ed9f822943d2b4ae7d95473842928ed79f8ba7571f7e0ebdc267c441916d543d5b7630aae5cb151bcc3184b71
+DIST calibre-5.4.2-SIP-v4.patch.xz 4640 BLAKE2B e8d20d9e23922885ecc3d24b7dd83579911dc83520037bad4e9323725c3127d348dc745dc725d137a3172e8891764355d3fcdee640a26cd6b142a2c26d00da0b SHA512 e79ee69ba0ca7e44c10c6670743889d0391d708e75c798e345e6228f483347f72b070e01e2a258590420a1eea6313d88d816817886747c699e6783bd965ab557
+DIST calibre-5.4.2.tar.xz 36596800 BLAKE2B 00373cdc9af56a8dacc70096d1e7925f8d3da4eaf37727ad58c211d18e6c593a21c3ad0f283048ae28b1bb83889c8c801baaa5e240eb65d972ebc78a79922ec1 SHA512 ef3839f5ff4ceecb3bbd6c84819d6f57cc4bb2a1ae789a9dcf8f029680bc778ef86f9c2eb01832c4990f68c2de892eedafa449205470cec4d86a3bbe9d4b4527

diff --git a/app-text/calibre/calibre-5.4.2.ebuild b/app-text/calibre/calibre-5.4.2.ebuild
new file mode 100644
index 00000000000..5f6bcd52277
--- /dev/null
+++ b/app-text/calibre/calibre-5.4.2.ebuild
@@ -0,0 +1,263 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..8} )
+PYTHON_REQ_USE="sqlite,ssl"
+
+inherit bash-completion-r1 desktop toolchain-funcs python-single-r1 xdg-utils
+
+DESCRIPTION="Ebook management application"
+HOMEPAGE="https://calibre-ebook.com/"
+SRC_URI="https://download.calibre-ebook.com/${PV}/${P}.tar.xz
+	https://dev.gentoo.org/~zmedico/dist/calibre-5.4.2-SIP-v4.patch.xz"
+
+LICENSE="
+	GPL-3+
+	GPL-3
+	GPL-2+
+	GPL-2
+	GPL-1+
+	LGPL-3+
+	LGPL-2.1+
+	LGPL-2.1
+	BSD
+	MIT
+	Old-MIT
+	Apache-2.0
+	public-domain
+	|| ( Artistic GPL-1+ )
+	CC-BY-3.0
+	OFL-1.1
+	PSF-2
+"
+KEYWORDS="~amd64 ~arm ~x86"
+SLOT="0"
+IUSE="ios +udisks"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-text/hunspell-1.7:=
+	>=app-text/podofo-0.9.6_pre20171027:=
+	>=app-text/poppler-0.26.5[qt5]
+	>=dev-libs/chmlib-0.40:=
+	dev-libs/glib:2=
+	dev-libs/hyphen:=
+	>=dev-libs/icu-57.1:=
+	dev-libs/libinput:=
+	>=dev-libs/dbus-glib-0.106
+	>=sys-apps/dbus-1.10.8
+	$(python_gen_cond_dep '
+		>=dev-python/apsw-3.25.2_p1[${PYTHON_MULTI_USEDEP}]
+		dev-python/beautifulsoup:4[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/chardet-3.0.3[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/cssselect-0.7.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/css-parser-1.0.4[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/dbus-python-1.2.4[${PYTHON_MULTI_USEDEP}]
+		dev-python/dnspython[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/feedparser-5.2.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/html2text-2019.8.11[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/html5-parser-0.4.9[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/lxml-3.8.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/markdown-3.0.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/mechanize-0.3.5[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/msgpack-0.6.2[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/netifaces-0.10.5[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pillow-3.2.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/psutil-4.3.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pygments-2.3.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/python-dateutil-2.5.3[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/PyQt5-5.12[gui,svg,widgets,network,printsupport,${PYTHON_MULTI_USEDEP}]
+		>=dev-python/PyQtWebEngine-5.12[${PYTHON_MULTI_USEDEP}]
+		dev-python/regex[${PYTHON_MULTI_USEDEP}]
+		dev-python/zeroconf[${PYTHON_MULTI_USEDEP}]
+	')
+	dev-qt/qtcore:5=
+	dev-qt/qtdbus:5=
+	dev-qt/qtgui:5=[jpeg]
+	>=dev-qt/qtwebengine-5.12
+	dev-qt/qtwidgets:5=
+	dev-util/desktop-file-utils
+	dev-util/gtk-update-icon-cache
+	media-fonts/liberation-fonts
+	media-libs/fontconfig:=
+	>=media-libs/freetype-2:=
+	>=media-libs/libmtp-1.1.11:=
+	>=media-libs/libwmf-0.2.8
+	>=media-gfx/optipng-0.7.6
+	>=sys-libs/zlib-1.2.11:=
+	virtual/libusb:1=
+	x11-libs/libxkbcommon:=
+	x11-libs/libX11:=
+	x11-libs/libXext:=
+	x11-libs/libXrender:=
+	x11-misc/shared-mime-info
+	>=x11-misc/xdg-utils-1.0.2-r2
+	ios? (
+		>=app-pda/usbmuxd-1.0.8
+		>=app-pda/libimobiledevice-1.2.0
+	)
+	udisks? ( virtual/libudev )"
+RDEPEND="${COMMON_DEPEND}
+	udisks? ( sys-fs/udisks:2 )"
+DEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/setuptools-23.1.0[${PYTHON_MULTI_USEDEP}]
+		dev-python/sip[${PYTHON_MULTI_USEDEP}]
+	')
+	>=virtual/podofo-build-0.9.6_pre20171027
+	virtual/pkgconfig"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && tc-is-gcc && [[ $(gcc-major-version) -lt 6 ]]; then
+		eerror "Calibre cannot be built with this version of gcc."
+		eerror "You need at least gcc-6.0"
+		die "Your C compiler is too old for this package."
+	fi
+}
+
+src_prepare() {
+	# no_updates: do not annoy user with "new version is availible all the time
+	# disable_plugins: walking sec-hole, wait for upstream to use GHNS interface
+	eapply \
+		"${FILESDIR}/${PN}-2.9.0-no_updates_dialog.patch" \
+		"${FILESDIR}/${PN}-disable_plugins.patch" \
+		"${WORKDIR}/${PN}-5.4.2-SIP-v4.patch"
+
+	eapply_user
+
+	# Fix outdated version constant.
+	#sed -e "s#\\(^numeric_version =\\).*#\\1 (${PV//./, })#" \
+	#	-i src/calibre/constants.py || \
+	#	die "sed failed to patch constants.py"
+
+	# Avoid sandbox violation in /usr/share/gnome/apps when linux.py
+	# calls xdg-* (bug #258938).
+	sed -e "s|'xdg-desktop-menu', 'install'|\\0, '--mode', 'user'|" \
+		-e "s|check_call(\\['xdg-desktop-menu', 'forceupdate'\\])|#\\0|" \
+		-e "s|\\(CurrentDir(tdir)\\), \\\\\$|\\1:|" \
+		-e "s|, PreserveMIMEDefaults():|:|" \
+		-e "s|'xdg-icon-resource', 'install'|\\0, '--mode', 'user'|" \
+		-e "s|cmd\[2\]|cmd[4]|" \
+		-e "s|cc(\\['xdg-desktop-menu', 'forceupdate'\\])|#\\0|" \
+		-e "s|'xdg-mime', 'install'|\\0, '--mode', 'user'|" \
+		-i src/calibre/linux.py || die "sed failed to patch linux.py"
+
+	# Disable unnecessary privilege dropping for bug #287067.
+	sed -e "s:if os.geteuid() == 0:if False and os.geteuid() == 0:" \
+		-i setup/install.py || die "sed failed to patch install.py"
+
+	sed -e "/^                self.check_call(\\[QMAKE\\] + qmc + \\[proname\\])$/a\
+\\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ self.check_call(['sed', \
+'-e', 's|^CFLAGS .*|\\\\\\\\0 ${CFLAGS}|', \
+'-e', 's|^CXXFLAGS .*|\\\\\\\\0 ${CXXFLAGS}|', \
+'-e', 's|^LFLAGS .*|\\\\\\\\0 ${LDFLAGS}|', \
+'-i', 'Makefile'])" \
+		-e "s|open(self.j(bdir, '.qmake.conf'), 'wb').close()|open(self.j(bdir, '.qmake.conf'), 'wb').write(b'QMAKE_LFLAGS += ${LDFLAGS}')|" \
+		-i setup/build.py || die "sed failed to patch build.py"
+}
+
+src_install() {
+	# calibre works with python 3, so remove the python 2 constraint
+	export CALIBRE_PY3_PORT=1
+
+	# Bypass kbuildsycoca and update-mime-database in order to
+	# avoid sandbox violations if xdg-mime tries to call them.
+	mkdir "${T}/bin" || die
+	cat - > "${T}/bin/kbuildsycoca" <<-EOF
+	#!${BASH}
+	echo $0 : $@
+	exit 0
+	EOF
+
+	cp "${T}"/bin/{kbuildsycoca,update-mime-database} || die
+	chmod +x "${T}"/bin/{kbuildsycoca,update-mime-database} || die
+
+	export QMAKE="${EPREFIX}/usr/$(get_libdir)/qt5/bin/qmake"
+
+	# Unset DISPLAY in order to prevent xdg-mime from triggering a sandbox
+	# violation with kbuildsycoca as in bug #287067, comment #13.
+	export -n DISPLAY
+
+	# Bug #352625 - Some LANGUAGE values can trigger the following ValueError:
+	#   File "/usr/lib/python2.6/locale.py", line 486, in getdefaultlocale
+	#    return _parse_localename(localename)
+	#  File "/usr/lib/python2.6/locale.py", line 418, in _parse_localename
+	#    raise ValueError, 'unknown locale: %s' % localename
+	#ValueError: unknown locale: 46
+	export -n LANG LANGUAGE ${!LC_*}
+	export LC_ALL=C.utf8 #709682
+
+	# Bug #295672 - Avoid sandbox violation in ~/.config by forcing
+	# variables to point to our fake temporary $HOME.
+	export HOME="${T}/fake_homedir"
+	export XDG_CONFIG_HOME="${HOME}/.config"
+	export XDG_DATA_HOME="${HOME}/.local/share"
+	export CALIBRE_CONFIG_DIRECTORY="${XDG_CONFIG_HOME}/calibre"
+	mkdir -p "${XDG_DATA_HOME}" "${CALIBRE_CONFIG_DIRECTORY}" || die
+
+	tc-export CC CXX
+	# Bug #334243 - respect LDFLAGS when building extensions
+	export OVERRIDE_CFLAGS="$CFLAGS" OVERRIDE_LDFLAGS="$LDFLAGS"
+	local libdir=$(get_libdir)
+	[[ -n $libdir ]] || die "get_libdir returned an empty string"
+
+	addpredict /dev/dri #665310
+
+	PATH=${T}/bin:${PATH} PYTHONPATH=${S}/src${PYTHONPATH:+:}${PYTHONPATH} \
+	"${PYTHON}" setup.py install \
+		--root="${D}" \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/${libdir}" \
+		--staging-root="${ED}/usr" \
+		--staging-libdir="${ED}/usr/${libdir}" || die
+
+	rm "${ED}/usr/share/applications/defaults.list" || die
+	find "${ED}"/usr/share -type d -empty -delete
+
+	cd "${ED}"/usr/share/calibre/fonts/liberation || die
+	local x
+	for x in * ; do
+		[[ -f ${EPREFIX}/usr/share/fonts/liberation-fonts/${x} ]] || continue
+		ln -sf "../../../fonts/liberation-fonts/${x}" "${x}" || die
+	done
+
+	einfo "Converting python shebangs"
+	python_fix_shebang --force "${ED}"
+
+	einfo "Compiling python modules"
+	python_optimize "${ED}"/usr/$(get_libdir)/calibre "${D}/$(python_get_sitedir)"
+
+	newinitd "${FILESDIR}"/calibre-server-3.init calibre-server
+	newconfd "${FILESDIR}"/calibre-server-3.conf calibre-server
+}
+
+pkg_preinst() {
+	# Indentify stray directories from upstream's "Binary install"
+	# method (see bug 622728).
+	CALIBRE_LIB_DIR=/usr/$(get_libdir)/calibre
+	CALIBRE_LIB_CONTENT=$(for x in "${ED}${CALIBRE_LIB_DIR}"/*; do
+		printf -- "${x##*/} "; done) || die "Failed to list ${ED}${CALIBRE_LIB_DIR}"
+}
+
+pkg_postinst() {
+	[[ -n ${CALIBRE_LIB_DIR} ]] || die "CALIBRE_LIB_DIR is unset"
+	local x
+	for x in "${EROOT}${CALIBRE_LIB_DIR}"/*; do
+		if [[ " ${CALIBRE_LIB_CONTENT} " != *" ${x##*/} "* ]]; then
+			elog "Purging '${x}'"
+			rm -rf "${x}"
+		fi
+	done
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	xdg_icon_cache_update
+}