[gentoo-commits] repo/gentoo:master commit in: sys-libs/libieee1284/

[Michał Górny]

commit:     5acd3b7460ed72b77d2757695f4c7270ce725334
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 25 21:12:57 2016 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jun 25 21:13:08 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5acd3b74

sys-libs/libieee1284: Convert to python-single-r1, EAPI 6

 sys-libs/libieee1284/libieee1284-0.2.11-r4.ebuild | 49 +++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/sys-libs/libieee1284/libieee1284-0.2.11-r4.ebuild b/sys-libs/libieee1284/libieee1284-0.2.11-r4.ebuild
new file mode 100644
index 0000000..e0bf541
--- /dev/null
+++ b/sys-libs/libieee1284/libieee1284-0.2.11-r4.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 )
+inherit eutils python-single-r1 multilib-minimal
+
+DESCRIPTION="Library to query devices using IEEE1284"
+HOMEPAGE="http://cyberelk.net/tim/libieee1284/index.html"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+IUSE="doc python static-libs"
+
+RDEPEND="abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r9
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	doc? (
+		app-text/docbook-sgml-utils
+		>=app-text/docbook-sgml-dtd-4.1
+		app-text/docbook-dsssl-stylesheets
+		dev-perl/XML-RegExp
+	)"
+
+DOCS="AUTHORS NEWS README* TODO doc/interface*"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local myconf="--without-python"
+	multilib_is_native_abi && myconf="$(use_with python)"
+
+	ECONF_SOURCE="${S}" econf \
+		--enable-shared \
+		$(use_enable static-libs static) \
+		${myconf}
+}
+
+multilib_src_install_all() {
+	prune_libtool_files --all
+	einstalldocs
+}