[gentoo-commits] gentoo-x86 commit in media-libs/libafterimage: ChangeLog libafterimage-1.20.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    11/02/28 17:47:15

  Modified:             ChangeLog
  Added:                libafterimage-1.20.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.9.41/cvs/Linux x86_64)

Revision  Changes    Path
1.30                 media-libs/libafterimage/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libafterimage/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libafterimage/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libafterimage/ChangeLog?r1=1.29&r2=1.30

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libafterimage/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog	11 Nov 2010 10:08:26 -0000	1.29
+++ ChangeLog	28 Feb 2011 17:47:15 -0000	1.30
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libafterimage
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libafterimage/ChangeLog,v 1.29 2010/11/11 10:08:26 ssuominen Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libafterimage/ChangeLog,v 1.30 2011/02/28 17:47:15 bicatali Exp $
+
+*libafterimage-1.20 (28 Feb 2011)
+
+  28 Feb 2011; Sébastien Fabbro <bicatali@g.o>
+  +libafterimage-1.20.ebuild:
+  Version bump
 
   11 Nov 2010; Samuli Suominen <ssuominen@g.o>
   libafterimage-1.18-r1.ebuild:



1.1                  media-libs/libafterimage/libafterimage-1.20.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libafterimage/libafterimage-1.20.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libafterimage/libafterimage-1.20.ebuild?rev=1.1&content-type=text/plain

Index: libafterimage-1.20.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libafterimage/libafterimage-1.20.ebuild,v 1.1 2011/02/28 17:47:15 bicatali Exp $

EAPI=3
inherit eutils

MY_PN=libAfterImage

DESCRIPTION="Afterstep's standalone generic image manipulation library"
HOMEPAGE="http://www.afterstep.org/afterimage/index.php"
SRC_URI="ftp://ftp.afterstep.org/stable/${MY_PN}/${MY_PN}-${PV}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="gif jpeg mmx nls png svg tiff examples static-libs truetype"

RDEPEND="x11-libs/libSM
	x11-libs/libXext
	x11-libs/libXrender
	png?  ( >=media-libs/libpng-1.4 )
	jpeg? ( virtual/jpeg )
	gif?  ( media-libs/giflib )
	svg? ( gnome-base/librsvg )
	tiff? ( media-libs/tiff )
	truetype? ( media-libs/freetype )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	x11-proto/xextproto
	!x11-wm/afterstep"

S="${WORKDIR}/${MY_PN}-${PV}"

src_prepare() {
	# fix some ldconfig problem in makefile.in
	epatch "${FILESDIR}"/${PN}-makefile.in.patch
	# fix lib paths in afterimage-config
	epatch "${FILESDIR}"/${PN}-config.patch
	# remove forced flags
	sed -i \
		-e 's/CFLAGS="-O3"//' \
		-e 's/ -rdynamic//' \
		configure || die "sed failed"
}

src_configure() {
	econf \
		$(use_enable static-libs staticlibs) \
		$(use_enable nls i18n) \
		$(use_enable mmx mmx-optimization) \
		$(use_with png) \
		$(use_with jpeg) \
		$(use_with gif) \
		$(use_with svg) \
		$(use_with tiff) \
		$(use_with truetype ttf) \
		--enable-glx \
		--enable-sharedlibs \
		--with-x \
		--with-xpm \
		--without-builtin-gif \
		--without-builtin-ungif \
		--without-builtin-zlib \
		--without-afterbase
}

src_install() {
	emake \
		DESTDIR="${ED}" \
		AFTER_DOC_DIR="${ED}/usr/share/doc/${PF}" \
		install || die "emake install failed"
	dodoc ChangeLog README || die
	if use examples; then
		cd apps || die
		emake clean
		rm -f Makefile*
		insinto /usr/share/doc/${PF}/examples
		doins * || die "install examples failed"
	fi
}