[gentoo-commits] gentoo-x86 commit in x11-libs/fltk: ChangeLog fltk-2.0_pre6483.ebuild

[Ben de Groot (yngwin)]

yngwin      08/10/30 18:18:13

  Modified:             ChangeLog
  Added:                fltk-2.0_pre6483.ebuild
  Log:
  New snapshot version
  (Portage version: 2.2_rc12_p11688/cvs/Linux 2.6.26-hh3 i686)

Revision  Changes    Path
1.99                 x11-libs/fltk/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/fltk/ChangeLog?rev=1.99&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/fltk/ChangeLog?rev=1.99&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/fltk/ChangeLog?r1=1.98&r2=1.99

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/fltk/ChangeLog,v
retrieving revision 1.98
retrieving revision 1.99
diff -u -r1.98 -r1.99
--- ChangeLog	21 Oct 2008 13:50:51 -0000	1.98
+++ ChangeLog	30 Oct 2008 18:18:13 -0000	1.99
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/fltk
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/fltk/ChangeLog,v 1.98 2008/10/21 13:50:51 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/fltk/ChangeLog,v 1.99 2008/10/30 18:18:13 yngwin Exp $
+
+*fltk-2.0_pre6483 (30 Oct 2008)
+
+  30 Oct 2008; Ben de Groot <yngwin@g.o> +fltk-2.0_pre6483.ebuild:
+  New snapshot version
 
 *fltk-2.0_pre6403 (21 Oct 2008)
 



1.1                  x11-libs/fltk/fltk-2.0_pre6483.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/fltk/fltk-2.0_pre6483.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/fltk/fltk-2.0_pre6483.ebuild?rev=1.1&content-type=text/plain

Index: fltk-2.0_pre6483.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/fltk/fltk-2.0_pre6483.ebuild,v 1.1 2008/10/30 18:18:13 yngwin Exp $

EAPI="1"
inherit multilib autotools flag-o-matic

MY_P=${P/_pre/.x-r}
DESCRIPTION="C++ user interface toolkit for X and OpenGL"
HOMEPAGE="http://www.fltk.org/"
SRC_URI="mirror://easysw/fltk/snapshots/${MY_P}.tar.bz2"

KEYWORDS="~amd64 ~x86"
LICENSE="FLTK LGPL-2"
SLOT="2"
IUSE="cairo debug doc +jpeg +png opengl +xft xinerama zlib"

RDEPEND="x11-libs/libXext
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libXt
	xft? ( virtual/xft )
	png? ( media-libs/libpng )
	jpeg? ( media-libs/jpeg )
	opengl? ( virtual/opengl )
	cairo? ( x11-libs/cairo )
	xinerama? ( x11-libs/libXinerama )
	zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
	x11-proto/xextproto
	xinerama? ( x11-proto/xineramaproto )
	doc? ( app-doc/doxygen )"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/fltk2-config.patch
	use opengl || epatch "${FILESDIR}"/fltk2-nogl.patch
	eautoreconf
}

src_compile() {
	append-flags -fno-strict-aliasing

	CPPFLAGS="${CPPFLAGS} -DFLTK_DOCDIR=\"/usr/share/doc/${PF}\"" \
	econf --enable-shared --enable-threads \
		$(use_enable debug) \
		$(use_enable xft) \
		$(use_enable opengl gl) \
		$(use_enable cairo) \
		$(use_enable jpeg) \
		$(use_enable png) \
		$(use_enable xinerama) \
		$(use_enable zlib) \
		|| die "configure failed"

	emake || die "make failed"
	use doc && make -C documentation
}

src_install() {
	einstall includedir="${D}/usr/include" \
		libdir="${D}/usr/$(get_libdir)/fltk" || die "install failed"

	if use doc; then
		emake -C documentation install || die "install documentation failed"
		dohtml documentation/html
	fi
	dodoc CHANGES CREDITS README* TODO

	echo "LDPATH=/usr/$(get_libdir)/fltk" > 99fltk-${SLOT}
	echo "FLTK_DOCDIR=/usr/share/doc/${PF}/html" >> 99fltk-${SLOT}

	doenvd 99fltk-${SLOT}
}