[gentoo-commits] repo/gentoo:master commit in: media-sound/deadbeef/

[Piotr Karbowski]

commit:     94e42c7ad4ce63ee3c85d7a6aa136992dd9a0e07
Author:     Piotr Karbowski <slashbeast <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 26 12:35:14 2022 +0000
Commit:     Piotr Karbowski <slashbeast <AT> gentoo <DOT> org>
CommitDate: Sun Jun 26 12:36:19 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=94e42c7a

media-sound/deadbeef: 1.9.1 version bump

Closes: https://bugs.gentoo.org/851687
Signed-off-by: Piotr Karbowski <slashbeast <AT> gentoo.org>

 media-sound/deadbeef/Manifest              |   1 +
 media-sound/deadbeef/deadbeef-1.9.1.ebuild | 191 +++++++++++++++++++++++++++++
 2 files changed, 192 insertions(+)

diff --git a/media-sound/deadbeef/Manifest b/media-sound/deadbeef/Manifest
index 0ca8958aee29..315ce3f2e738 100644
--- a/media-sound/deadbeef/Manifest
+++ b/media-sound/deadbeef/Manifest
@@ -1 +1,2 @@
 DIST deadbeef-1.8.8.tar.bz2 5083407 BLAKE2B 69fd2cbaf131b3e44b426163ce6a83479bb1aff0e088c4beea09d747750f6f20b1e297eab1dd1ae0446d2af0aaf28fe0cc7c9f9e3e73fe031d369ba2f5d809ca SHA512 399f0e70eca5e102a9e73ff03199c89c6f28f3e0da96e793316d1af83f00e71f09f6cc81a3fd0b0f0d52fe9e0195a3b9ffb0cf7e7708c3ea7085f33a5ec08b47
+DIST deadbeef-1.9.1.tar.bz2 5136384 BLAKE2B 6e8314728b824b182ecb356d9a9cb09364650f6ca6b5e5d2f7077fc048fe62284e4959910a4cf982fd79893c503044d02417633713d0dcf34e93128aff22692e SHA512 2f959fb139078bbde3c1183019545ed3979b3c5dfc051794ea7a5ccf166156acc8d5dface3169ec705059f487d47c9b314c5400770a7572c22fbd0b903eefc5a

