[gentoo-commits] repo/gentoo:master commit in: media-radio/tucnak/

[Thomas Beierlein]

commit:     c91ea0c7a23275088de8e6549fe47127b0ead3ed
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Tue Sep  3 05:31:53 2019 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Tue Sep  3 05:32:33 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c91ea0c7

media-radio/tucnak: Version bump

Package-Manager: Portage-2.3.75, Repoman-2.3.17
Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 media-radio/tucnak/Manifest           |  1 +
 media-radio/tucnak/tucnak-4.17.ebuild | 68 +++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/media-radio/tucnak/Manifest b/media-radio/tucnak/Manifest
index 9aad9b2f750..ac0d6009a88 100644
--- a/media-radio/tucnak/Manifest
+++ b/media-radio/tucnak/Manifest
@@ -1 +1,2 @@
 DIST tucnak-4.16.tar.gz 3526223 BLAKE2B 1e88157a2fc023cc115a9cadfffa7516eac2ff23e4fa5aef7d7f4a959899cf5d7be99a6d934eaee1c32c1b702ca5b5e37a82dd91b7ea03d7ac21815c2e8c0c63 SHA512 65547fd4f83d41bdf312d61c0b6d750c5f949399821c5298731ee6941de0bc95290e90a004c22d731319b0bbd7b55f0d512c2e616ebd43f0c35698cc940594ce
+DIST tucnak-4.17.tar.gz 3520755 BLAKE2B 6628d628cfc7770fdc02611ec7d21410dd910601c8159052f0d2c2d5754de7f3c9360b8f43b60ae3a27eac92808a0a8254efdba5198684b19662b8fdb32a43a8 SHA512 1f59bb47c302df03ac2f6420c71d3708b94efbb74642eb403f0ee6e29bb6826f11cb606d1542d287d776908af8f9c3d9724b20d4678fb8c3ea1cadb22255ec20

diff --git a/media-radio/tucnak/tucnak-4.17.ebuild b/media-radio/tucnak/tucnak-4.17.ebuild
new file mode 100644
index 00000000000..f97b30dca3c
--- /dev/null
+++ b/media-radio/tucnak/tucnak-4.17.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools flag-o-matic multilib
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/libzia
+	media-libs/libsndfile
+	>=media-libs/libsdl-1.2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}