[gentoo-commits] gentoo-x86 commit in app-dicts/verbiste: ChangeLog verbiste-0.1.38.ebuild verbiste-0.1.23.ebuild

[Gilles Dartiguelongue (eva)]

eva         13/09/01 10:57:40

  Modified:             ChangeLog
  Added:                verbiste-0.1.38.ebuild
  Removed:              verbiste-0.1.23.ebuild
  Log:
  Version bump. Clean up old revision.
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.39                 app-dicts/verbiste/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-dicts/verbiste/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-dicts/verbiste/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-dicts/verbiste/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-dicts/verbiste/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	20 May 2013 08:33:18 -0000	1.38
+++ ChangeLog	1 Sep 2013 10:57:39 -0000	1.39
@@ -1,6 +1,12 @@
 # ChangeLog for app-dicts/verbiste
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-dicts/verbiste/ChangeLog,v 1.38 2013/05/20 08:33:18 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-dicts/verbiste/ChangeLog,v 1.39 2013/09/01 10:57:39 eva Exp $
+
+*verbiste-0.1.38 (01 Sep 2013)
+
+  01 Sep 2013; Gilles Dartiguelongue <eva@g.o> -verbiste-0.1.23.ebuild,
+  +verbiste-0.1.38.ebuild:
+  Version bump. Clean up old revision.
 
   20 May 2013; Agostino Sarubbo <ago@g.o> verbiste-0.1.35.ebuild:
   Stable for x86, wrt bug #461056



1.1                  app-dicts/verbiste/verbiste-0.1.38.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-dicts/verbiste/verbiste-0.1.38.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-dicts/verbiste/verbiste-0.1.38.ebuild?rev=1.1&content-type=text/plain

Index: verbiste-0.1.38.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-dicts/verbiste/verbiste-0.1.38.ebuild,v 1.1 2013/09/01 10:57:39 eva Exp $

EAPI="5"

inherit eutils gnome2-utils fdo-mime

DESCRIPTION="French conjugation system"
HOMEPAGE="http://sarrazip.com/dev/verbiste.html"
SRC_URI="http://sarrazip.com/dev/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~x86"

IUSE="gnome gtk"

RDEPEND="
	>=dev-libs/libxml2-2.4.0:2
	gtk? ( >=x11-libs/gtk+-2.6:2 )
	gnome? (
		gnome-base/gnome-panel[bonobo]
		>=gnome-base/libgnomeui-2.0 )
"
DEPEND="${RDEPEND}
	sys-devel/gettext
	virtual/pkgconfig
"

src_configure() {
	econf \
		--with-console-app \
		$(use_with gtk gtk-app) \
		$(use_with gnome gnome-app) \
		$(use_with gnome gnome-applet)
}

src_install() {
	default
	prune_libtool_files
	dodoc HACKING LISEZMOI
	# file is only installed with USE=gnome
	if use gtk && ! use gnome ; then
		sed -e 's/Exec=.*/Exec=verbiste-gtk/' \
			-i src/gnome/verbiste.desktop || die
		insinto usr/share/applications
		doins src/gnome/verbiste.desktop
	fi
}

pkg_preinst() {
	if use gtk || use gnome ; then
		gnome2_icon_savelist
	fi
}

pkg_postinst() {
	if use gtk || use gnome ; then
		fdo-mime_desktop_database_update
		fdo-mime_mime_database_update
		gnome2_icon_cache_update
	fi
}

pkg_postrm() {
	if use gtk || use gnome ; then
		fdo-mime_desktop_database_update
		fdo-mime_mime_database_update
		gnome2_icon_cache_update
	fi
}