[gentoo-commits] gentoo-x86 commit in media-libs/gegl: gegl-0.1.8.ebuild metadata.xml ChangeLog

[Sebastian Pipping (sping)]

sping       12/01/01 13:33:38

  Modified:             metadata.xml ChangeLog
  Added:                gegl-0.1.8.ebuild
  Log:
  media-libs/gegl: 0.1.8
  
  (Portage version: 2.1.10.43/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  media-libs/gegl/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gegl/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gegl/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gegl/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/gegl/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	24 Sep 2011 09:39:14 -0000	1.3
+++ metadata.xml	1 Jan 2012 13:33:37 -0000	1.4
@@ -5,6 +5,8 @@
 	<email>hanno@g.o</email>
 </maintainer>
 <use>
+	<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for introspection.</flag>
+	<flag name="lensfun">Enable support for <pkg>media-libs/lensfun</pkg>.</flag>
 	<flag name="umfpack">Enable sparse solving via <pkg>sci-libs/umfpack</pkg>.</flag>
 </use>
 </pkgmetadata>



1.59                 media-libs/gegl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gegl/ChangeLog?rev=1.59&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gegl/ChangeLog?rev=1.59&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gegl/ChangeLog?r1=1.58&r2=1.59

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/gegl/ChangeLog,v
retrieving revision 1.58
retrieving revision 1.59
diff -u -r1.58 -r1.59
--- ChangeLog	22 Dec 2011 10:33:39 -0000	1.58
+++ ChangeLog	1 Jan 2012 13:33:38 -0000	1.59
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/gegl
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/ChangeLog,v 1.58 2011/12/22 10:33:39 scarabeus Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/ChangeLog,v 1.59 2012/01/01 13:33:38 sping Exp $
+
+*gegl-0.1.8 (01 Jan 2012)
+
+  01 Jan 2012; Sebastian Pipping <sping@g.o> +gegl-0.1.8.ebuild,
+  metadata.xml:
+  Bump to 0.1.8
 
   22 Dec 2011; Tomáš Chvátal <scarabeus@g.o> -gegl-0.0.22.ebuild:
   remove old



1.1                  media-libs/gegl/gegl-0.1.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gegl/gegl-0.1.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gegl/gegl-0.1.8.ebuild?rev=1.1&content-type=text/plain

Index: gegl-0.1.8.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/gegl-0.1.8.ebuild,v 1.1 2012/01/01 13:33:37 sping Exp $

EAPI=4

inherit eutils autotools

DESCRIPTION="A graph based image processing framework"
HOMEPAGE="http://www.gegl.org/"
SRC_URI="ftp://ftp.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"

LICENSE="|| ( GPL-3 LGPL-3 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"

IUSE="cairo debug exif ffmpeg graphviz introspection jpeg jpeg2k lensfun lua mmx openexr png raw sdl sse svg umfpack v4l"

VALASLOT="0.14"

RDEPEND=">=media-libs/babl-0.1.6
	>=dev-libs/glib-2.28:2
	x11-libs/gtk+:2
	>=x11-libs/gdk-pixbuf-2.18:2
	x11-libs/pango
	sys-libs/zlib
	cairo? ( x11-libs/cairo )
	exif? ( media-gfx/exiv2 )
	ffmpeg? ( virtual/ffmpeg )
	graphviz? ( media-gfx/graphviz )
	jpeg? ( virtual/jpeg )
	jpeg2k? ( >=media-libs/jasper-1.900.1 )
	lua? ( >=dev-lang/lua-5.1 )
	openexr? ( media-libs/openexr )
	png? ( media-libs/libpng )
	raw? ( >=media-libs/libopenraw-0.0.5 )
	sdl? ( media-libs/libsdl )
	svg? ( >=gnome-base/librsvg-2.14:2 )
	umfpack? ( sci-libs/umfpack )
	v4l? ( media-libs/libv4l )
	dev-lang/perl
	introspection? ( >=dev-libs/gobject-introspection-0.10
			>=dev-python/pygobject-2.26:2 )
	lensfun? ( >=media-libs/lensfun-0.2.5 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=sys-devel/libtool-2.2
	dev-lang/vala:${VALASLOT}[vapigen]"

# tests fail in various ways:
#   see bug #362215
RESTRICT="test"

DOCS=( ChangeLog INSTALL README NEWS )

src_prepare() {
	# Workaroung "No rule to make target `gegl-0.1.deps'"
	touch "${S}/gegl/gegl-0.1.deps" || die

	# fix OSX loadable module filename extension
	sed -i -e 's/\.dylib/.bundle/' configure.ac || die
	eautoreconf
}

src_configure() {
	# never enable altering of CFLAGS via profile option
	# libspiro: not in portage main tree
	# disable documentation as the generating is bit automagic
	#    if anyone wants to work on it just create bug with patch
	VAPIGEN="$(type -p vapigen-${VALASLOT})" \
	econf \
		--disable-profile \
		--without-libspiro \
		--disable-docs --disable-workshop \
		--with-pango --with-gdk-pixbuf \
		$(use_enable mmx) \
		$(use_enable sse) \
		$(use_enable debug) \
		$(use_with cairo) \
		$(use_with cairo pangocairo) \
		$(use_with exif exiv2) \
		$(use_with ffmpeg libavformat) \
		$(use_with graphviz) \
		$(use_with jpeg libjpeg) \
		$(use_with jpeg2k jasper) \
		$(use_with lua) \
		$(use_with openexr) \
		$(use_with png libpng) \
		$(use_with raw libopenraw) \
		$(use_with sdl) \
		$(use_with svg librsvg) \
		$(use_with umfpack) \
		$(use_with v4l libv4l) \
		$(use_with introspection) \
		$(use_with lensfun)
	# TODO expose --without-vala ?
}

src_test() {
	# set xdg dirs to not violate sandbox constrains
	export XDG_CONFIG_HOME="${T}"
	export XDG_CACHE_HOME="${T}"

	default
}

src_install() {
	default
	find "${ED}" -name '*.la' -delete
}