[gentoo-commits] gentoo-x86 commit in media-sound/audtty: ChangeLog audtty-0.1.9a.ebuild audtty-0.1.8.ebuild

[Samuli Suominen (drac)]

drac        08/07/05 06:39:19

  Modified:             ChangeLog
  Added:                audtty-0.1.9a.ebuild
  Removed:              audtty-0.1.8.ebuild
  Log:
  Version bump wrt #230309 by Hlevyn.
  (Portage version: 2.2_rc1/cvs/Linux 2.6.26-rc3 x86_64)

Revision  Changes    Path
1.19                 media-sound/audtty/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/audtty/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/audtty/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/audtty/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/audtty/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	26 Apr 2008 16:32:53 -0000	1.18
+++ ChangeLog	5 Jul 2008 06:39:19 -0000	1.19
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/audtty
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/audtty/ChangeLog,v 1.18 2008/04/26 16:32:53 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audtty/ChangeLog,v 1.19 2008/07/05 06:39:19 drac Exp $
+
+*audtty-0.1.9a (05 Jul 2008)
+
+  05 Jul 2008; Samuli Suominen <drac@g.o>
+  +files/audtty-0.1.9a-cc-and-destdir.patch, +audtty-0.1.9a.ebuild:
+  Version bump wrt #230309 by Hlevyn.
 
   26 Apr 2008; nixnut <nixnut@g.o> audtty-0.1.7.ebuild:
   Stable on ppc wrt bug 216888



1.1                  media-sound/audtty/audtty-0.1.9a.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/audtty/audtty-0.1.9a.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/audtty/audtty-0.1.9a.ebuild?rev=1.1&content-type=text/plain

Index: audtty-0.1.9a.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/audtty/audtty-0.1.9a.ebuild,v 1.1 2008/07/05 06:39:19 drac Exp $

inherit autotools eutils toolchain-funcs

DESCRIPTION="Control Audacious from the command line with a friendly ncurses interface"
HOMEPAGE="http://audtty.alioth.debian.org"
SRC_URI="http://${PN}.alioth.debian.org/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~x86"
IUSE=""

RDEPEND="sys-libs/ncurses
	>=media-sound/audacious-1.4.4"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${PN}

pkg_setup() {
	if has_version "=media-sound/audacious-1.4*"; then
		if ! built_with_use media-sound/audacious dbus; then
			die "Re-emerge media-sound/audacious with USE dbus."
		fi
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-cc-and-destdir.patch
	eautoreconf
}

src_compile() {
	tc-export CC
	econf
	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."
	dodoc ChangeLog README
}

pkg_postinst() {
	elog "In order to run audtty over ssh or on a seperate TTY locally you need"
	elog "to download and run the following script in a terminal on your desktop:"
	elog ""
	elog "http://${PN}.alioth.debian.org/dbus.sh"
	elog ""
	elog "Once run you will need to add ~/.dbus-session to your ~/.bashrc file."
}



-- 
gentoo-commits@l.g.o mailing list