[gentoo-commits] gentoo-x86 commit in net-voip/gnugk: metadata.xml gnugk-3.2.2.ebuild ChangeLog gnugk-2.2.5.ebuild

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    13/03/06 02:09:40

  Modified:             metadata.xml ChangeLog
  Added:                gnugk-3.2.2.ebuild
  Removed:              gnugk-2.2.5.ebuild
  Log:
  Version bump. Fixes bug #290067 and security bug #432756.
  
  (Portage version: 2.1.11.50/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.3                  net-voip/gnugk/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/gnugk/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/gnugk/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/gnugk/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-voip/gnugk/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	16 Aug 2008 16:22:29 -0000	1.2
+++ metadata.xml	6 Mar 2013 02:09:40 -0000	1.3
@@ -2,4 +2,7 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
   <herd>voip</herd>
+  <use>
+    <flag name="ssh">Enable support for SSH port forwarding using <pkg>net-libs/libssh</pkg></flag>
+  </use>
 </pkgmetadata>



1.10                 net-voip/gnugk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/gnugk/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/gnugk/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/gnugk/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-voip/gnugk/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	17 Jun 2010 20:58:55 -0000	1.9
+++ ChangeLog	6 Mar 2013 02:09:40 -0000	1.10
@@ -1,6 +1,14 @@
 # ChangeLog for net-voip/gnugk
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-voip/gnugk/ChangeLog,v 1.9 2010/06/17 20:58:55 patrick Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-voip/gnugk/ChangeLog,v 1.10 2013/03/06 02:09:40 chithanh Exp $
+
+*gnugk-3.2.2 (06 Mar 2013)
+
+  06 Mar 2013; Chí-Thanh Christopher Nguyễn <chithanh@g.o>
+  +files/gnugk-3.2.2-h323plus-buildopts.patch,
+  +files/gnugk-3.2.2-lua.cxx-toolkit_h.patch, +files/gnugk-3.2.2-ptrace.patch,
+  +gnugk-3.2.2.ebuild, -gnugk-2.2.5.ebuild, metadata.xml:
+  Version bump. Fixes bug #290067 and security bug #432756.
 
   17 Jun 2010; Patrick Lauer <patrick@g.o> gnugk-2.2.5.ebuild,
   gnugk-2.2.7.ebuild, gnugk-2.2.8.ebuild:
@@ -85,4 +93,3 @@
   metadata.xml, files/gnugk-2.0.6-gentoo.diff, files/gnugk.confd,
   files/gnugk.rc6:
   initial import.
-



1.1                  net-voip/gnugk/gnugk-3.2.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/gnugk/gnugk-3.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/gnugk/gnugk-3.2.2.ebuild?rev=1.1&content-type=text/plain

Index: gnugk-3.2.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-voip/gnugk/gnugk-3.2.2.ebuild,v 1.1 2013/03/06 02:09:40 chithanh Exp $

EAPI="5"

inherit eutils versionator

MY_P1=${PN}-$(replace_version_separator 2 -)
MY_P2=${PN}-$(get_version_component_range 1-2)

DESCRIPTION="GNU H.323 gatekeeper"
HOMEPAGE="http://www.gnugk.org/"
SRC_URI="mirror://sourceforge/openh323gk/${MY_P1}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
# dev-db/firebird isn't keyworded for ppc but firebird IUSE is masked for ppc
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="doc firebird lua mysql odbc postgres radius snmp sqlite ssh linguas_en linguas_es linguas_fr"
REQUIRED_USE="doc? (
	|| ( linguas_en linguas_es linguas_fr )
	)
"

RDEPEND="net-libs/ptlib:=
	net-libs/h323plus:=
	dev-libs/openssl
	firebird? ( dev-db/firebird )
	lua? ( dev-lang/lua )
	mysql? ( virtual/mysql )
	odbc? ( dev-db/unixODBC )
	postgres? ( dev-db/postgresql-base )
	snmp? ( net-analyzer/net-snmp )
	ssh? ( net-libs/libssh )
	sqlite? ( dev-db/sqlite:3 )"
DEPEND="${RDEPEND}
	doc? ( app-text/linuxdoc-tools )"

S=${WORKDIR}/${MY_P2}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.2.2-ptrace.patch
	epatch "${FILESDIR}"/${PN}-3.2.2-h323plus-buildopts.patch
	epatch "${FILESDIR}"/${PN}-3.2.2-lua.cxx-toolkit_h.patch
}

# TODO: investigate possible ebuild conversion to use cmake
src_configure() {
	# --with-large-fdset=4096 is added because of bug #128102
	# and it is recommended in the online manual
	econf \
		$(use_enable firebird) \
		$(use_enable lua) \
		$(use_enable mysql) \
		$(use_enable postgres pgsql) \
		$(use_enable odbc unixodbc) \
		$(use_enable radius) \
		$(use_enable snmp netsnmp) \
		$(use_enable sqlite) \
		$(use_enable ssh libssh) \
		--with-large-fdset=4096
}

src_compile() {
	# PASN_NOPRINT should be set for -debug but it's buggy
	# better to prevent issues and keep default settings
	# `make debugdepend debugshared` and `make debug` failed (so no debug)
	# `make optdepend optnoshared` also failed (so no static)

	# splitting emake calls fixes parallel build issue
	emake optdepend
	emake \
		PT_LIBDIR="$(ptlib-config --libdir)" \
		OH323_LIBDIR="${EPREFIX}"/usr/lib \
		optshared
	# build tool addpasswd
	emake -C addpasswd PTLIBDIR="$(ptlib-config --ptlibdir)"

	if use doc; then
		cd docs/manual

		if use linguas_en; then
			emake html
		fi

		if use linguas_es; then
			emake html-es
		fi

		if use linguas_fr; then
			emake html-fr
		fi
		cd ../..
	fi
}

src_install() {
	dosbin obj_*_*_*/${PN}
	dosbin addpasswd/obj_*_*_*/addpasswd

	dodir /etc/${PN}
	insinto /etc/${PN}
	doins etc/*

	dodoc changes.txt readme.txt
	dodoc docs/*.txt docs/*.pdf

	if use doc; then
		if use linguas_en; then
			dohtml docs/manual/manual*.html
		fi
		if use linguas_fr; then
			dohtml docs/manual/fr/manual-fr*.html
		fi
		if use linguas_es; then
			dohtml docs/manual/es/manual-es*.html
		fi
	fi

	doman docs/${PN}.1 docs/addpasswd.1

	newinitd "${FILESDIR}"/${PN}.rc6 ${PN}
	newconfd "${FILESDIR}"/${PN}.confd ${PN}
}