[gentoo-commits] gentoo-x86 commit in net-im/minbif: minbif-1.0.5-r1.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/06/22 19:20:48

  Modified:             ChangeLog
  Added:                minbif-1.0.5-r1.ebuild
  Log:
  Drop support relying on farsight2, that is obsolete by farstream for ages
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.17                 net-im/minbif/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/minbif/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/minbif/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/minbif/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/minbif/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	8 Jan 2014 06:41:12 -0000	1.16
+++ ChangeLog	22 Jun 2014 19:20:48 -0000	1.17
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/minbif
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/minbif/ChangeLog,v 1.16 2014/01/08 06:41:12 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/minbif/ChangeLog,v 1.17 2014/06/22 19:20:48 pacho Exp $
+
+*minbif-1.0.5-r1 (22 Jun 2014)
+
+  22 Jun 2014; Pacho Ramos <pacho@g.o> +minbif-1.0.5-r1.ebuild:
+  Drop support relying on farsight2, that is obsolete by farstream for ages
 
   08 Jan 2014; Mike Frysinger <vapier@g.o> minbif-1.0.5.ebuild:
   Inherit the user eclass for enewuser/etc...



1.1                  net-im/minbif/minbif-1.0.5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/minbif/minbif-1.0.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/minbif/minbif-1.0.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: minbif-1.0.5-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/minbif/minbif-1.0.5-r1.ebuild,v 1.1 2014/06/22 19:20:48 pacho Exp $

EAPI=5
inherit cmake-utils eutils user

DESCRIPTION="an IRC gateway to IM networks"
HOMEPAGE="https://symlink.me/projects/minbif/wiki/"
SRC_URI="https://symlink.me/attachments/download/148/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="gnutls +imlib +libcaca pam xinetd"
REQUIRED_USE="
	libcaca? ( imlib )
"

DEPEND="
	>=net-im/pidgin-2.6
	libcaca? ( media-libs/libcaca media-libs/imlib2 )
	imlib? ( media-libs/imlib2 )
	pam? ( sys-libs/pam )
	gnutls? ( net-libs/gnutls )
"
RDEPEND="${DEPEND}
	virtual/logger
	xinetd? ( sys-apps/xinetd )
"

pkg_setup() {
	enewgroup minbif
	enewuser minbif -1 -1 /var/lib/minbif minbif
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.0.5-glib-single-includes.patch"
	epatch "${FILESDIR}/${PN}-1.0.5-gcc47.patch"

	sed -i "s/-Werror//g" CMakeLists.txt || die "sed failed"

	sed -i "s#share/doc/minbif#share/doc/${P}#" \
		CMakeLists.txt || die "sed failed"

	if use xinetd; then
		sed -i "s/type\s=\s[0-9]/type = 0/" \
			minbif.conf || die "sed failed"
	fi
}

src_configure() {
	local mycmakeargs
	mycmakeargs="${mycmakeargs}
		-DCONF_PREFIX=${PREFIX:-/etc/minbif}
		-DENABLE_VIDEO=OFF
		$(cmake-utils_use_enable libcaca CACA)
		$(cmake-utils_use_enable imlib IMLIB)
		$(cmake-utils_use_enable pam PAM)
		$(cmake-utils_use_enable gnutls TLS)"

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	keepdir /var/lib/minbif
	fperms 700 /var/lib/minbif
	fowners minbif:minbif /var/lib/minbif

	dodoc ChangeLog README
	doman man/minbif.8

	if use xinetd; then
		insinto /etc/xinetd.d
		newins doc/minbif.xinetd minbif
	fi

	newinitd "${FILESDIR}"/minbif.initd minbif

	dodir /usr/share/minbif
	insinto /usr/share/minbif
	doins -r scripts
}