[gentoo-commits] gentoo-x86 commit in dev-libs/xerces-c: ChangeLog xerces-c-3.1.1.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    10/08/28 06:25:10

  Modified:             ChangeLog
  Added:                xerces-c-3.1.1.ebuild
  Log:
  Version bump (bug #328643), readded dropped disable-thread-tests patchs (bug #307303).
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.88                 dev-libs/xerces-c/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/xerces-c/ChangeLog?rev=1.88&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/xerces-c/ChangeLog?rev=1.88&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/xerces-c/ChangeLog?r1=1.87&r2=1.88

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v
retrieving revision 1.87
retrieving revision 1.88
diff -u -r1.87 -r1.88
--- ChangeLog	18 Jun 2010 18:54:58 -0000	1.87
+++ ChangeLog	28 Aug 2010 06:25:10 -0000	1.88
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/xerces-c
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v 1.87 2010/06/18 18:54:58 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v 1.88 2010/08/28 06:25:10 dev-zero Exp $
+
+*xerces-c-3.1.1 (28 Aug 2010)
+
+  28 Aug 2010; Tiziano Müller <dev-zero@g.o>
+  +files/3.1.1-disable-thread-tests.patch, +xerces-c-3.1.1.ebuild:
+  Version bump (bug #328643), readded dropped disable-thread-tests patchs
+  (bug #307303).
 
   18 Jun 2010; Pacho Ramos <pacho@g.o> xerces-c-3.0.1-r1.ebuild:
   stable amd64, security bug 280613



1.1                  dev-libs/xerces-c/xerces-c-3.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/xerces-c/xerces-c-3.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/xerces-c/xerces-c-3.1.1.ebuild?rev=1.1&content-type=text/plain

Index: xerces-c-3.1.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-3.1.1.ebuild,v 1.1 2010/08/28 06:25:10 dev-zero Exp $

EAPI="2"

inherit eutils

DESCRIPTION="A validating XML parser written in a portable subset of C++."
HOMEPAGE="http://xerces.apache.org/xerces-c/"
SRC_URI="mirror://apache/xerces/c/3/sources/${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="curl doc iconv icu libwww sse2 static-libs threads elibc_Darwin elibc_FreeBSD"

RDEPEND="icu? ( >=dev-libs/icu-4.2 )
	curl? ( net-misc/curl )
	libwww? ( net-libs/libwww )
	virtual/libiconv"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

pkg_setup() {
	export ICUROOT="/usr"

	if use iconv && use icu ; then
		ewarn "This package can use iconv or icu for loading messages"
		ewarn "and transcoding, but not both. ICU will precede."
	fi
}

src_prepare() {
	use threads || epatch "${FILESDIR}/${PV}-disable-thread-tests.patch"

	sed -i \
		-e 's|$(prefix)/msg|$(DESTDIR)/$(prefix)/share/xerces-c/msg|' \
		src/xercesc/util/MsgLoaders/MsgCatalog/Makefile.in || die "sed failed"
}

src_configure() {
	local mloader="inmemory"
	use iconv && mloader="iconv"
	use icu && mloader="icu"

	local transcoder="gnuiconv"
	use elibc_FreeBSD && transcoder="iconv"
	use elibc_Darwin && transcoder="macosunicodeconverter"
	use icu && transcoder="icu"
	# for interix maybe: transcoder="windows"

	# 'cfurl' is only available on OSX and 'socket' isn't supposed to work.
	# But the docs aren't clear about it, so we would need some testing...
	local netaccessor="socket"
	use elibc_Darwin && netaccessor="cfurl"
	use libwww && netaccessor="libwww"
	use curl && netaccessor="curl"

	econf \
		--disable-pretty-make \
		$(use_enable static-libs static) \
		$(use_enable threads) \
		--enable-msgloader-${mloader} \
		--enable-netaccessor-${netaccessor} \
		--enable-transcoder-${transcoder} \
		$(use_enable sse2)
}

src_compile() {
	default

	if use doc ; then
		cd "${S}/doc"
		doxygen || die "making docs failed"
	fi
}

src_install () {
	emake DESTDIR="${D}" install || die "emake failed"

	use static-libs || rm "${D}"/lib*/*.la

	# To make sure an appropriate NLS msg file is around when using the iconv msgloader
	# ICU has the messages compiled in.
	if use iconv && ! use icu ; then
		doenvd "${FILESDIR}/50xerces-c"
	fi

	if use doc; then
		insinto /usr/share/doc/${PF}
		rm -rf samples/Makefile* samples/runConfigure samples/src/*/Makefile* samples/.libs
		doins -r samples
		dohtml -r doc/html/*
	fi

	dodoc CREDITS KEYS NOTICE README version.incl
}