[gentoo-commits] gentoo-x86 commit in app-misc/muttprint: ChangeLog muttprint-0.73-r1.ebuild

[JosA MarAa Alonso (nimiux)]

nimiux      12/04/28 12:34:12

  Modified:             ChangeLog
  Added:                muttprint-0.73-r1.ebuild
  Log:
  Bump to 0.73-r1. Added dependency on dev-texlive/texlive-latexextra. Removed warning on fatal error.
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.53                 app-misc/muttprint/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/muttprint/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/muttprint/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/muttprint/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/muttprint/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	18 Apr 2012 11:39:52 -0000	1.52
+++ ChangeLog	28 Apr 2012 12:34:12 -0000	1.53
@@ -1,6 +1,13 @@
 # ChangeLog for app-misc/muttprint
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/muttprint/ChangeLog,v 1.52 2012/04/18 11:39:52 nimiux Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/muttprint/ChangeLog,v 1.53 2012/04/28 12:34:12 nimiux Exp $
+
+*muttprint-0.73-r1 (28 Apr 2012)
+
+  28 Apr 2012; Chema Alonso <nimiux@g.o> +muttprint-0.73-r1.ebuild,
+  files/muttprint-0.73-warning.patch:
+  Bump to 0.73-r1. Added dependency on dev-texlive/texlive-latexextra. Removed
+  warning on fatal error.
 
 *muttprint-0.73 (18 Apr 2012)
 



1.1                  app-misc/muttprint/muttprint-0.73-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/muttprint/muttprint-0.73-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/muttprint/muttprint-0.73-r1.ebuild?rev=1.1&content-type=text/plain

Index: muttprint-0.73-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/muttprint/muttprint-0.73-r1.ebuild,v 1.1 2012/04/28 12:34:12 nimiux Exp $

EAPI=4

inherit autotools-utils eutils

DESCRIPTION="Script for pretty printing of your mails"
HOMEPAGE="http://muttprint.sourceforge.net"
SRC_URI="mirror://sourceforge/muttprint/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="doc"

DEPEND="dev-lang/perl
	virtual/latex-base
	doc? (
		app-text/dvipsk
		app-text/docbook-sgml-utils[jadetex] )"

RDEPEND="dev-lang/perl
	virtual/latex-base
	dev-texlive/texlive-latexextra"

patch_docs() {
	sed -i -e 's/db2pdf/docbook2pdf/' "${S}"/configure.ac || die
	for l in de en es it sl
	do
		sed -i -e "/^docdir/s/$/-${PV}/" \
			-e 's/db2/docbook2/' -e 's/ -s / -d /' \
			-e "s|manual-${l}-sed/||" \
			-e "s/mv manual-${l}-sed.dvi/cp manual-${l}-sed.dvi/" \
			"${S}"/doc/manual/${l}/Makefile.am || die
	done
}

src_prepare() {
	epatch "${FILESDIR}/${P}-warning.patch"
	epatch "${FILESDIR}/${P}-manuals.patch"

	if use doc ; then
		# Patch docbook and docdir
		patch_docs
	else
		# Don't do manuals
		sed -i -e '/db2pdf/d' "${S}"/configure.ac || die
	fi
	sed -i -e "/^docdir/s/$/-${PV}/" "${S}"/Makefile.am || die

	# The distfile does not include the png files, nor penguin.jpg
	sed -i -e '/.*png /d' -e '/penguin.jpg /d' "${S}"/pics/Makefile.am || die

	eautoreconf
}

src_configure() {
	econf --docdir="/usr/share/doc/${PF}"
}

src_compile() {
	# Paralell build does not work when USE="doc"
	emake -j1
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc ChangeLog
}