[gentoo-commits] repo/gentoo:master commit in: sys-devel/lld/

[Michał Górny]

commit:     012e6f108662056e07126c8241da07303a91ea7e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Feb  3 15:39:20 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Feb  3 15:44:07 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=012e6f10

sys-devel/lld: Remove 13.0.1.9999

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 sys-devel/lld/lld-13.0.1.9999.ebuild | 73 ------------------------------------
 1 file changed, 73 deletions(-)

diff --git a/sys-devel/lld/lld-13.0.1.9999.ebuild b/sys-devel/lld/lld-13.0.1.9999.ebuild
deleted file mode 100644
index 863c9b49bdb9..000000000000
--- a/sys-devel/lld/lld-13.0.1.9999.ebuild
+++ /dev/null
@@ -1,73 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{8..10} )
-inherit cmake flag-o-matic llvm llvm.org python-any-r1
-
-DESCRIPTION="The LLVM linker (link editor)"
-HOMEPAGE="https://llvm.org/"
-
-LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
-SLOT="0"
-KEYWORDS=""
-IUSE="debug test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="~sys-devel/llvm-${PV}"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	test? (
-		>=dev-util/cmake-3.16
-		$(python_gen_any_dep "~dev-python/lit-${PV}[\${PYTHON_USEDEP}]")
-	)"
-
-LLVM_COMPONENTS=( lld libunwind/include/mach-o )
-LLVM_TEST_COMPONENTS=( llvm/utils/{lit,unittest} )
-llvm.org_set_globals
-
-python_check_deps() {
-	has_version -b "dev-python/lit[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
-	use test && python-any-r1_pkg_setup
-}
-
-src_unpack() {
-	llvm.org_src_unpack
-
-	# Directory ${WORKDIR}/llvm does not exist with USE="-test",
-	# but LLVM_MAIN_SRC_DIR="${WORKDIR}/llvm" is set below,
-	# and ${LLVM_MAIN_SRC_DIR}/../libunwind/include is used by build system
-	# (lld/MachO/CMakeLists.txt) and is expected to be resolvable
-	# to existent directory ${WORKDIR}/libunwind/include.
-	mkdir -p "${WORKDIR}/llvm" || die
-}
-
-src_configure() {
-	# LLVM_ENABLE_ASSERTIONS=NO does not guarantee this for us, #614844
-	use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
-
-	use elibc_musl && append-ldflags -Wl,-z,stack-size=2097152
-
-	local mycmakeargs=(
-		-DBUILD_SHARED_LIBS=ON
-		-DLLVM_INCLUDE_TESTS=$(usex test)
-		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
-	)
-	use test && mycmakeargs+=(
-		-DLLVM_BUILD_TESTS=ON
-		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
-		-DLLVM_LIT_ARGS="$(get_lit_flags)"
-		-DPython3_EXECUTABLE="${PYTHON}"
-	)
-	cmake_src_configure
-}
-
-src_test() {
-	local -x LIT_PRESERVES_TMP=1
-	cmake_build check-lld
-}