[gentoo-commits] gentoo-x86 commit in lxde-base/lxpanel: ChangeLog lxpanel-0.5.7.ebuild lxpanel-0.5.4.1.ebuild lxpanel-0.5.5.ebuild lxpanel-0.5.3.ebuild

[Markos Chandras (hwoarang)]

hwoarang    11/07/26 22:34:58

  Modified:             ChangeLog
  Added:                lxpanel-0.5.7.ebuild
  Removed:              lxpanel-0.5.4.1.ebuild lxpanel-0.5.5.ebuild
                        lxpanel-0.5.3.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha46/cvs/Linux x86_64)

Revision  Changes    Path
1.30                 lxde-base/lxpanel/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/lxde-base/lxpanel/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/lxde-base/lxpanel/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/lxde-base/lxpanel/ChangeLog?r1=1.29&r2=1.30

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog	7 Mar 2011 20:31:34 -0000	1.29
+++ ChangeLog	26 Jul 2011 22:34:58 -0000	1.30
@@ -1,6 +1,13 @@
 # ChangeLog for lxde-base/lxpanel
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/ChangeLog,v 1.29 2011/03/07 20:31:34 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/ChangeLog,v 1.30 2011/07/26 22:34:58 hwoarang Exp $
+
+*lxpanel-0.5.7 (26 Jul 2011)
+
+  26 Jul 2011; Markos Chandras <hwoarang@g.o> -lxpanel-0.5.3.ebuild,
+  -files/lxpanel-0.5.3-battery.patch, -lxpanel-0.5.4.1.ebuild,
+  -lxpanel-0.5.5.ebuild, +lxpanel-0.5.7.ebuild:
+  Version bump
 
   07 Mar 2011; Tobias Klausmann <klausman@g.o> lxpanel-0.5.6.ebuild:
   Keyworded on alpha, bug #330911



1.1                  lxde-base/lxpanel/lxpanel-0.5.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/lxde-base/lxpanel/lxpanel-0.5.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/lxde-base/lxpanel/lxpanel-0.5.7.ebuild?rev=1.1&content-type=text/plain

Index: lxpanel-0.5.7.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/lxpanel-0.5.7.ebuild,v 1.1 2011/07/26 22:34:58 hwoarang Exp $

EAPI="4"

inherit autotools eutils

DESCRIPTION="Lightweight X11 desktop panel for LXDE"
HOMEPAGE="http://lxde.org/"
SRC_URI="mirror://sourceforge/lxde/${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~x86 ~x86-interix ~amd64-linux ~x86-linux"
SLOT="0"
IUSE="+alsa"
RESTRICT="test"  # bug 249598

RDEPEND="x11-libs/gtk+:2
	x11-libs/libXmu
	x11-libs/libXpm
	lxde-base/lxmenu-data
	lxde-base/menu-cache
	alsa? ( media-libs/alsa-lib )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.5.1-sandbox.patch
	epatch "${FILESDIR}"/${PN}-0.5.6-broken-apps.patch
	eautoreconf
}

src_configure() {
	local plugins=all
	[[ ${CHOST} == *-interix* ]] && plugins=deskno,kbled,xkb

	econf $(use_enable alsa) --with-x --with-plugins=${plugins}
	# the gtk+ dep already pulls in libX11, so we might as well hardcode with-x
}

src_install () {
	emake DESTDIR="${D}" install
	dodoc AUTHORS ChangeLog README

	# Get rid of the .la files.
	find "${D}" -name '*.la' -delete
}

pkg_postinst() {
	elog "If you have problems with broken icons shown in the main panel,"
	elog "you will have to configure panel settings via its menu."
	elog "This will not be an issue with first time installations."
}