[gentoo-commits] gentoo-x86 commit in dev-util/ccache: ccache-3.1.10-r1.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      14/11/01 08:11:46

  Modified:             ChangeLog
  Added:                ccache-3.1.10-r1.ebuild
  Log:
  Fix temp file usage to not rely on pids (fixes running in pid namespaces).  Fix disk usage checks #456178 by Richard Yao.  Always use /usr/lib/ccache/bin/ #509956 by Michał Górny.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.141                dev-util/ccache/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ccache/ChangeLog?rev=1.141&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ccache/ChangeLog?rev=1.141&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ccache/ChangeLog?r1=1.140&r2=1.141

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/ccache/ChangeLog,v
retrieving revision 1.140
retrieving revision 1.141
diff -u -r1.140 -r1.141
--- ChangeLog	1 Nov 2014 07:54:34 -0000	1.140
+++ ChangeLog	1 Nov 2014 08:11:46 -0000	1.141
@@ -1,6 +1,15 @@
 # ChangeLog for dev-util/ccache
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/ccache/ChangeLog,v 1.140 2014/11/01 07:54:34 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/ccache/ChangeLog,v 1.141 2014/11/01 08:11:46 vapier Exp $
+
+*ccache-3.1.10-r1 (01 Nov 2014)
+
+  01 Nov 2014; Mike Frysinger <vapier@g.o> +ccache-3.1.10-r1.ebuild,
+  +files/ccache-3.1.10-real-temp-files.patch,
+  +files/ccache-3.1.10-size-on-disk.patch:
+  Fix temp file usage to not rely on pids (fixes running in pid namespaces).
+  Fix disk usage checks #456178 by Richard Yao.  Always use /usr/lib/ccache/bin/
+  #509956 by Michał Górny.
 
   01 Nov 2014; Mike Frysinger <vapier@g.o> files/ccache-config:
   Trim empty ccache dirs automatically #517242 by Arfrever Frehtes Taifersar



1.1                  dev-util/ccache/ccache-3.1.10-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ccache/ccache-3.1.10-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ccache/ccache-3.1.10-r1.ebuild?rev=1.1&content-type=text/plain

Index: ccache-3.1.10-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/ccache/ccache-3.1.10-r1.ebuild,v 1.1 2014/11/01 08:11:46 vapier Exp $

EAPI="4"

inherit eutils readme.gentoo

DESCRIPTION="fast compiler cache"
HOMEPAGE="http://ccache.samba.org/"
SRC_URI="http://samba.org/ftp/ccache/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE=""

RDEPEND="sys-libs/zlib"
DEPEND="${RDEPEND}
	app-arch/xz-utils"

src_prepare() {
	# make sure we always use system zlib
	rm -rf zlib
	epatch "${FILESDIR}"/${PN}-3.1.7-no-perl.patch #421609
	epatch "${FILESDIR}"/${PN}-3.1.10-size-on-disk.patch #456178
	epatch "${FILESDIR}"/${PN}-3.1.10-real-temp-files.patch
	sed \
		-e "/^EPREFIX=/s:'':'${EPREFIX}':" \
		"${FILESDIR}"/ccache-config-2 > ccache-config || die
}

src_install() {
	default
	dodoc AUTHORS.txt MANUAL.txt NEWS.txt README.txt

	dobin ccache-config

	DOC_CONTENTS="
To use ccache with **non-Portage** C compiling, add
${EPREFIX}/usr/lib/ccache/bin to the beginning of your path, before ${EPREFIX}usr/bin.
Portage 2.0.46-r11+ will automatically take advantage of ccache with
no additional steps.  If this is your first install of ccache, type
something like this to set a maximum cache size of 2GB:\\n
# ccache -M 2G\\n
If you are upgrading from an older version than 3.x you should clear all of your caches like so:\\n
# CCACHE_DIR='${CCACHE_DIR:-${PORTAGE_TMPDIR}/ccache}' ccache -C\\n
ccache now supports sys-devel/clang and dev-lang/icc, too!"

	readme.gentoo_create_doc
}

pkg_prerm() {
	if [[ -z ${REPLACED_BY_VERSION} ]] ; then
		"${EROOT}"/usr/bin/ccache-config --remove-links
		"${EROOT}"/usr/bin/ccache-config --remove-links ${CHOST}
	fi
}

pkg_postinst() {
	"${EROOT}"/usr/bin/ccache-config --install-links
	"${EROOT}"/usr/bin/ccache-config --install-links ${CHOST}

	# nuke broken symlinks from previous versions that shouldn't exist
	rm -f "${EROOT}"/usr/lib/ccache/bin/${CHOST}-cc
	rm -rf "${EROOT}"/usr/lib/ccache.backup

	readme.gentoo_print_elog
}