[gentoo-commits] gentoo-x86 commit in net-misc/lldpd: ChangeLog lldpd-0.7.9.ebuild

[Patrick McLean (chutzpah)]

chutzpah    14/07/01 18:01:53

  Modified:             ChangeLog
  Added:                lldpd-0.7.9.ebuild
  Log:
  Version bump. Add systemd unit (bug #515644).
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xE3F69979BB4B8928DA78E3D17CBF44EF)

Revision  Changes    Path
1.14                 net-misc/lldpd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/lldpd/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	3 Mar 2014 23:50:56 -0000	1.13
+++ ChangeLog	1 Jul 2014 18:01:53 -0000	1.14
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/lldpd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/lldpd/ChangeLog,v 1.13 2014/03/03 23:50:56 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/lldpd/ChangeLog,v 1.14 2014/07/01 18:01:53 chutzpah Exp $
+
+*lldpd-0.7.9 (01 Jul 2014)
+
+  01 Jul 2014; Patrick McLean <chutzpah@g.o> +lldpd-0.7.9.ebuild,
+  +files/lldpd.service:
+  Version bump. Add systemd unit (bug #515644).
 
   03 Mar 2014; Pacho Ramos <pacho@g.o> lldpd-0.7.6.ebuild:
   amd64 stable, bug #495876



1.1                  net-misc/lldpd/lldpd-0.7.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/lldpd-0.7.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/lldpd-0.7.9.ebuild?rev=1.1&content-type=text/plain

Index: lldpd-0.7.9.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/lldpd/lldpd-0.7.9.ebuild,v 1.1 2014/07/01 18:01:53 chutzpah Exp $

EAPI=5

inherit eutils user systemd

DESCRIPTION="Implementation of IEEE 802.1ab (LLDP)"
HOMEPAGE="http://vincentbernat.github.com/lldpd/"
SRC_URI="http://media.luffy.cx/files/${PN}/${P}.tar.gz"

LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cdp doc +dot1 +dot3 edp fdp graph json +lldpmed seccomp sonmp snmp static-libs readline xml"

RDEPEND=">=dev-libs/libevent-2.0.5
		snmp? ( net-analyzer/net-snmp[extensible(+)] )
		xml? ( dev-libs/libxml2 )
		json? ( dev-libs/jansson )
		seccomp? ( sys-libs/libseccomp )"
DEPEND="${RDEPEND}
		virtual/pkgconfig
		doc? (
			graph? ( app-doc/doxygen[dot] )
			!graph? ( app-doc/doxygen )
		)"

REQUIRED_USE="graph? ( doc )"

pkg_setup() {
	ebegin "Creating lldpd user and group"
	enewgroup ${PN}
	enewuser ${PN} -1 -1 -1 ${PN}
	eend $?
}

src_prepare() {
	# remove the bundled libevent
	rm -rf libevent

	epatch_user
}

src_configure() {
	econf \
		--with-privsep-user=${PN} \
		--with-privsep-group=${PN} \
		--with-privsep-chroot=/var/lib/${PN} \
		--docdir=/usr/share/doc/${PF} \
		$(use_enable graph doxygen-dot) \
		$(use_enable doc doxygen-man) \
		$(use_enable doc doxygen-pdf) \
		$(use_enable doc doxygen-html) \
		$(use_enable cdp) \
		$(use_enable dot1) \
		$(use_enable dot3) \
		$(use_enable edp) \
		$(use_enable fdp) \
		$(use_enable lldpmed) \
		$(use_enable sonmp) \
		$(use_enable static-libs static) \
		$(use_with json) \
		$(use_with readline) \
		$(use_with seccomp) \
		$(use_with snmp) \
		$(use_with xml)
}

src_compile() {
	emake
	use doc && emake doxygen-doc
}

src_install() {
	emake DESTDIR="${D}" install
	prune_libtool_files

	newinitd "${FILESDIR}"/${PN}-initd-1 ${PN}
	newconfd "${FILESDIR}"/${PN}-confd-1 ${PN}

	use doc && dohtml -r doxygen/html/*

	keepdir /var/lib/${PN}

	systemd_dounit "${FILESDIR}"/${PN}.service
}