[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     79673d8c159ab26d8a1ca5b38a003836a0289c4a
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 17 03:56:34 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Jul 17 03:56:34 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=79673d8c

sys-kernel/gentoo-kernel-bin: bump to 5.4.132-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.4.132-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 647b8128be4..ccf21d7fe86 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -57,6 +57,7 @@ DIST gentoo-kernel-5.4.131-1.amd64.xpak 61358364 BLAKE2B 198334bf55e0b55316d6e03
 DIST gentoo-kernel-5.4.131-1.arm64.xpak 56106784 BLAKE2B 927c175773ca2897140764a5d5558818b51de95596c7a87f8cf42127f0698735e06e34458537d334810287d020aba039fe57863d2f78691de5caa90f031cca9b SHA512 205fd52209234d26857eb962e1ea956ea5e7c44852663cb1e0a63a095e35f30a0448eb15c8a5ebda53129b4054c5172fe9db88c544ab842c5611dc4150d535a4
 DIST gentoo-kernel-5.4.131-1.x86.xpak 53137168 BLAKE2B 3b7a631de49d5ba7de28e839bb5c67218b7e2f13ad051efde3d9b70142be81636e21d0d3cf48b94911851e5dab38db523e552a52034aa8901bc331fea86127ae SHA512 49a7e2eef8572a51c9cdf24f16908d4527fa5d27db4a673fcea03277864fde724d92e667d4cb4ae0dea0d92a783720c19d5a5160439dcbe404694236a02a5b90
 DIST gentoo-kernel-5.4.132-1.amd64.xpak 61362216 BLAKE2B a298c4bb4f756cf0f1d27416b1737a9e263648f4bb8220c97e8b8733ffd4758406b00678e5e5b1996a22f8a8a18d728dc41f749602924d7e8b74221aac9b05fc SHA512 80d4a79e8df63a57fe66437aab0850e2f6617791571abd142282abcd1c961fddb73b7ab5beb60e24c903bb1fe38b6433c2cd4afdfcf5de3de3cf81e3023eba6a
+DIST gentoo-kernel-5.4.132-1.arm64.xpak 56070122 BLAKE2B ae7f2da1bbfd0eb682503a5c5b61f8642fcca276c8ebb3fbb67a81620fb0c2969ec42d9079d4067e16738d0ab5f15eb70993bf152453799acc4fe6b7a4d85391 SHA512 a49284da190cb8c633c457698f46fac8287122f774f45f6662970c281a8dafac536bc3a42b6a7720d834d4c9427685a0ed9b08ef2710a6a4ffcb2887e1b6b2e6
 DIST gentoo-kernel-5.4.132-1.x86.xpak 53136062 BLAKE2B 79c432723db6a8e0d38a2f9d01611e91a76b1ed9de959177e10325b14854786629785685226b1107454a6c7088386695c75f4157b3d164e226c64b322ac63684 SHA512 671bfce54c06eb0957db4db797a7768664be911388583626a013a57fc2f5ab2bd2b4d92063563d38a0659cc912c8b8e114971dcd3ec7b66da8be65224bbe695d
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.12.tar.xz 118112412 BLAKE2B 842d921b9a73d2aaade763dbd2ec67bdfe0275baa6d628b775f5c87574ad7dc86f0419afcd48c10c1235f4bffa16084243f2cf4556e6afcd391e975fe8ba530b SHA512 be03b6fee1d1ea8087b09874d27c0a602c0b04fd90ad38b975bd2c8455a07e83c29b56814aaf1389e82305fae0e4c2d1701075a7f0a7295dd28149f967ec5b3d

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.132-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.132-r1.ebuild
new file mode 100644
index 00000000000..b63276300c5
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.132-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}