[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     26e176dd54accc84627e13bf3490d7f9c09977f1
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Nov  7 22:07:56 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Nov  7 22:07:56 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=26e176dd

sys-kernel/gentoo-kernel-bin: add 5.10.78-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.78-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 8b77cc7b794..64c85450def 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -43,6 +43,7 @@ DIST gentoo-kernel-5.10.77-1.amd64.xpak 65535606 BLAKE2B f6f9a289e77c9126a7b05cd
 DIST gentoo-kernel-5.10.77-1.arm64.xpak 60908355 BLAKE2B 99116acdfd9790281f2128d5cf54f97e27e38f7908cc9c1abe1751653e437560e865b89cafe3e292e5761ff3f4aeee95d02695447d0911d0d0491579fb22b8a7 SHA512 54c38926901b24199e90a744c1bd44c587cb6861aeafa787641a87c4382b41936e18e00ae460dd2ec7a3cdf3b13d9df58aed701bad548e5a1429b9c06be1703c
 DIST gentoo-kernel-5.10.77-1.x86.xpak 57261834 BLAKE2B 2c344b671b51ecff973dbe4fe62db1d541d76744268f867911037de8778af2c213302edf9f714a98eab0956d3031e7c12c4490eaf3a8c37d1b6826d6d14b81d9 SHA512 a6f071d54eefa72c3a6bb67fd09a4f6fe3e96b99fd4ec1d34be45d8eab0f6f690130c0d51c98e9d6b086c3bc8775592ca5e3fc3e993483e39f3562d8234c21cc
 DIST gentoo-kernel-5.10.78-1.amd64.xpak 65516317 BLAKE2B 444139b73822a88abf4ff033858cd4514f09c689bf68a24659477f5106b4faf89678ba7ed0b80c831d16456c04309bbfb1593cdcab9979991cf86052ffa9632b SHA512 4034c53b5c8f3dad7f8bcc146d3827978040daad6e05dbdd683202467a8ad62c29fa0d79236b1fdae404993f42ac301088f89605e4f6d32158cf867b498a8e62
+DIST gentoo-kernel-5.10.78-1.arm64.xpak 60916561 BLAKE2B 4994d703ca272c6ad296cf50c498e992a799e5129ff758c9797fbc4d29c5ddef3a865b529360b189c27c751213ac5f7d3822a9473f0596494c739ddedbdc6f95 SHA512 f1c9eb8fe6f3997ff90ddbcc9b7dcd6c7544edd69301da9e2e803a01d288c503269ec1295883975da3dbdc6928bd7a8e27f4037cfcb890545fe7d86db7df90d9
 DIST gentoo-kernel-5.10.78-1.x86.xpak 57263133 BLAKE2B d4f3ade0de191584fb2022aadf5223a917d77f8e0aaa885d919d22477230661a47c1e8849d5c78f3fd283097c2f509bf1e7db9e6a02bb8aa745a4a4fb45a1436 SHA512 340d4a59b417e872f0a2aab2b8b0a2ddaefd29abd3c51882f08bce93cfd72e44d2a4798e688a33e36162fb9cfc33b8c173fe0d4551e956ad7d4fec2ae7d2286b
 DIST gentoo-kernel-5.13.19-1.amd64.xpak 67338326 BLAKE2B d9e718a94bf9a341f5b57063cbde2f3f1f0ea6d03f1805051c084b792388789494a49786d643f1570871ca2b6366a206497aed83f9ed00837c542ac970a71fc6 SHA512 aea74f6f39861752f7a5dae16d955d541f65d3e7b8a0e5fba593011d9ca8583f3dd0964e76aa21daa6583d5d26e3616885aeca8a04dbba222e0aae2a85062b40
 DIST gentoo-kernel-5.13.19-1.arm64.xpak 62747957 BLAKE2B 1981ddb4e35d2210e1c678856ac58e088cd100ecbd70d2b5c88ffe8eb25b56f3f0c90e45d12adb74c7a0fb881dfd36b1d46d6fdfb837dbdff1881ded066b906d SHA512 d8c1e524a3e58def5352b3faae07c42074a2d67015cc62b9601e20bb9b7f29d44d2843e7771e0399e9150be1de2be2b28776f96f7fe75ba7ec4e8f2c31e1f715

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.78-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.78-r1.ebuild
new file mode 100644
index 00000000000..a76ca745a64
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.78-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 7 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}