[gentoo-commits] gentoo-x86 commit in media-sound/mumble: ChangeLog mumble-1.2.1.ebuild mumble-1.2.0.ebuild

[Timo Gurr (tgurr)]

tgurr       10/01/08 21:00:44

  Modified:             ChangeLog
  Added:                mumble-1.2.1.ebuild
  Removed:              mumble-1.2.0.ebuild
  Log:
  Version bump, remove old.
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 media-sound/mumble/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mumble/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mumble/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mumble/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/mumble/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	11 Dec 2009 00:06:39 -0000	1.24
+++ ChangeLog	8 Jan 2010 21:00:44 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/mumble
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mumble/ChangeLog,v 1.24 2009/12/11 00:06:39 tgurr Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mumble/ChangeLog,v 1.25 2010/01/08 21:00:44 tgurr Exp $
+
+*mumble-1.2.1 (08 Jan 2010)
+
+  08 Jan 2010; Timo Gurr <tgurr@g.o> -mumble-1.2.0.ebuild,
+  +mumble-1.2.1.ebuild:
+  Version bump, remove old.
 
 *mumble-1.2.0 (11 Dec 2009)
 



1.1                  media-sound/mumble/mumble-1.2.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mumble/mumble-1.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mumble/mumble-1.2.1.ebuild?rev=1.1&content-type=text/plain

Index: mumble-1.2.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mumble/mumble-1.2.1.ebuild,v 1.1 2010/01/08 21:00:44 tgurr Exp $

EAPI="2"

inherit eutils multilib qt4

MY_P="${PN}-${PV/_/~}"

DESCRIPTION="Mumble is an open source, low-latency, high quality voice chat software."
HOMEPAGE="http://mumble.sourceforge.net/"
SRC_URI="http://mumble.info/snapshot/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+alsa +dbus debug g15 oss pch portaudio pulseaudio speech zeroconf"

RDEPEND=">=dev-libs/boost-1.36.0-r1
	dev-libs/openssl
	>=dev-libs/protobuf-2.2.0
	>=media-libs/celt-0.7.0
	>=media-libs/libsndfile-1.0.20
	>=media-libs/speex-1.2_rc1
	x11-libs/qt-core:4[ssl]
	x11-libs/qt-gui:4
	x11-libs/qt-opengl:4
	x11-libs/qt-sql:4[sqlite]
	x11-libs/qt-svg:4
	x11-libs/qt-xmlpatterns:4
	x11-proto/inputproto
	alsa? ( media-libs/alsa-lib )
	dbus? ( x11-libs/qt-dbus:4 )
	g15? ( app-misc/g15daemon )
	portaudio? ( media-libs/portaudio )
	pulseaudio? ( media-sound/pulseaudio )
	speech? ( app-accessibility/speech-dispatcher )
	zeroconf? ( || ( net-dns/avahi[mdnsresponder-compat] net-misc/mDNSResponder ) )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S="${WORKDIR}/${MY_P}"

src_configure() {
	local conf_add

	if has_version '<=sys-devel/gcc-4.2'; then
		conf_add="${conf_add} no-pch"
	else
		use pch || conf_add="${conf_add} no-pch"
	fi

	use alsa || conf_add="${conf_add} no-alsa"
	use dbus || conf_add="${conf_add} no-dbus"
	use debug && conf_add="${conf_add} symbols debug" || conf_add="${conf_add} release"
	use g15 || conf_add="${conf_add} no-g15"
	use oss || conf_add="${conf_add} no-oss"
	use portaudio || conf_add="${conf_add} no-portaudio"
	use pulseaudio || conf_add="${conf_add} no-pulseaudio"
	use speech || conf_add="${conf_add} no-speechd"
	use zeroconf || conf_add="${conf_add} no-bonjour"

	eqmake4 "${S}/main.pro" -recursive \
		CONFIG+="${conf_add} \
			no-11x \
			no-bundled-celt \
			no-bundled-speex \
			no-embed-qt-translations \
			no-server" \
		DEFINES+="PLUGIN_PATH=/usr/$(get_libdir)/mumble" \
		|| die "eqmake4 failed."
}

src_install() {
	newdoc README.Linux README || die "Installing docs failed."
	dodoc CHANGES || die "Installing docs failed."

	local dir
	if use debug; then
		dir=debug
	else
		dir=release
	fi

	dobin "${dir}"/mumble || die "Installing mumble binary failed."
	dobin scripts/mumble-overlay || die "Installing overlay script failed."

	insinto /usr/share/services
	doins scripts/mumble.protocol || die "Installing mumble.protocol file failed."

	domenu scripts/mumble.desktop || die "Installing menu entry failed."

	insinto /usr/share/icons/hicolor/scalable/apps
	doins icons/mumble.svg || die "Installing icon failed."

	doman man/mumble-overlay.1 || die "Installing mumble-overlay manpage failed."
	doman man/mumble.1 || die "Installing mumble manpage failed."

	insopts -o root -g root -m 0755
	insinto "/usr/$(get_libdir)/mumble"
	doins "${dir}"/lib*.so* || die "Installing plugins failed."
	doins "${dir}"/plugins/lib*.so* || die "Installing plugins failed."
}

pkg_postinst() {
	echo
	elog "Visit http://mumble.sourceforge.net/ for futher configuration instructions."
	elog "Run mumble-overlay to start the OpenGL overlay (after starting mumble)."
	echo
}