[gentoo-commits] gentoo-x86 commit in sys-apps/udevil: udevil-0.2.9.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    12/06/29 22:37:17

  Modified:             ChangeLog
  Added:                udevil-0.2.9.ebuild
  Log:
  version bump by Elijah El Lazkani
  
  (Portage version: 2.2.0_alpha114/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  sys-apps/udevil/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/udevil/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/udevil/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/udevil/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/udevil/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	29 Jun 2012 22:34:47 -0000	1.3
+++ ChangeLog	29 Jun 2012 22:37:17 -0000	1.4
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/udevil
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/udevil/ChangeLog,v 1.3 2012/06/29 22:34:47 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/udevil/ChangeLog,v 1.4 2012/06/29 22:37:17 hasufell Exp $
+
+*udevil-0.2.9 (29 Jun 2012)
+
+  29 Jun 2012; Julian Ospald <hasufell@g.o> +udevil-0.2.9.ebuild:
+  version bump by Elijah El Lazkani
 
   29 Jun 2012; Julian Ospald <hasufell@g.o> udevil-0.2.8.ebuild:
   https -> http



1.1                  sys-apps/udevil/udevil-0.2.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/udevil/udevil-0.2.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/udevil/udevil-0.2.9.ebuild?rev=1.1&content-type=text/plain

Index: udevil-0.2.9.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/udevil/udevil-0.2.9.ebuild,v 1.1 2012/06/29 22:37:17 hasufell Exp $

EAPI=4

inherit eutils autotools user

DESCRIPTION="mount and unmount removable devices without a password"
HOMEPAGE="http://ignorantguru.github.com/udevil/"
SRC_URI="http://dev.gentoo.org/~hasufell/distfiles/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND=">=app-shells/bash-4.0
	sys-apps/util-linux
	>=sys-fs/udev-143
	virtual/acl"
DEPEND="${RDEPEND}
	dev-util/intltool
	sys-devel/gettext
	virtual/pkgconfig"

pkg_setup(){
	enewgroup plugdev
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-0.2.8-flags.patch"
	eautoreconf
}

src_configure() {
	econf \
		--with-setfacl-prog="$(type -P setfacl)"
}

src_install() {
	default
	fowners root:plugdev /usr/bin/udevil
	fperms 4754 /usr/bin/udevil
}

pkg_postinst() {
	einfo
	elog "Please add your user to the plugdev group"
	elog "to be able to use ${PN} as a user"
	elog
	elog "Optional dependencies:"
	elog "  gnome-extra/zenity (devmon popups)"
	elog "  net-fs/cifs-utils  (mounting samba shares)"
	elog "  net-fs/curlftpfs   (mounting ftp shares)"
	elog "  net-fs/nfs-utils   (mounting nfs shares)"
	elog "  sys-fs/sshfs-fuse  (mounting sftp shares)"
	elog "  virtual/eject      (eject via devmon)"
	if ! has_version 'sys-fs/udisks' ; then
		elog
		elog "When using ${PN} without udisks, and without the udisks-daemon running,"
		elog "you may need to enable kernel polling for device media changes to be detected."
		elog "See http://ignorantguru.github.com/${PN}/#polling"
		has_version '<sys-fs/udev-173' && ewarn "You need at least udev-173"
		kernel_is lt 2 6 38 && ewarn "You need at least kernel 2.6.38"
		einfo
	fi
}