[gentoo-commits] gentoo-x86 commit in net-analyzer/hydra: ChangeLog hydra-6.0.ebuild

[Jeroen Roovers (jer)]

jer         11/02/01 07:50:24

  Modified:             ChangeLog
  Added:                hydra-6.0.ebuild
  Log:
  Version bump by Anton Bolshakov (bug #353364).
  
  (Portage version: 2.2.0_alpha19/cvs/Linux i686)

Revision  Changes    Path
1.47                 net-analyzer/hydra/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hydra/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hydra/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hydra/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/hydra/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	22 Dec 2010 01:54:49 -0000	1.46
+++ ChangeLog	1 Feb 2011 07:50:24 -0000	1.47
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/hydra
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/hydra/ChangeLog,v 1.46 2010/12/22 01:54:49 hwoarang Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/hydra/ChangeLog,v 1.47 2011/02/01 07:50:24 jer Exp $
+
+*hydra-6.0 (01 Feb 2011)
+
+  01 Feb 2011; Jeroen Roovers <jer@g.o> +hydra-6.0.ebuild:
+  Version bump by Anton Bolshakov (bug #353364).
 
   22 Dec 2010; Markos Chandras <hwoarang@g.o> hydra-5.8.ebuild:
   Stable on amd64 wrt bug #347347



1.1                  net-analyzer/hydra/hydra-6.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hydra/hydra-6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hydra/hydra-6.0.ebuild?rev=1.1&content-type=text/plain

Index: hydra-6.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/hydra/hydra-6.0.ebuild,v 1.1 2011/02/01 07:50:24 jer Exp $

EAPI="2"

inherit toolchain-funcs

DESCRIPTION="Advanced parallized login hacker"
HOMEPAGE="http://www.thc.org/thc-hydra/"
SRC_URI="http://freeworld.thc.org/releases/${P}-src.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="gtk ssl"

DEPEND="
	dev-libs/openssl
	gtk? ( >=x11-libs/gtk+-1.2 )
	ssl? ( >=net-libs/libssh-0.4.0 )
"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${P}-src

src_prepare() {
	# None of the settings in Makefile.unix are useful to us
	: > Makefile.unix

	sed -i \
		-e 's:-O2:$(CPPFLAGS) $(CFLAGS):g' \
		-e 's:|| echo.*$::' \
		-e '/\t-$(CC)/s/-//' \
		-e '/ -o /s:$(OPTS):& $(LDFLAGS):g' \
		Makefile.am || die "sed failed"
}

src_configure() {
	# Note: despite the naming convention, the top level script is not an
	# autoconf-based script.
	./configure \
		--prefix=/usr \
		$(use gtk && echo --disable-xhydra) \
			|| die "configure failed"

	sed -i \
		-e '/^XDEFINES=/s:=.*:=:' \
		-e '/^XLIBS=/s:=.*:=-lcrypto:' \
		-e '/^XLIBPATHS/s:=.*:=:' \
		-e '/^XIPATHS=/s:=.*:=:' \
		Makefile || die "pruning vars"

	if use ssl ; then
		sed -i \
			-e '/^XDEFINES=/s:=:=-DLIBOPENSSL -DLIBSSH:' \
			-e '/^XLIBS=/s:$: -lssl -lssh:' \
			Makefile || die "adding ssl"
	fi

	if use gtk ; then
		cd hydra-gtk && \
		econf || die "econf failed"
	fi
}

src_compile() {
	tc-export CC
	emake || die "make failed"
	if use gtk ; then
		cd hydra-gtk && \
		emake || die "emake hydra-gtk failed"
	fi
}

src_install() {
	dobin hydra pw-inspector || die "dobin failed"
	if use gtk ; then
		dobin hydra-gtk/src/xhydra || die "gtk"
	fi
	dodoc CHANGES README TODO
}