[gentoo-commits] repo/gentoo:master commit in: dev-python/pyilmbase/

[Andreas Sturmlechner]

commit:     8e3eb85f19ac6d60b334dd63f6401fbe3bb4f300
Author:     Bernd Waibel <waebbl <AT> gmail <DOT> com>
AuthorDate: Sun Jul 26 08:00:55 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Aug  2 10:40:32 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e3eb85f

dev-python/pyilmbase: change to python-single-r1

The package is not fully python-r1 aware. The cmake configuration
files currently only support one python version, so switch to
inheriting python-single-r1 instead of python-r1.

Closes: https://bugs.gentoo.org/733858
Package-Manager: Portage-3.0.0, Repoman-2.3.23
Signed-off-by: Bernd Waibel <waebbl <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/16828
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-python/pyilmbase/pyilmbase-2.5.2-r1.ebuild | 59 ++++++++++++++++++++
 dev-python/pyilmbase/pyilmbase-2.5.2.ebuild    | 77 --------------------------
 2 files changed, 59 insertions(+), 77 deletions(-)

diff --git a/dev-python/pyilmbase/pyilmbase-2.5.2-r1.ebuild b/dev-python/pyilmbase/pyilmbase-2.5.2-r1.ebuild
new file mode 100644
index 00000000000..861ffa45e7c
--- /dev/null
+++ b/dev-python/pyilmbase/pyilmbase-2.5.2-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# boost is lacking py39 support as of 20200605
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit cmake python-single-r1
+
+DESCRIPTION="IlmBase Python bindings"
+HOMEPAGE="https://www.openexr.com"
+SRC_URI="https://github.com/AcademySoftwareFoundation/openexr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/25"
+KEYWORDS="~amd64 ~x86"
+IUSE="exceptions +numpy test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	~media-libs/ilmbase-${PV}:=
+	sys-libs/zlib
+	$(python_gen_cond_dep '
+		>=dev-libs/boost-1.62.0-r1:=[python,${PYTHON_MULTI_USEDEP}]
+		numpy? ( >=dev-python/numpy-1.10.4[${PYTHON_MULTI_USEDEP}] )
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/openexr-${PV}/PyIlmBase"
+
+PATCHES=(
+	"${FILESDIR}/${P}-0001-Fix-pkgconfig-file-for-PyIlmBase-to-include-prefixes.patch"
+)
+
+DOCS=( README.md )
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Python2=ON
+		-DPYILMBASE_INSTALL_PKG_CONFIG=ON
+		-DPYIMATH_ENABLE_EXCEPTIONS=$(usex exceptions)
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	if use numpy; then
+		python_domodule "${BUILD_DIR}/${EPYTHON/./_}/imathnumpy.so"
+		chmod +x "${D}/$(python_get_sitedir)/imathnumpy.so" || die
+	fi
+}

diff --git a/dev-python/pyilmbase/pyilmbase-2.5.2.ebuild b/dev-python/pyilmbase/pyilmbase-2.5.2.ebuild
deleted file mode 100644
index 0411b0530d8..00000000000
--- a/dev-python/pyilmbase/pyilmbase-2.5.2.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-# boost is lacking py39 support as of 20200605
-PYTHON_COMPAT=( python3_{6,7,8} )
-CMAKE_ECLASS=cmake
-inherit cmake-multilib python-r1
-
-DESCRIPTION="IlmBase Python bindings"
-HOMEPAGE="https://www.openexr.com"
-SRC_URI="https://github.com/AcademySoftwareFoundation/openexr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0/25"
-KEYWORDS="~amd64 ~x86"
-IUSE="exceptions +numpy test"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	${PYTHON_DEPS}
-	>=dev-libs/boost-1.62.0-r1:=[python,${MULTILIB_USEDEP},${PYTHON_USEDEP}]
-	~media-libs/ilmbase-${PV}:=[${MULTILIB_USEDEP}]
-	sys-libs/zlib[${MULTILIB_USEDEP}]
-	numpy? ( >=dev-python/numpy-1.10.4[${PYTHON_USEDEP}] )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="virtual/pkgconfig"
-
-S="${WORKDIR}/openexr-${PV}/PyIlmBase"
-
-PATCHES=(
-	"${FILESDIR}/${P}-0001-Fix-pkgconfig-file-for-PyIlmBase-to-include-prefixes.patch"
-)
-
-DOCS=( README.md )
-
-multilib_src_prepare() {
-	cmake_src_prepare
-	multilib_copy_sources
-}
-
-multilib_src_configure() {
-	python_configure() {
-		local mycmakeargs=(
-			-DCMAKE_DISABLE_FIND_PACKAGE_Python2=ON
-			-DPYILMBASE_INSTALL_PKG_CONFIG=ON
-			-DPYIMATH_ENABLE_EXCEPTIONS=$(usex exceptions)
-			-DPython3_EXECUTABLE="${PYTHON}"
-			-DPython3_INCLUDE_DIR=$(python_get_includedir)
-			-DPython3_LIBRARY=$(python_get_library_path)
-		)
-		cmake_src_configure
-	}
-	python_foreach_impl python_configure
-}
-
-multilib_src_compile() {
-	python_foreach_impl cmake_src_compile
-}
-
-multilib_src_install() {
-	python_install() {
-		cmake_src_install
-		if use numpy; then
-			python_domodule "${BUILD_DIR}/${EPYTHON/./_}/imathnumpy.so"
-			chmod +x "${D}/$(python_get_sitedir)/imathnumpy.so" || die
-		fi
-	}
-	python_foreach_impl python_install
-}
-
-multilib_src_test() {
-	python_foreach_impl cmake_src_test
-}