[gentoo-commits] gentoo-x86 commit in app-misc/task: task-2.0.0_beta3.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    11/10/04 03:40:54

  Modified:             ChangeLog
  Added:                task-2.0.0_beta3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha60/cvs/Linux x86_64)

Revision  Changes    Path
1.23                 app-misc/task/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	22 Sep 2011 06:27:48 -0000	1.22
+++ ChangeLog	4 Oct 2011 03:40:54 -0000	1.23
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/task
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.22 2011/09/22 06:27:48 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.23 2011/10/04 03:40:54 radhermit Exp $
+
+*task-2.0.0_beta3 (04 Oct 2011)
+
+  04 Oct 2011; Tim Harder <radhermit@g.o> +task-2.0.0_beta3.ebuild:
+  Version bump.
 
 *task-2.0.0_beta2 (22 Sep 2011)
 



1.1                  app-misc/task/task-2.0.0_beta3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/task-2.0.0_beta3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/task-2.0.0_beta3.ebuild?rev=1.1&content-type=text/plain

Index: task-2.0.0_beta3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/task/task-2.0.0_beta3.ebuild,v 1.1 2011/10/04 03:40:54 radhermit Exp $

EAPI=4

inherit eutils cmake-utils bash-completion-r1

MY_P="${P/_/.}"
DESCRIPTION="A task management tool with a command-line interface"
HOMEPAGE="http://taskwarrior.org/projects/show/taskwarrior/"
SRC_URI="http://taskwarrior.org/download/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="lua vim-syntax zsh-completion"

DEPEND="lua? ( dev-lang/lua )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# Use the correct directory locations
	sed -i -e "s:/usr/local/share/doc/task/rc:/usr/share/task/rc:" \
		doc/man/taskrc.5.in doc/man/task-tutorial.5.in doc/man/task-color.5.in
	sed -i -e "s:/usr/local/bin:/usr/bin:" doc/man/task-faq.5.in scripts/add-ons/*

	# Don't automatically install scripts
	sed -i -e '/scripts/d' CMakeLists.txt

	epatch "${FILESDIR}"/${PN}-2.0.0_beta1-rcdir.patch \
		"${FILESDIR}"/${PN}-1.9.4-lua-automagic.patch
}

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_enable lua LUA)
		-DTASK_DOCDIR=/usr/share/doc/${PF}
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	newbashcomp scripts/bash/task_completion.sh task

	if use vim-syntax ; then
		rm scripts/vim/README
		insinto /usr/share/vim/vimfiles
		doins -r scripts/vim/*
	fi

	if use zsh-completion ; then
		insinto /usr/share/zsh/site-functions
		doins scripts/zsh/*
	fi

	exeinto /usr/share/${PN}/scripts
	doexe scripts/add-ons/*
}