[gentoo-commits] gentoo-x86 commit in app-admin/smolt: smolt-1.4.2.ebuild ChangeLog

[Sebastian Pipping (sping)]

sping       10/02/17 00:53:04

  Modified:             ChangeLog
  Added:                smolt-1.4.2.ebuild
  Log:
  app-admin/smolt: Trivial-bump to 1.4.2
  (Portage version: 2.2_rc61/cvs/Linux i686)

Revision  Changes    Path
1.5                  app-admin/smolt/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/smolt/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	2 Oct 2009 20:09:32 -0000	1.4
+++ ChangeLog	17 Feb 2010 00:53:03 -0000	1.5
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/smolt
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/smolt/ChangeLog,v 1.4 2009/10/02 20:09:32 sping Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/smolt/ChangeLog,v 1.5 2010/02/17 00:53:03 sping Exp $
+
+*smolt-1.4.2 (17 Feb 2010)
+
+  17 Feb 2010; Sebastian Pipping <sping@g.o> +smolt-1.4.2.ebuild:
+  Trivial-bump to 1.4.2
 
 *smolt-1.4 (02 Oct 2009)
 



1.1                  app-admin/smolt/smolt-1.4.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/smolt-1.4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/smolt-1.4.2.ebuild?rev=1.1&content-type=text/plain

Index: smolt-1.4.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/smolt/smolt-1.4.2.ebuild,v 1.1 2010/02/17 00:53:03 sping Exp $

EAPI="2"

inherit python eutils

DESCRIPTION="The Fedora hardware profiler"
HOMEPAGE="https://fedorahosted.org/smolt/"
SRC_URI="https://fedorahosted.org/releases/s/m/${PN}/${P}.tar.gz"

LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="qt4"

DEPEND="virtual/python
	sys-devel/gettext"

RDEPEND="${DEPEND}
	sys-apps/hal
	>=dev-python/rhpl-0.213
	>=dev-python/urlgrabber-3.0.0
	>=dev-python/simplejson-1.7.1
	dev-python/dbus-python
	qt4? ( dev-python/PyQt4 )"

S="${S}/client"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.4-upstream-{fix-gzip-calls,docdir}.patch
}

src_install() {
	emake install DESTDIR="${D}" DOCDIR="/usr/share/doc/${PF}" \
		|| die "Install failed"

	if ! use qt4; then
		rm "${D}"/usr/bin/smoltGui \
				"${D}"/usr/share/smolt/client/{gui,smoltGui}.py \
				"${D}"/usr/share/applications/smolt.desktop \
				"${D}"/usr/share/man/man1/smoltGui.1.* \
			|| die "rm failed"
		rmdir "${D}"/usr/share/applications || die "rmdir failed"
	fi

	bzip2 -9 "${D}"/usr/share/doc/${PF}/PrivacyPolicy || die "bzip2 failed"
	dodoc ../README ../TODO || die "dodoc failed"

	newinitd "${FILESDIR}"/${PN}-init.d ${PN} || die "newinitd failed"
}

pkg_postinst() {
	python_mod_optimize "${ROOT}"/usr/share/${PN}

	if ! [ -f "${ROOT}"/etc/smolt/hw-uuid ]; then
		elog "Creating this machines UUID in ${ROOT}/etc/smolt/hw-uuid"
		cat /proc/sys/kernel/random/uuid > "${ROOT}"/etc/smolt/hw-uuid
		UUID=$(cat "${ROOT}"/etc/smolt/hw-uuid)
		elog "Your UUID is: ${UUID}"
	fi
	echo
	elog "Call smoltSendProfile as root in order to initialize your profile."
	echo
	elog "You can withdraw it from the server if you wish to with"
	elog "   smoltDeleteProfile any time later on."
	echo

	if use qt4 && has_version "<virtual/python-2.5"; then
		elog "If you want to view your profile on the web from within smoltGui,"
		elog "you should have a link mozilla-firefox -> firefox in your path."
		echo
	fi
}

pkg_postrm() {
	python_mod_cleanup /usr/share/${PN}
}