[gentoo-commits] gentoo-x86 commit in dev-scheme/kawa: kawa-1.9.90-r1.ebuild ChangeLog kawa-1.9.90.ebuild

[TomAs Touceda (chiiph)]

chiiph      10/06/28 23:30:54

  Modified:             ChangeLog
  Added:                kawa-1.9.90-r1.ebuild
  Removed:              kawa-1.9.90.ebuild
  Log:
  Revbump, change swt dependency to swt:3.5. Port to EAPI 3
  (Portage version: 2.2_rc67/cvs/Linux i686)

Revision  Changes    Path
1.11                 dev-scheme/kawa/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/kawa/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/kawa/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/kawa/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-scheme/kawa/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	30 Nov 2009 19:51:42 -0000	1.10
+++ ChangeLog	28 Jun 2010 23:30:54 -0000	1.11
@@ -1,6 +1,12 @@
 # ChangeLog for dev-scheme/kawa
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-scheme/kawa/ChangeLog,v 1.10 2009/11/30 19:51:42 ulm Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-scheme/kawa/ChangeLog,v 1.11 2010/06/28 23:30:54 chiiph Exp $
+
+*kawa-1.9.90-r1 (29 Jun 2010)
+
+  29 Jun 2010; Tomas Touceda <chiiph@g.o> -kawa-1.9.90.ebuild,
+  +kawa-1.9.90-r1.ebuild:
+  Revbump, change swt dependency to swt:3.5. Port to EAPI 3
 
 *kawa-1.9.90 (30 Nov 2009)
 



1.1                  dev-scheme/kawa/kawa-1.9.90-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/kawa/kawa-1.9.90-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/kawa/kawa-1.9.90-r1.ebuild?rev=1.1&content-type=text/plain

Index: kawa-1.9.90-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-scheme/kawa/kawa-1.9.90-r1.ebuild,v 1.1 2010/06/28 23:30:54 chiiph Exp $

EAPI="3"

JAVA_PKG_IUSE="source"

inherit eutils java-pkg-2

DESCRIPTION="Kawa, the Java-based Scheme system & Language Framework"
HOMEPAGE="http://www.gnu.org/software/kawa/"
XQTS_Ver="1_0_2"
SRC_URI="mirror://gnu/kawa/${P}.tar.gz
		 xqtests? ( http://www.w3.org/XML/Query/test-suite/XQTS_${XQTS_Ver}.zip )"

LICENSE="MIT public-domain
		 jemacs? ( GPL-2 )
		 krl? ( GPL-2 )"
SLOT="0"
KEYWORDS="~x86"
IUSE="+awt echo2 +frontend jemacs krl +sax servlets +swing swt +xml xqtests"

COMMON_DEPEND="( >=virtual/jdk-1.5 )
			   frontend? ( sys-libs/readline:0 )
			   sax? ( dev-java/sax:0 )
			   echo2? ( dev-java/echo2 )
			   swt? ( dev-java/swt:3.5 )
			   servlets? ( dev-java/servletapi:2.4 )"
DEPEND="${COMMON_DEPEND}
		xqtests? ( app-arch/unzip:0 )"
RDEPEND="${COMMON_DEPEND}"

xtestsuite="XQTS_${XQTS_Ver}"

src_unpack () {
	unpack kawa-${PV}.tar.gz || die
	if use xqtests; then
		mkdir "${WORKDIR}/${xtestsuite}" || die
		cd "${WORKDIR}/${xtestsuite}" || die
		unpack ${xtestsuite}.zip || die
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}.patch
}

src_configure() {
	# speeds up one-shot ebuilds.
	myconf="--disable-dependency-tracking"
	if use jemacs && ! use swing; then
		echo
		einfo "Although the swing USE flag is disabled you chose to enable jemacs,"
		einfo "so swing is enabled anyway."
		echo
		myconf="${myconf} --with-swing"
	else
		myconf="${myconf} $(use_with swing)"
	fi
	if use xqtests; then
		myconf="${myconf} $(use_with xqtests XQTS=${WORKDIR}/${xtestsuite})"
	fi
	if use servlets; then
		myconf="${myconf} --with-servlet=$(java-pkg_getjar servletapi-2.4 servlet-api.jar)"
	fi
	if use swt; then
		myconf="${myconf} --with-swt=$(java-pkg_getjar swt-3.5 swt.jar)"
	fi

	econf ${myconf} $(use_enable frontend kawa-frontend) \
		  $(use_enable xml) \
		  $(use_enable krl brl) \
		  $(use_enable echo2) \
		  $(use_enable jemacs) \
		  $(use_with awt) \
		  $(use_with sax sax2) \
		  --with-java-source=$(java-pkg_get-source) || die "econf failed."
}

src_compile() {
	emake -j1 || die "emake failed."
}

src_install () {
	emake -j1 DESTDIR="${D}" install || die "emake install failed"
	rm -rv "${D}"/usr/share/java/ || die "rm -rv failed"

	java-pkg_newjar kawa-${PV}.jar || die

	java-pkg_dolauncher "kawa" --main kawa.repl || die "dolauncher failed"
	java-pkg_dolauncher "qexo" --main kawa.repl --pkg_args \
		"--xquery" || die "dolauncher qexo failed"
	if use servlets; then
		java-pkg_dolauncher "kawa-cgi-servlet" --main \
			gnu.kawa.servlet.CGIServletWrapper || die
	fi
	if use jemacs; then
		java-pkg_dolauncher "jemacs" --main \
			gnu.jemacs.lang.ELisp || die
	fi

	use source && java-pkg_dosrc kawa/* gnu/*

	dodoc ChangeLog TODO README NEWS || die
	doinfo doc/kawa.info* || die
	cp doc/kawa.man doc/kawa.2 || die
	cp doc/qexo.man doc/qexo.2 || die
	doman doc/*.2 || die
}