[gentoo-commits] proj/gnome:master commit in: x11-misc/alacarte/

[Gilles Dartiguelongue]

commit:     a2bdf3621a5447ce667ca797c12e2bd094b998ce
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 30 20:42:12 2012 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Tue Oct 30 20:42:12 2012 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=a2bdf362

x11-misc/alacarte: 0.13.4 → 3.6.1

---
 x11-misc/alacarte/alacarte-3.6.1.ebuild |   81 +++++++++++++++++++++++++++++++
 x11-misc/alacarte/metadata.xml          |    5 ++
 2 files changed, 86 insertions(+), 0 deletions(-)

diff --git a/x11-misc/alacarte/alacarte-3.6.1.ebuild b/x11-misc/alacarte/alacarte-3.6.1.ebuild
new file mode 100644
index 0000000..71a8a0d
--- /dev/null
+++ b/x11-misc/alacarte/alacarte-3.6.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/alacarte/alacarte-0.13.4.ebuild,v 1.1 2012/10/28 16:50:07 eva Exp $
+
+EAPI="4"
+GCONF_DEBUG="no"
+PYTHON_DEPEND="2:2.5"
+PYTHON_USE_WITH="xml"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="3.*"
+
+inherit gnome2 python
+
+DESCRIPTION="Simple GNOME menu editor"
+HOMEPAGE="http://live.gnome.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+COMMON_DEPEND="
+	dev-python/pygobject:3
+	>=gnome-base/gnome-menus-3.5.3:3[introspection]
+"
+# gnome-panel needed for gnome-desktop-item-edit
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/gnome-panel
+	x11-libs/gdk-pixbuf:2[introspection]
+	x11-libs/gtk+:3[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.0
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	python_pkg_setup
+}
+
+src_prepare() {
+	DOCS="AUTHORS ChangeLog NEWS README"
+
+	gnome2_src_prepare
+	python_clean_py-compile_files
+
+	python_copy_sources
+}
+
+src_configure() {
+	configure() {
+		G2CONF="${G2CONF} PYTHON=$(PYTHON -a)"
+		gnome2_src_configure
+	}
+	python_execute_function -s configure
+}
+
+src_compile() {
+	python_execute_function -s gnome2_src_compile
+}
+
+src_test() {
+	python_execute_function -s -d
+}
+
+src_install() {
+	python_execute_function -s gnome2_src_install
+	python_clean_installation_image
+	python_convert_shebangs -r 2 "${ED}"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	python_mod_optimize Alacarte
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup Alacarte
+}

diff --git a/x11-misc/alacarte/metadata.xml b/x11-misc/alacarte/metadata.xml
new file mode 100644
index 0000000..6e0e2ec
--- /dev/null
+++ b/x11-misc/alacarte/metadata.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>gnome</herd>
+</pkgmetadata>