[gentoo-commits] proj/gnome:master commit in: gnome-base/nautilus/

[Gilles Dartiguelongue]

commit:     d92f9bae154cc8e4f54e203ca3ef368c3533f204
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sat Dec  1 17:30:53 2018 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sat Dec  1 17:41:29 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=d92f9bae

gnome-base/nautilus: sync live ebuild

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Manifest-Sign-Key: 0x5A56C8CD0C13248A
Signed-off-by: Gilles Dartiguelongue <eva <AT> gentoo.org>

 gnome-base/nautilus/nautilus-9999.ebuild | 89 +++++++++++++++-----------------
 1 file changed, 43 insertions(+), 46 deletions(-)

diff --git a/gnome-base/nautilus/nautilus-9999.ebuild b/gnome-base/nautilus/nautilus-9999.ebuild
index 7b1340d5..f49bf82c 100644
--- a/gnome-base/nautilus/nautilus-9999.ebuild
+++ b/gnome-base/nautilus/nautilus-9999.ebuild
@@ -1,12 +1,14 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
 GNOME2_LA_PUNT="yes" # Needed with USE 'sendto'
 
-inherit gnome2 readme.gentoo-r1 virtualx
+inherit gnome.org gnome2-utils meson readme.gentoo-r1 virtualx xdg
 if [[ ${PV} = 9999 ]]; then
-	inherit gnome2-live
+	inherit git-r3
+	SRC_URI=""
+	EGIT_SRC_URI="https://gitlab.gnome.org/GNOME/${PN}"
 fi
 
 DESCRIPTION="A file manager for the GNOME desktop"
@@ -14,14 +16,9 @@ HOMEPAGE="https://wiki.gnome.org/Apps/Nautilus"
 
 LICENSE="GPL-2+ LGPL-2+ FDL-1.1"
 SLOT="0"
-IUSE="exif gnome +introspection packagekit +previewer selinux sendto tracker xmp"
+IUSE="exif gnome gtk-doc +introspection packagekit +previewer selinux sendto tracker xmp"
 
-if [[ ${PV} = 9999 ]]; then
-	IUSE="${IUSE} doc"
-	KEYWORDS=""
-else
-	KEYWORDS="~amd64 ~arm64 ~ia64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
-fi
+KEYWORDS=""
 
 # FIXME: tests fails under Xvfb, but pass when building manually
 # "FAIL: check failed in nautilus-file.c, line 8307"
@@ -31,55 +28,46 @@ RESTRICT="test"
 # Require {glib,gdbus-codegen}-2.30.0 due to GDBus API changes between 2.29.92
 # and 2.30.0
 COMMON_DEPEND="
-	>=app-arch/gnome-autoar-0.1
-	>=dev-libs/glib-2.49.1:2[dbus]
+	>=app-arch/gnome-autoar-0.2.1
+	>=dev-libs/glib-2.51.2:2[dbus]
 	>=x11-libs/pango-1.28.3
-	>=x11-libs/gtk+-3.21.6:3[introspection?]
+	>=x11-libs/gtk+-3.22.6:3[introspection?]
 	>=dev-libs/libxml2-2.7.8:2
 	>=gnome-base/gnome-desktop-3:3=
 
-	gnome-base/dconf
 	>=gnome-base/gsettings-desktop-schemas-3.8.0
 	x11-libs/libX11
-	x11-libs/libXext
-	x11-libs/libXrender
 
 	exif? ( >=media-libs/libexif-0.6.20 )
 	introspection? ( >=dev-libs/gobject-introspection-0.6.4:= )
 	selinux? ( >=sys-libs/libselinux-2 )
-	tracker? ( >=app-misc/tracker-0.16:= )
+	tracker? ( >=app-misc/tracker-2:= )
 	xmp? ( >=media-libs/exempi-2.1.0:2 )
 "
 DEPEND="${COMMON_DEPEND}
-	>=dev-lang/perl-5
 	>=dev-util/gdbus-codegen-2.33
-	>=dev-util/gtk-doc-am-1.10
 	>=sys-devel/gettext-0.19.7
 	virtual/pkgconfig
 	x11-base/xorg-proto
+
+	gtk-doc? ( dev-util/gtk-doc )
 "
 RDEPEND="${COMMON_DEPEND}
+	gnome-base/dconf
 	packagekit? ( app-admin/packagekit-base )
 	sendto? ( !<gnome-extra/nautilus-sendto-3.0.1 )
 "
-
-# For eautoreconf
-#	gnome-base/gnome-common
-#	dev-util/gtk-doc-am"
-
 PDEPEND="
 	gnome? ( x11-themes/adwaita-icon-theme )
-	tracker? ( >=gnome-extra/nautilus-tracker-tags-0.12 )
 	previewer? ( >=gnome-extra/sushi-0.1.9 )
 	sendto? ( >=gnome-extra/nautilus-sendto-3.0.1 )
-	>=gnome-base/gvfs-1.14[gtk]
+	>=gnome-base/gvfs-1.34
 "
-# Need gvfs[gtk] for recent:/// support
 
-if [[ ${PV} = 9999 ]]; then
-	DEPEND="${DEPEND}
-		doc? ( >=dev-util/gtk-doc-1.4 )"
-fi
+PATCHES=(
+	# Keep tracker optional
+	"${FILESDIR}"/${PV}-tracker-support-optional.patch
+)
 
 src_prepare() {
 	if use previewer; then
@@ -87,34 +75,37 @@ src_prepare() {
 			To activate the previewer, select a file and press space; to
 			close the previewer, press space again."
 	fi
-	gnome2_src_prepare
+	xdg_src_prepare
 }
 
 src_configure() {
-	gnome2_src_configure \
-		--enable-desktop \
-		--disable-profiling \
-		--disable-update-mimedb \
-		$(use_enable exif libexif) \
-		$(use_enable introspection) \
-		$(use_enable packagekit) \
-		$(use_enable sendto nst-extension) \
-		$(use_enable selinux) \
-		$(use_enable tracker) \
-		$(use_enable xmp)
+	local emesonargs=(
+		"-Denable-desktop=true"
+		"-Denable-profiling=false"
+		"-Dtracker=$(usex tracker auto disabled)"
+		$(meson_use gtk-doc enable-gtk-doc)
+		$(meson_use exif enable-exif)
+		$(meson_use packagekit enable-packagekit)
+		$(meson_use sendto enable-nst-extension)
+		$(meson_use selinux enable-selinux)
+		$(meson_use xmp enable-xmp)
+	)
+	meson_src_configure
 }
 
 src_test() {
-	virtx emake check
+	virtx meson_src_test
 }
 
 src_install() {
 	use previewer && readme.gentoo_create_doc
-	gnome2_src_install
+	meson_src_install
 }
 
 pkg_postinst() {
-	gnome2_pkg_postinst
+	xdg_pkg_postinst
+	gnome2_icon_cache_update
+	gnome2_schemas_update
 
 	if use previewer; then
 		readme.gentoo_print_elog
@@ -122,3 +113,9 @@ pkg_postinst() {
 		elog "To preview media files, emerge nautilus with USE=previewer"
 	fi
 }
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}