[gentoo-commits] gentoo-x86 commit in media-sound/jtagger: ChangeLog jtagger-2008.04.28.ebuild

[Serkan Kaba (serkan)]

serkan      08/05/28 21:07:37

  Modified:             ChangeLog
  Added:                jtagger-2008.04.28.ebuild
  Log:
  Version bump. Fixes bug #220189.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.5                  media-sound/jtagger/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/jtagger/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/jtagger/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/jtagger/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/jtagger/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	9 May 2008 21:00:59 -0000	1.4
+++ ChangeLog	28 May 2008 21:07:36 -0000	1.5
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/jtagger
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/jtagger/ChangeLog,v 1.4 2008/05/09 21:00:59 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/jtagger/ChangeLog,v 1.5 2008/05/28 21:07:36 serkan Exp $
+
+*jtagger-2008.04.28 (28 May 2008)
+
+  28 May 2008; Serkan Kaba <serkan@g.o> +jtagger-2008.04.28.ebuild:
+  Version bump. Fixes bug #220189.
 
   09 May 2008; Christian Faulhammer <opfer@g.o>
   jtagger-2008.01.ebuild:



1.1                  media-sound/jtagger/jtagger-2008.04.28.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/jtagger/jtagger-2008.04.28.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/jtagger/jtagger-2008.04.28.ebuild?rev=1.1&content-type=text/plain

Index: jtagger-2008.04.28.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/jtagger/jtagger-2008.04.28.ebuild,v 1.1 2008/05/28 21:07:36 serkan Exp $

EAPI="1"

JAVA_PKG_IUSE="source test"

inherit eutils java-pkg-2

DESCRIPTION="Powerful MP3 tag and filename editor"
HOMEPAGE="http://dronten.googlepages.com/jtagger"
SRC_URI="http://dronten.googlepages.com/${P}.zip"

LICENSE="GPL-3"
KEYWORDS="~amd64 ~x86"
IUSE=""
SLOT="0"

COMMON_DEP="
	dev-java/jlayer
	>=dev-java/jid3-0.46-r1"
RDEPEND=">=virtual/jre-1.5
	${COMMON_DEP}"

DEPEND="${COMMON_DEP}
	>=virtual/jdk-1.5
	app-arch/unzip
	test? ( dev-java/junit:0 )"

src_unpack() {
	mkdir -p "${S}/src" || die
	cd "${S}/src" || die

	unpack ${A}
	unzip -q ${PN}.jar || die

	rm -vr ${PN}.jar javazoom  org META-INF || die
	find . -name '*.class' -delete || die

	# Move the tests away
	mkdir -p ../test/com/googlepages/dronten/jtagger || die
	mv com/googlepages/dronten/jtagger/test \
		../test/com/googlepages/dronten/jtagger/test || die
}

src_compile() {
	local classpath="$(java-pkg_getjars jid3,jlayer)"

	cd "${S}/src"
	find . -name '*.java' > sources.list
	ejavac -encoding latin1 -cp "${classpath}" @sources.list

	find . -name '*.class' -o -name '*.png' > classes.list
	touch myManifest
	jar cmf myManifest ${PN}.jar @classes.list || die "jar failed"
}

src_test() {
	cd "${S}/test"

	local cp=".:${S}/src/${PN}.jar:$(java-pkg_getjars jid3,jlayer)"
	cp="${cp}:$(java-pkg_getjars --build-only junit)"

	find . -name '*.java' > sources.list
	ejavac -cp "${cp}" @sources.list
	ejunit -cp "${cp}" \
		com.googlepages.dronten.jtagger.test.TestRenameAlbum \
		com.googlepages.dronten.jtagger.test.TestRenameFile \
		com.googlepages.dronten.jtagger.test.TestRenameTitle
}

src_install() {
	java-pkg_dojar src/${PN}.jar
	java-pkg_dolauncher jtagger --main com.googlepages.dronten.jtagger.JTagger

	use source && java-pkg_dosrc src/com

	newicon src/com/googlepages/dronten/jtagger/resource/jTagger.icon.png ${PN}.png
	make_desktop_entry jtagger "jTagger MP3 tag editor"
}



-- 
gentoo-commits@l.g.o mailing list