[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-shell-extensions: gnome-shell-extensions-3.8.0.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       13/03/28 23:00:19

  Modified:             ChangeLog
  Added:                gnome-shell-extensions-3.8.0.ebuild
  Log:
  Version bump for Gnome 3.8
  
  (Portage version: 2.1.11.58/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.7                  gnome-extra/gnome-shell-extensions/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-shell-extensions/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-shell-extensions/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-shell-extensions/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-shell-extensions/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	26 Dec 2012 23:03:58 -0000	1.6
+++ ChangeLog	28 Mar 2013 23:00:18 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/gnome-shell-extensions
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-shell-extensions/ChangeLog,v 1.6 2012/12/26 23:03:58 eva Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-shell-extensions/ChangeLog,v 1.7 2013/03/28 23:00:18 pacho Exp $
+
+*gnome-shell-extensions-3.8.0 (28 Mar 2013)
+
+  28 Mar 2013; Pacho Ramos <pacho@g.o>
+  +gnome-shell-extensions-3.8.0.ebuild:
+  Version bump for Gnome 3.8
 
 *gnome-shell-extensions-3.6.2 (26 Dec 2012)
 
@@ -53,4 +59,3 @@
   +files/gnome-shell-extensions-3.2.0-systemMonitor-enable-disable.patch,
   +metadata.xml:
   Add extensions for gnome-base/gnome-shell from the gnome overlay.
-



1.1                  gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.8.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.8.0.ebuild?rev=1.1&content-type=text/plain

Index: gnome-shell-extensions-3.8.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.8.0.ebuild,v 1.1 2013/03/28 23:00:18 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit eutils gnome2

DESCRIPTION="JavaScript extensions for GNOME Shell"
HOMEPAGE="http://live.gnome.org/GnomeShell/Extensions"

LICENSE="GPL-2"
SLOT="0"
IUSE="examples"
KEYWORDS="~amd64 ~x86"

COMMON_DEPEND="
	>=dev-libs/glib-2.26:2
	>=gnome-base/gnome-desktop-2.91.6:3[introspection]
	>=gnome-base/libgtop-2.28.3[introspection]
	>=app-admin/eselect-gnome-shell-extensions-20111211"
RDEPEND="${COMMON_DEPEND}
	>=dev-libs/gjs-1.29
	dev-libs/gobject-introspection
	gnome-base/gnome-desktop[introspection]
	gnome-base/gnome-menus:3[introspection]
	>=gnome-base/gnome-shell-3.5.91
	media-libs/clutter:1.0[introspection]
	net-libs/telepathy-glib[introspection]
	x11-libs/gdk-pixbuf:2[introspection]
	x11-libs/gtk+:3[introspection]
	x11-libs/pango[introspection]
	x11-themes/gnome-icon-theme-symbolic
"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.50
	sys-devel/gettext
	virtual/pkgconfig
"
# eautoreconf needs gnome-base/gnome-common

src_configure() {
	G2CONF="${G2CONF}
		--enable-extensions=all"
	gnome2_src_configure
}

src_install() {
	gnome2_src_install

	local example="example@×××××××××××××××××××××××××××××××××××××.com"
	if use examples; then
		mv "${ED}usr/share/gnome-shell/extensions/${example}" \
			"${ED}usr/share/doc/${PF}/" || die
	else
		rm -r "${ED}usr/share/gnome-shell/extensions/${example}" || die
	fi
}

pkg_postinst() {
	gnome2_pkg_postinst

	ebegin "Updating list of installed extensions"
	eselect gnome-shell-extensions update
	eend $?
	elog
	elog "Installed extensions installed are initially disabled by default."
	elog "To change the system default and enable some extensions, you can use"
	elog "# eselect gnome-shell-extensions"
	elog "Alternatively, to enable/disable extensions on a per-user basis,"
	elog "you can use the https://extensions.gnome.org/ web interface, the"
	elog "gnome-extra/gnome-tweak-tool GUI, or modify the org.gnome.shell"
	elog "enabled-extensions gsettings key from the command line or a script."
}