[gentoo-commits] gentoo-x86 commit in games-puzzle/pauker: ChangeLog pauker-1.8_rc6.ebuild

[Alistair Bush (ali_bush)]

ali_bush    08/11/24 09:17:21

  Modified:             ChangeLog
  Added:                pauker-1.8_rc6.ebuild
  Log:
  Version Bump
  (Portage version: 2.2_rc15/cvs/Linux 2.6.27-gentoo x86_64)

Revision  Changes    Path
1.22                 games-puzzle/pauker/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/pauker/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/pauker/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/pauker/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-puzzle/pauker/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	2 Jul 2008 19:08:43 -0000	1.21
+++ ChangeLog	24 Nov 2008 09:17:21 -0000	1.22
@@ -1,6 +1,12 @@
 # ChangeLog for games-puzzle/pauker
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-puzzle/pauker/ChangeLog,v 1.21 2008/07/02 19:08:43 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/pauker/ChangeLog,v 1.22 2008/11/24 09:17:21 ali_bush Exp $
+
+*pauker-1.8_rc6 (24 Nov 2008)
+
+  24 Nov 2008; Alistair Bush <ali_bush@g.o>
+  +files/pauker_bundledjars.patch, +pauker-1.8_rc6.ebuild:
+  Version Bump.
 
   02 Jul 2008; Brent Baude <ranger@g.o> pauker-1.7.5-r1.ebuild:
   stable ppc, bug 229235



1.1                  games-puzzle/pauker/pauker-1.8_rc6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/pauker/pauker-1.8_rc6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/pauker/pauker-1.8_rc6.ebuild?rev=1.1&content-type=text/plain

Index: pauker-1.8_rc6.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-puzzle/pauker/pauker-1.8_rc6.ebuild,v 1.1 2008/11/24 09:17:21 ali_bush Exp $

JAVA_PKG_IUSE="doc source"
EAPI="1"

inherit eutils java-pkg-2 java-ant-2 games

MY_PV="1.8RC6"

DESCRIPTION="A java based flashcard program"
HOMEPAGE="http://pauker.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_PV}.src.jar"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

IUSE=""

COMMON_DEP="dev-java/browserlauncher2:1.0
			dev-java/javahelp
			dev-java/lucene:2.4
			dev-java/swing-layout:1"

RDEPEND=">=virtual/jre-1.5
		${COMMON_DEP}"
DEPEND=">=virtual/jdk-1.5
		app-arch/unzip
		${COMMON_DEP}"

S="${WORKDIR}"

pkg_setup() {
	games_pkg_setup
	java-pkg-2_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	find . -iname '*.jar' -delete

	epatch "${FILESDIR}/${PN}_bundledjars.patch"

	java-pkg_jar-from --into libs browserlauncher2-1.0 browserlauncher2.jar BrowserLauncher2-1_3.jar
	java-pkg_jar-from --into libs javahelp jhall.jar
	java-pkg_jar-from --into libs lucene-2.4 lucene-core.jar lucene-core-2.4.0.jar
	java-pkg_jar-from --into libs swing-layout-1 swing-layout.jar
}

src_compile() {
	eant -Dfile.reference.BrowserLauncher2-1_3.jar="libs/BrowserLauncher2-1_3.jar" \
		-Dlibs.swing-layout.classpath="libs/swing-layout.jar" jar $(use_doc javadoc)
}

#test depend on jemmy, a netbeans module.  so unless it is packaged separately
#tests cannot be build.

src_install() {
	java-pkg_jarinto "${GAMES_DATADIR}/${PN}"
	java-pkg_newjar "dist/${PN}-${MY_PV}.jar"

	java-pkg_dolauncher ${PN} \
		-into "${GAMES_PREFIX}" \
		--pwd "${GAMES_DATADIR}"/${PN} \
		--main pauker.program.gui.swing.PaukerFrame

	use doc && java-pkg_dojavadoc dist/javadoc
	use source && java-pkg_dosrc src

	prepgamesdirs
}