[gentoo-commits] gentoo-x86 commit in games-roguelike/crossfire-client: ChangeLog crossfire-client-1.70.0-r1.ebuild

[Julian Ospald (hasufell)]

hasufell    13/01/28 08:24:58

  Modified:             ChangeLog
  Added:                crossfire-client-1.70.0-r1.ebuild
  Log:
  fix underlinking wrt #451286
  
  (Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.36                 games-roguelike/crossfire-client/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/crossfire-client/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/crossfire-client/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/crossfire-client/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-roguelike/crossfire-client/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	13 Jan 2013 11:38:41 -0000	1.35
+++ ChangeLog	28 Jan 2013 08:24:58 -0000	1.36
@@ -1,6 +1,13 @@
 # ChangeLog for games-roguelike/crossfire-client
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-roguelike/crossfire-client/ChangeLog,v 1.35 2013/01/13 11:38:41 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/crossfire-client/ChangeLog,v 1.36 2013/01/28 08:24:58 hasufell Exp $
+
+*crossfire-client-1.70.0-r1 (28 Jan 2013)
+
+  28 Jan 2013; Julian Ospald <hasufell@g.o>
+  +crossfire-client-1.70.0-r1.ebuild,
+  +files/crossfire-client-1.70.0-gold.patch:
+  fix underlinking wrt #451286
 
   13 Jan 2013; Agostino Sarubbo <ago@g.o> crossfire-client-1.70.0.ebuild:
   Stable for x86, wrt bug #450790



1.1                  games-roguelike/crossfire-client/crossfire-client-1.70.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/crossfire-client/crossfire-client-1.70.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/crossfire-client/crossfire-client-1.70.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: crossfire-client-1.70.0-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-roguelike/crossfire-client/crossfire-client-1.70.0-r1.ebuild,v 1.1 2013/01/28 08:24:58 hasufell Exp $

EAPI=5
inherit autotools eutils toolchain-funcs gnome2-utils games

DESCRIPTION="Client for the nethack-style but more in the line of UO"
HOMEPAGE="http://crossfire.real-time.com/"
SRC_URI="mirror://sourceforge/crossfire/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="alsa lua oss sdl"

RDEPEND="alsa? ( media-libs/alsa-lib )
	virtual/opengl
	x11-libs/gtk+:2
	gnome-base/libglade
	sdl? ( media-libs/libsdl[video]
		media-libs/sdl-image )
	lua? ( dev-lang/lua )
	net-misc/curl
	media-libs/freeglut
	media-libs/libpng:0
	sys-libs/zlib"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	sed -ri -e '/^.TH/s:$: 6:' $(find . -name "*man") || die
	epatch "${FILESDIR}"/${P}-gold.patch
	eautoreconf
}

src_configure() {
	# bugs in configure script so we cant use $(use_enable ...)
	local myconf

	use sdl || myconf="${myconf} --disable-sdl"
	use alsa || myconf="${myconf} --disable-alsa9 --disable-alsa"
	if ! use alsa && ! use oss ; then
		myconf="${myconf} --disable-sound"
	fi
	egamesconf ${myconf}
}

src_compile() {
	# bug 139785
	if use alsa || use oss ; then
		emake -j1 -C sound-src AR="$(tc-getAR)"
	fi
	emake AR="$(tc-getAR)"
}

src_install() {
	local s

	emake DESTDIR="${D}" install
	dodoc AUTHORS ChangeLog README TODO
	domenu gtk-v2/crossfire-client.desktop
	for s in 16 32 48
	do
		newicon -s ${s} pixmaps/${s}x${s}.png ${PN}.png
	done
	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}