[gentoo-commits] repo/gentoo:master commit in: gnome-extra/cinnamon-session/

[Joonas Niilola]

commit:     1c4b8c0b4d7ae83c3c55e4a7c1ae1e8542f72156
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Sat Jul 24 20:20:04 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sat Jul 31 08:35:49 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1c4b8c0b

gnome-extra/cinnamon-session: 5.0.1 version bump

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 gnome-extra/cinnamon-session/Manifest              |  1 +
 .../cinnamon-session/cinnamon-session-5.0.1.ebuild | 77 ++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/gnome-extra/cinnamon-session/Manifest b/gnome-extra/cinnamon-session/Manifest
index 6aaad77f47d..1efde52cb57 100644
--- a/gnome-extra/cinnamon-session/Manifest
+++ b/gnome-extra/cinnamon-session/Manifest
@@ -1,2 +1,3 @@
 DIST cinnamon-session-4.8.0.tar.gz 199684 BLAKE2B 07baa1d359376fb1c5150224d3420c2ea2c06c2c015739835ffa2c8f0be751362b8ea2299e155369c0cb2d3e8493d5c45ed3f521bb36b6ddb092aff493f01b1f SHA512 21e40d3776c2cd2fcb70bf5597e7f97d415a3236b7c2bdb46cc2359adcb62ec34ad529841154f87ea4a38013cd329cbba5cd6c88e16c4fc4e03acbe38a62edd7
 DIST cinnamon-session-5.0.0.tar.gz 199887 BLAKE2B c009a690c479944f8b3879a3ebff24ea3d44676b9235fcd36049e1680e5a1358266b75ca9f6e193fc51f11d8d94cf0c592dc22cbae2fededf41281748f9410cc SHA512 98ab99d09b8d4904446a38888380beb3a403457e3da4c0f4160633156a490040924743d63eaa13e23b9e5f5c45c9392be082c39c969e0639b0bb06d9c1a2207c
+DIST cinnamon-session-5.0.1.tar.gz 200036 BLAKE2B a7e254d54daa63f5dcf5592843b85e0c63a3fdd34ce5c3045ff5c7ce410f2ab340b5c778b1579e7586f7d9e0517fdf00703934395b9bbbbd234cb181a1096fcf SHA512 0c367764269ce1597035288508909aad2c031ab5b8c04bde3d81cc420f38abf6cca82f169db199cf01218e92014653f1749c0ed2096950f7bc9f3b56f1fcdebc

diff --git a/gnome-extra/cinnamon-session/cinnamon-session-5.0.1.ebuild b/gnome-extra/cinnamon-session/cinnamon-session-5.0.1.ebuild
new file mode 100644
index 00000000000..dfb7bf69e57
--- /dev/null
+++ b/gnome-extra/cinnamon-session/cinnamon-session-5.0.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit meson gnome2-utils python-any-r1 xdg-utils
+
+DESCRIPTION="Cinnamon session manager"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-session"
+SRC_URI="https://github.com/linuxmint/cinnamon-session/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc ipv6 systemd"
+
+DEPEND="
+	>=dev-libs/glib-2.37.3:2
+	media-libs/libcanberra[pulseaudio]
+	virtual/opengl
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3:3
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango[X]
+	>=x11-libs/xapps-2.2.0
+
+	systemd? ( >=sys-apps/systemd-183 )
+	!systemd? ( sys-auth/elogind[policykit] )
+"
+RDEPEND="
+	${DEPEND}
+	>=gnome-extra/cinnamon-desktop-5.0:0=
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	>=dev-util/intltool-0.40.6
+	virtual/pkgconfig
+
+	doc? (
+		app-text/xmlto
+		dev-libs/libxslt )
+"
+
+src_prepare() {
+	default
+	python_fix_shebang data
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgconf=false
+		$(meson_use doc docbook)
+		$(meson_use ipv6)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}