[gentoo-commits] gentoo-x86 commit in sys-cluster/gearmand: gearmand-0.33.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    12/06/04 06:56:29

  Modified:             ChangeLog
  Added:                gearmand-0.33.ebuild
  Log:
  Version bump by Pavel; also update to EAPI=4. Init script update to use default stop() function and checkpath.
  
  (Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

Revision  Changes    Path
1.13                 sys-cluster/gearmand/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/gearmand/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/gearmand/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/gearmand/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/gearmand/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	14 Jan 2012 17:27:31 -0000	1.12
+++ ChangeLog	4 Jun 2012 06:56:29 -0000	1.13
@@ -1,6 +1,13 @@
 # ChangeLog for sys-cluster/gearmand
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/gearmand/ChangeLog,v 1.12 2012/01/14 17:27:31 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/gearmand/ChangeLog,v 1.13 2012/06/04 06:56:29 flameeyes Exp $
+
+*gearmand-0.33 (04 Jun 2012)
+
+  04 Jun 2012; Diego E. Pettenò <flameeyes@g.o> +files/gearmand.init.d.2,
+  +gearmand-0.33.ebuild:
+  Version bump by Pavel; also update to EAPI=4. Init script update to use
+  default stop() function and checkpath.
 
   14 Jan 2012; Kacper Kowalik <xarthisius@g.o> metadata.xml:
   tcmalloc is now global



1.1                  sys-cluster/gearmand/gearmand-0.33.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/gearmand/gearmand-0.33.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/gearmand/gearmand-0.33.ebuild?rev=1.1&content-type=text/plain

Index: gearmand-0.33.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/gearmand/gearmand-0.33.ebuild,v 1.1 2012/06/04 06:56:29 flameeyes Exp $

EAPI=4

inherit flag-o-matic libtool

DESCRIPTION="Generic framework to farm out work to other machines"
HOMEPAGE="http://www.gearman.org/"
SRC_URI="http://launchpad.net/gearmand/trunk/${PV}/+download/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug tcmalloc +memcache drizzle sqlite tokyocabinet postgres"

RDEPEND="dev-libs/libevent
	|| ( >=sys-apps/util-linux-2.16 <sys-libs/e2fsprogs-libs-1.41.8 )
	tcmalloc? ( dev-util/google-perftools )
	memcache? ( >=dev-libs/libmemcached-0.47 )
	drizzle? ( dev-db/drizzle )
	sqlite? ( dev-db/sqlite:3 )
	tokyocabinet? ( dev-db/tokyocabinet )
	postgres? ( >=dev-db/postgresql-base-9.0 )"
DEPEND="${RDEPEND}"

pkg_setup() {
	enewuser gearmand -1 -1 /dev/null nogroup
}

src_prepare() {
	elibtoolize
}

src_configure() {
	# Don't ever use --enable-assert since configure.ac is broken, and
	# only does --disable-assert correctly.
	 if use debug; then
		# Since --with-debug would turn off optimisations as well as
		# enabling debug, we just enable debug through the
		# preprocessor then.
		append-flags -DDEBUG
	else
		myconf="${myconf} --disable-assert"
	fi

	econf \
		--disable-static \
		--disable-dependency-tracking \
		--disable-mtmalloc \
		$(use_enable tcmalloc) \
		$(use_enable memcache libmemcached) \
		$(use_enable drizzle libdrizzle) \
		$(use_enable sqlite libsqlite3) \
		$(use_enable tokyocabinet libtokyocabinet) \
		$(use_enable postgres libpq)
}

src_test() {
	# Since libtool is stupid and doesn't discard /usr/lib64 from the
	# load path, we'd end up testing against the installed copy of
	# gearmand (bad).
	#
	# We thus cheat and "fix" the scripts by hand.
	sed -i -e '/LD_LIBRARY_PATH=/s|/usr/lib64:||' "${S}"/tests/*_test \
		|| die "test fixing failed"

	emake check
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc README AUTHORS ChangeLog

	newinitd "${FILESDIR}"/gearmand.init.d.2 gearmand
	newconfd "${FILESDIR}"/gearmand.conf.d gearmand

	find "${D}" -name '*.la' -delete || die
}

pkg_postinst() {
	elog ""
	elog "Unless you set the PERSISTENT_TABLE option in"
	elog "/etc/conf.d/gearmand, Gearmand will use table 'queue'."
	elog "If such table doesn't exist, Gearmand will create it for you"
	elog ""
}