[gentoo-commits] gentoo-x86 commit in net-misc/apt-cacher-ng: ChangeLog apt-cacher-ng-0.8.0_pre2.ebuild

[Jeroen Roovers (jer)]

jer         14/09/02 09:53:49

  Modified:             ChangeLog
  Added:                apt-cacher-ng-0.8.0_pre2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.43                 net-misc/apt-cacher-ng/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	18 Jul 2014 14:24:39 -0000	1.42
+++ ChangeLog	2 Sep 2014 09:53:49 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/apt-cacher-ng
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v 1.42 2014/07/18 14:24:39 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v 1.43 2014/09/02 09:53:49 jer Exp $
+
+*apt-cacher-ng-0.8.0_pre2 (02 Sep 2014)
+
+  02 Sep 2014; Jeroen Roovers <jer@g.o>
+  +apt-cacher-ng-0.8.0_pre2.ebuild:
+  Version bump.
 
 *apt-cacher-ng-0.8.0_pre1 (18 Jul 2014)
 *apt-cacher-ng-0.7.27 (18 Jul 2014)



1.1                  net-misc/apt-cacher-ng/apt-cacher-ng-0.8.0_pre2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/apt-cacher-ng-0.8.0_pre2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/apt-cacher-ng-0.8.0_pre2.ebuild?rev=1.1&content-type=text/plain

Index: apt-cacher-ng-0.8.0_pre2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/apt-cacher-ng-0.8.0_pre2.ebuild,v 1.1 2014/09/02 09:53:49 jer Exp $

EAPI=5
inherit cmake-utils eutils user

DESCRIPTION="Yet another implementation of an HTTP proxy for Debian/Ubuntu software packages written in C++"
HOMEPAGE="
	http://www.unix-ag.uni-kl.de/~bloch/acng/
	http://packages.qa.debian.org/a/apt-cacher-ng.html
"
LICENSE="BSD-4 ZLIB public-domain"
SLOT="0"
SRC_URI="mirror://debian/pool/main/a/${PN}/${PN}_${PV/_/~}.orig.tar.xz"

KEYWORDS=""
IUSE="doc fuse tcpd"

COMMON_DEPEND="
	app-arch/bzip2
	app-arch/xz-utils
	sys-libs/zlib
"
DEPEND="
	${COMMON_DEPEND}
	dev-util/cmake
"
RDEPEND="
	${COMMON_DEPEND}
	dev-lang/perl
	fuse? ( sys-fs/fuse )
	tcpd? ( sys-apps/tcp-wrappers )
"

S=${WORKDIR}/${P/_}

pkg_setup() {
	# add new user & group for daemon
	enewgroup ${PN}
	enewuser ${PN} -1 -1 -1 ${PN}
}

src_configure(){
	mycmakeargs="-DCMAKE_INSTALL_PREFIX=/usr"
	if use fuse; then
		mycmakeargs="-DHAVE_FUSE_26=yes ${mycmakeargs}"
	else
		mycmakeargs="-DHAVE_FUSE_26=no ${mycmakeargs}"
	fi
	if use tcpd; then
		mycmakeargs="-DHAVE_LIBWRAP=yes ${mycmakeargs}"
	else
		mycmakeargs="-DHAVE_LIBWRAP=no ${mycmakeargs}"
	fi

	cmake-utils_src_configure
}

src_install() {
	pushd ${CMAKE_BUILD_DIR}
	dosbin ${PN}
	if use fuse; then
		dobin acngfs
	fi
	popd

	newinitd "${FILESDIR}"/initd ${PN}
	newconfd "${FILESDIR}"/confd ${PN}

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/logrotate ${PN}

	doman doc/man/${PN}*
	if use fuse; then
		doman doc/man/acngfs*
	fi

	# Documentation
	dodoc README TODO VERSION INSTALL ChangeLog
	if use doc; then
		dodoc doc/*.pdf
		dohtml doc/html/*
		docinto examples/conf
		dodoc conf/*
	fi

	# perl daily cron script
	dosbin scripts/expire-caller.pl
	exeinto /etc/cron.daily
	newexe "${FILESDIR}"/cron.daily ${PN}

	# default configuration
	insinto /etc/${PN}
	newins conf/acng.conf ${PN}.conf
	doins $( echo conf/* | sed 's|conf/acng.conf||g' )

	dodir /var/cache/${PN}
	dodir /var/log/${PN}
	# Some directories must exists
	keepdir /var/log/${PN}
	fowners -R ${PN}:${PN} \
		/etc/${PN} \
		/var/log/${PN} \
		/var/cache/${PN}
}