[gentoo-commits] gentoo-x86 commit in app-arch/tar: ChangeLog tar-1.27.1.ebuild tar-1.26.ebuild tar-1.25-r1.ebuild tar-1.25.ebuild tar-1.23-r4.ebuild tar-1.23-r2.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    13/11/25 12:20:59

  Modified:             ChangeLog
  Added:                tar-1.27.1.ebuild
  Removed:              tar-1.26.ebuild tar-1.25-r1.ebuild tar-1.25.ebuild
                        tar-1.23-r4.ebuild tar-1.23-r2.ebuild
  Log:
  Version bump. Removed old
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.194                app-arch/tar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/tar/ChangeLog?rev=1.194&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/tar/ChangeLog?rev=1.194&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/tar/ChangeLog?r1=1.193&r2=1.194

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/tar/ChangeLog,v
retrieving revision 1.193
retrieving revision 1.194
diff -u -r1.193 -r1.194
--- ChangeLog	24 Oct 2013 06:45:16 -0000	1.193
+++ ChangeLog	25 Nov 2013 12:20:59 -0000	1.194
@@ -1,6 +1,16 @@
 # ChangeLog for app-arch/tar
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/tar/ChangeLog,v 1.193 2013/10/24 06:45:16 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/tar/ChangeLog,v 1.194 2013/11/25 12:20:59 polynomial-c Exp $
+
+*tar-1.27.1 (25 Nov 2013)
+
+  25 Nov 2013; Lars Wendler <polynomial-c@g.o> -tar-1.23-r2.ebuild,
+  -tar-1.23-r4.ebuild, -tar-1.25.ebuild, -tar-1.25-r1.ebuild, -tar-1.26.ebuild,
+  +tar-1.27.1.ebuild, -files/tar-1.23-revert-pipe.patch,
+  -files/tar-1.23-strncpy.patch, -files/tar-1.23-symlink-k-hang.patch,
+  -files/tar-1.23-tests.patch, -files/tar-1.25-incremental-fix.patch,
+  -files/tar-1.25-verify-check.patch, -files/tar-1.25-verify-fix.patch:
+  Version bump. Removed old.
 
 *tar-1.27-r2 (24 Oct 2013)
 



1.1                  app-arch/tar/tar-1.27.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/tar/tar-1.27.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/tar/tar-1.27.1.ebuild?rev=1.1&content-type=text/plain

Index: tar-1.27.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/tar/tar-1.27.1.ebuild,v 1.1 2013/11/25 12:20:59 polynomial-c Exp $

EAPI="3"

inherit flag-o-matic eutils

DESCRIPTION="Use this to make tarballs :)"
HOMEPAGE="http://www.gnu.org/software/tar/"
SRC_URI="mirror://gnu/tar/${P}.tar.bz2
	mirror://gnu-alpha/tar/${P}.tar.bz2"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="acl minimal nls selinux static userland_GNU xattr"

RDEPEND="acl? ( virtual/acl )
	selinux? ( sys-libs/libselinux )"
DEPEND="${RDEPEND}
	nls? ( >=sys-devel/gettext-0.10.35 )
	xattr? ( sys-apps/attr )"

src_prepare() {
	if ! use userland_GNU ; then
		sed -i \
			-e 's:/backup\.sh:/gbackup.sh:' \
			scripts/{backup,dump-remind,restore}.in \
			|| die "sed non-GNU"
	fi
}

src_configure() {
	use static && append-ldflags -static
	FORCE_UNSAFE_CONFIGURE=1 \
	econf \
		--enable-backup-scripts \
		--bindir="${EPREFIX}"/bin \
		--libexecdir="${EPREFIX}"/usr/sbin \
		$(usex userland_GNU "" "--program-prefix=g") \
		$(use_with acl posix-acls) \
		$(use_enable nls) \
		$(use_with selinux) \
		$(use_with xattr xattrs)
}

src_install() {
	emake DESTDIR="${D}" install || die

	local p=$(usex userland_GNU "" "g")
	if [[ -z ${p} ]] ; then
		# a nasty yet required piece of baggage
		exeinto /etc
		doexe "${FILESDIR}"/rmt || die
	fi

	# autoconf looks for gtar before tar (in configure scripts), hence
	# in Prefix it is important that it is there, otherwise, a gtar from
	# the host system (FreeBSD, Solaris, Darwin) will be found instead
	# of the Prefix provided (GNU) tar
	if use prefix ; then
		dosym tar /bin/gtar
	fi

	dodoc AUTHORS ChangeLog* NEWS README* THANKS
	newman "${FILESDIR}"/tar.1-1.27 ${p}tar.1
	mv "${ED}"/usr/sbin/${p}backup{,-tar}
	mv "${ED}"/usr/sbin/${p}restore{,-tar}

	if use minimal ; then
		find "${ED}"/etc "${ED}"/*bin/ "${ED}"/usr/*bin/ \
			-type f -a '!' '(' -name tar -o -name ${p}tar ')' \
			-delete
	fi
}