[gentoo-commits] proj/gnome:master commit in: gnome-base/gnome-desktop/

[Sobhan Mohammadpour]

commit:     dd652554928f7e52b14e9e59bfa3c7fb15978e71
Author:     Sobhan Mohammadpour <sobhan <AT> gentoo <DOT> org>
AuthorDate: Fri Feb  9 15:46:02 2018 +0000
Commit:     Sobhan Mohammadpour <sobhan <AT> gentoo <DOT> org>
CommitDate: Fri Feb  9 15:46:02 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=dd652554

gnome-base/gnome-desktop: bump

Package-Manager: Portage-2.3.23, Repoman-2.3.6
Manifest-Sign-Key: 0x7DF238CF0AA182E1

 .../gnome-desktop/gnome-desktop-3.26.2.ebuild      | 59 ++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/gnome-base/gnome-desktop/gnome-desktop-3.26.2.ebuild b/gnome-base/gnome-desktop/gnome-desktop-3.26.2.ebuild
new file mode 100644
index 00000000..31b0c59a
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-3.26.2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2 virtualx
+
+DESCRIPTION="Libraries for the gnome desktop that are not part of the UI"
+HOMEPAGE="https://git.gnome.org/browse/gnome-desktop"
+
+LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
+SLOT="3/12" # subslot = libgnome-desktop-3 soname version
+IUSE="debug +introspection udev"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x86-solaris"
+
+# cairo[X] needed for gnome-bg
+COMMON_DEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.53.0:2[dbus]
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[X,introspection?]
+	x11-libs/cairo:=[X]
+	x11-libs/libX11
+	x11-misc/xkeyboard-config
+	>=gnome-base/gsettings-desktop-schemas-3.5.91
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
+	udev? (
+		sys-apps/hwids
+		virtual/libudev:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-desktop-2.32.1-r1:2[doc]
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.14
+	>=dev-util/intltool-0.40.6
+	dev-util/itstool
+	sys-devel/gettext
+	x11-proto/xproto
+	virtual/pkgconfig
+"
+
+# Includes X11/Xatom.h in libgnome-desktop/gnome-bg.c which comes from xproto
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--with-gnome-distributor=Gentoo \
+		--enable-desktop-docs \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable debug debug-tools) \
+		$(use_enable introspection) \
+		$(use_enable udev)
+}
+
+src_test() {
+	virtx emake check
+}