diff --git a/media-sound/deadbeef/deadbeef-1.9.1.ebuild b/media-sound/deadbeef/deadbeef-1.9.1.ebuild
new file mode 100644
index 000000000000..4ff8f9b85bef
--- /dev/null
+++ b/media-sound/deadbeef/deadbeef-1.9.1.ebuild
@@ -0,0 +1,191 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools xdg flag-o-matic toolchain-funcs plocale
+
+DESCRIPTION="DeaDBeeF is a modular audio player similar to foobar2000"
+HOMEPAGE="https://deadbeef.sourceforge.io/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="
+	GPL-2
+	LGPL-2.1
+	wavpack? ( BSD )
+"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="aac alsa cdda converter cover dts ffmpeg flac +hotkeys lastfm mp3 musepack nls notify nullout opus oss pulseaudio sc68 shellexec +supereq threads vorbis wavpack"
+
+REQUIRED_USE="
+	|| ( alsa oss pulseaudio nullout )
+"
+
+DEPEND="
+	x11-libs/gtk+:3
+	net-misc/curl:0=
+	dev-libs/jansson:=
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	cdda? (
+		dev-libs/libcdio:0=
+		media-libs/libcddb
+		dev-libs/libcdio-paranoia:0=
+	)
+	cover? (
+		media-libs/imlib2[jpeg,png]
+	)
+	dts? ( media-libs/libdca )
+	ffmpeg? ( media-video/ffmpeg )
+	flac? (
+		media-libs/flac
+		media-libs/libogg
+	)
+	mp3? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	nls? ( virtual/libintl )
+	notify? (
+		sys-apps/dbus
+	)
+	opus? ( media-libs/opusfile	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	dev-libs/libdispatch
+"
+
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+	sys-devel/clang
+	sys-devel/llvm
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/deadbeef-use-ffmpeg-plugin-for-ape-by-default.patch"
+)
+
+src_prepare() {
+	default
+
+	drop_from_linguas() {
+		sed "/${1}/d" -i "${S}/po/LINGUAS" || die
+	}
+
+	drop_and_stub() {
+		rm -rf "${1}"
+		mkdir "${1}"
+		cat > "${1}/Makefile.in" <<-EOF
+			all: nothing
+			install: nothing
+			nothing:
+		EOF
+	}
+
+	plocale_for_each_disabled_locale drop_from_linguas || die
+
+	eautopoint --force
+	eautoreconf
+
+	# Get rid of bundled gettext.
+	drop_and_stub "${S}/intl"
+
+	# Plugins that are undesired for whatever reason, candidates for unbundling and such.
+	for i in adplug alac dumb ffap mms gme mono2stereo psf shn sid soundtouch wma; do
+		drop_and_stub "${S}/plugins/${i}"
+	done
+
+	rm -rf "${S}/plugins/rg_scanner/ebur128"
+}
+
+src_configure () {
+	if ! tc-is-clang; then
+		AR=llvm-ar
+		CC=${CHOST}-clang
+		CXX=${CHOST}-clang++
+		NM=llvm-nm
+		RANLIB=llvm-ranlib
+
+		strip-unsupported-flags
+	fi
+
+	export HOST_CC="$(tc-getBUILD_CC)"
+	export HOST_CXX="$(tc-getBUILD_CXX)"
+	tc-export CC CXX LD AR NM OBJDUMP RANLIB PKG_CONFIG
+
+	local myconf=(
+		"--disable-static"
+		"--disable-staticlink"
+		"--disable-portable"
+		"--disable-rpath"
+
+		"--disable-libmad"
+		"--disable-gtk2"
+		"--disable-adplug"
+		"--disable-coreaudio"
+		"--disable-dumb"
+		"--disable-alac"
+		"--disable-ffap"
+		"--disable-gme"
+		"--disable-mms"
+		"--disable-mono2stereo"
+		"--disable-psf"
+		"--disable-rgscanner"
+		"--disable-shn"
+		"--disable-sid"
+		"--disable-sndfile"
+		"--disable-soundtouch"
+		"--disable-src"
+		"--disable-tta"
+		"--disable-vfs-zip"
+		"--disable-vtx"
+		"--disable-wildmidi"
+		"--disable-wma"
+
+		"$(use_enable alsa)"
+		"$(use_enable oss)"
+		"$(use_enable pulseaudio pulse)"
+		"$(use_enable mp3)"
+		"$(use_enable mp3 libmpg123)"
+		"$(use_enable nls)"
+		"$(use_enable vorbis)"
+		"$(use_enable threads)"
+		"$(use_enable flac)"
+		"$(use_enable supereq)"
+		"$(use_enable cdda)"
+		"$(use_enable cdda cdda-paranoia)"
+		"$(use_enable aac)"
+		"$(use_enable cover artwork)"
+		"$(use_enable cover artwork-network)"
+		"$(use_enable dts dca)"
+		"$(use_enable ffmpeg)"
+		"$(use_enable converter)"
+		"$(use_enable musepack)"
+		"$(use_enable notify)"
+		"$(use_enable nullout)"
+		"$(use_enable opus)"
+		"$(use_enable pulseaudio pulse)"
+		"$(use_enable sc68)"
+		"$(use_enable shellexec)"
+		"$(use_enable shellexec shellexecui)"
+		"$(use_enable lastfm lfm)"
+		"$(use_enable wavpack)"
+
+		"--enable-gtk3"
+		"--enable-vfs-curl"
+		"--enable-shared"
+		"--enable-m3u"
+		"--enable-pltbrowser"
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}