[gentoo-commits] gentoo-x86 commit in sys-libs/libhugetlbfs: ChangeLog libhugetlbfs-2.6.ebuild

[Robin H. Johnson (robbat2)]

robbat2     09/10/31 07:59:56

  Modified:             ChangeLog
  Added:                libhugetlbfs-2.6.ebuild
  Log:
  Version bump so it can be used for new memcached fun. src_test needs some work still.
  (Portage version: 2.2_rc46/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  sys-libs/libhugetlbfs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/libhugetlbfs/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/libhugetlbfs/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/libhugetlbfs/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/libhugetlbfs/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -p -w -b -B -u -u -r1.2 -r1.3
--- ChangeLog	5 Feb 2008 21:39:00 -0000	1.2
+++ ChangeLog	31 Oct 2009 07:59:56 -0000	1.3
@@ -1,6 +1,13 @@
 # ChangeLog for sys-libs/libhugetlbfs
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/libhugetlbfs/ChangeLog,v 1.2 2008/02/05 21:39:00 tgall Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/libhugetlbfs/ChangeLog,v 1.3 2009/10/31 07:59:56 robbat2 Exp $
+
+*libhugetlbfs-2.6 (31 Oct 2009)
+
+  31 Oct 2009; Robin H. Johnson <robbat2@g.o>
+  +libhugetlbfs-2.6.ebuild, +files/libhugetlbfs-2.6-noexec-stack.patch:
+  Version bump so it can be used for new memcached fun. src_test needs some
+  work still.
 
 *libhugetlbfs-1.2 (5 Feb 2008)
 



1.1                  sys-libs/libhugetlbfs/libhugetlbfs-2.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/libhugetlbfs/libhugetlbfs-2.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/libhugetlbfs/libhugetlbfs-2.6.ebuild?rev=1.1&content-type=text/plain

Index: libhugetlbfs-2.6.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/libhugetlbfs/libhugetlbfs-2.6.ebuild,v 1.1 2009/10/31 07:59:56 robbat2 Exp $

EAPI=2
inherit eutils multilib toolchain-funcs

DESCRIPTION="easy hugepage access"
HOMEPAGE="http://libhugetlbfs.ozlabs.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE=""

DEPEND=""

# testsuite requires specific kernel options, and LOTS of free memory.
# with 16GiB of RAM available, I hit swap :-) - robbat2
RESTRICT=test

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.6-noexec-stack.patch
	sed -i \
		-e '/^PREFIX/s:/local::' \
		-e '1iBUILDTYPE = NATIVEONLY' \
		-e '1iV = 1' \
		-e "/^LIB\(32\)/s:=.*:= $(get_libdir):" \
		-e '/^CC\(32\|64\)/s:=.*:= $(CC):' \
		Makefile
	if [ "$(get_libdir)" == "lib64" ]; then
		sed -i \
			-e "/^LIB\(32\)/s:=.*:= lib32:" \
				Makefile
	fi
}

src_configure() {
	:
}

src_compile() {
	tc-export AR CC
	emake libs tools || die
}

src_install() {
	emake install DESTDIR="${D}" || die
	dodoc HOWTO NEWS README
	rm "${D}"/usr/bin/oprofile*
}

src_test() {
	emake tests || die "Failed to build tests"
	hugeadm='obj/hugeadm'
	${hugeadm} --create-mounts
	PAGESIZES="$(${hugeadm} --page-sizes-all)"
	MIN_HUGEPAGE_RAM=$((64*1024*1024))
	ALLOCATED=''
	for p in ${PAGESIZES} ; do
		pagecount=$((${MIN_HUGEPAGE_RAM}/${p}))
		${hugeadm} \
		--pool-pages-min ${p}:+${pagecount} \
		--pool-pages-max ${p}:+${pagecount} \
		&& ALLOCATED="${ALLOCATED} ${p}:${pagecount}" \
		|| die "Failed to set pages"
	done
	cd "${S}"/tests
	TESTOPTS="-t func"
	case $ARCH in
		amd64|ppc64)
			TESTOPTS="${TESTOPTS} -b 64"
			;;
		x86)
			TESTOPTS="${TESTOPTS} -b 32"
			;;
	esac
	./run_tests.py ${TESTOPTS}
	# TODO: undo the allocation here.
	for p in ${ALLOCATED} ; do
		:
	done
}