[gentoo-commits] repo/gentoo:master commit in: media-sound/moc/

[Tim Harder]

commit:     28d31edea8bd3f083f7b461ad1dee2728f30cbd4
Author:     Tim Harder <radhermit <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 28 02:18:21 2016 +0000
Commit:     Tim Harder <radhermit <AT> gentoo <DOT> org>
CommitDate: Sun Aug 28 02:21:01 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=28d31ede

media-sound/moc: version bumps to 2.5.1 and 2.6.0_alpha2

 media-sound/moc/Manifest              |  2 +
 media-sound/moc/moc-2.5.1.ebuild      | 81 +++++++++++++++++++++++++++++
 media-sound/moc/moc-2.6_alpha2.ebuild | 95 +++++++++++++++++++++++++++++++++++
 3 files changed, 178 insertions(+)

diff --git a/media-sound/moc/Manifest b/media-sound/moc/Manifest
index d5fdb59..d0a79e9 100644
--- a/media-sound/moc/Manifest
+++ b/media-sound/moc/Manifest
@@ -1,2 +1,4 @@
 DIST moc-2.5.0.tar.bz2 594532 SHA256 d29ea52240af76c4aa56fa293553da9d66675823e689249cee5f8a60657a6091 SHA512 ca6cfd4d1d13030bd561df8ab671399a17dfb675c360ecc95a2491c6a85764d0f72259ac33665405b197f370f4fd7ef59d9a485706f8a882bff30d0fafcf252c WHIRLPOOL 770d4024451c9f153fe16b60819392f677171c1ba08c8d95d9dfd5e1be1a19bfd5a7d9f771aa4ded8c40c0f042865f6e693727fce261464261d4311860fcff58
+DIST moc-2.5.1.tar.bz2 580329 SHA256 1b419c75a92a85ff4ee7670c65d660c86fef32032c65e89e868b988f80fac4f2 SHA512 9e22ce72a96cb6e5e948af509c8b7528155fe50e8b5130d78363b6cd57f731f8847bd770cd2c2363a7b9ed70a16b55c7fc1672b2b981ae207c1abd35c2acc301 WHIRLPOOL e34d39824d69d11297fbe0b8e28279246dd5f90706af3b95840b5541c3d747544ffbffd280835d4e7acc849390c5c7becfef49784c389e96ae9d53cb3c87d541
 DIST moc-2.6-alpha1.tar.xz 491660 SHA256 0b0a3515c65b4c47a250e350c663535778239352db859921f5d564ed727a0bbc SHA512 9de2e17e2d7441bb5ae2fa33884d4f569a91e987db39d2b331e8c28ddf0ecca1bdbd6079bebc1770c20d7f062b33069dd8b4a8184a309bf831538cb36f69ed3a WHIRLPOOL 86adcff80f4597e68bcf22ecf21f9eba913e257f8c7cf63d934e3874ea8fd59169652e4571b6f2bb1e54cdce0de6cb3027c494b29c9ae179910366b11b3786f9
+DIST moc-2.6-alpha2.tar.xz 498728 SHA256 0a3a4fb11227ec58025f7177a3212aca9c9955226a2983939e8db662af13434b SHA512 37d83f46e32d3253e896860ea573a021435561d5814d32b22ffc74e6f7d68de165f32420a7e10c679f5074a8717c104ddb437283462f993cb3dcaefd3cbb6d5f WHIRLPOOL cca1b37d5ba54009ce4b2c48d1ea400f41cab48efa26883099c63271410626c8e6773149e2c4a423cea2cd3286f0b6a806df074272a82a41055a10b7a9e5fe37

diff --git a/media-sound/moc/moc-2.5.1.ebuild b/media-sound/moc/moc-2.5.1.ebuild
new file mode 100644
index 00000000..30406ed
--- /dev/null
+++ b/media-sound/moc/moc-2.5.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MY_P=${P/_/-}
+DESCRIPTION="Music On Console - ncurses interface for playing audio files"
+HOMEPAGE="http://moc.daper.net"
+SRC_URI="http://ftp.daper.net/pub/soft/moc/stable/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="aac alsa +cache curl debug ffmpeg flac jack libsamplerate mad +magic modplug musepack
+	oss sid sndfile speex timidity tremor +unicode vorbis wavpack"
+
+RDEPEND=">=dev-libs/libltdl-2:0
+	sys-libs/ncurses:0=[unicode?]
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	cache? ( >=sys-libs/db-4:= )
+	curl? ( net-misc/curl )
+	ffmpeg? ( virtual/ffmpeg )
+	flac? ( media-libs/flac )
+	jack? ( media-sound/jack-audio-connection-kit )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad sys-libs/zlib media-libs/libid3tag )
+	magic? ( sys-apps/file )
+	modplug? ( media-libs/libmodplug )
+	musepack? ( media-sound/musepack-tools media-libs/taglib )
+	sid? ( >=media-libs/libsidplay-2 )
+	sndfile? ( media-libs/libsndfile )
+	speex? ( media-libs/speex )
+	timidity? ( media-libs/libtimidity media-sound/timidity++ )
+	vorbis? (
+		media-libs/libogg
+		tremor? ( media-libs/tremor )
+		!tremor? ( media-libs/libvorbis )
+	)
+	wavpack? ( media-sound/wavpack )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	local myconf=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable debug)
+		$(use_enable cache)
+		$(use_with oss)
+		$(use_with alsa)
+		$(use_with jack)
+		$(use_with magic)
+		$(use_with unicode ncursesw)
+		$(use_with libsamplerate samplerate)
+		$(use_with aac)
+		$(use_with ffmpeg)
+		$(use_with flac)
+		$(use_with modplug)
+		$(use_with mad mp3)
+		--without-rcc
+		$(use_with musepack)
+		$(use_with sid sidplay2)
+		$(use_with sndfile)
+		$(use_with speex)
+		$(use_with timidity)
+		$(use_with vorbis vorbis $(usex tremor tremor ""))
+		$(use_with wavpack)
+		$(use_with curl)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}

diff --git a/media-sound/moc/moc-2.6_alpha2.ebuild b/media-sound/moc/moc-2.6_alpha2.ebuild
new file mode 100644
index 00000000..ca23495
--- /dev/null
+++ b/media-sound/moc/moc-2.6_alpha2.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MY_P=${PN}-${PV/_/-}
+DESCRIPTION="Music On Console - ncurses interface for playing audio files"
+HOMEPAGE="http://moc.daper.net"
+SRC_URI="http://ftp.daper.net/pub/soft/moc/unstable/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+IUSE="aac alsa +cache curl debug ffmpeg flac jack libsamplerate mad +magic modplug musepack
+	oss sid sndfile speex timidity tremor +unicode vorbis wavpack"
+
+RDEPEND="
+	>=dev-libs/libltdl-2:0
+	dev-libs/popt
+	sys-libs/ncurses:0=[unicode?]
+	aac? ( media-libs/faad2 )
+	alsa? ( >=media-libs/alsa-lib-1.0.11 )
+	cache? ( >=sys-libs/db-4.1:= )
+	curl? ( >=net-misc/curl-7.15.1 )
+	ffmpeg? ( virtual/ffmpeg )
+	flac? ( >=media-libs/flac-1.1.3 )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.4 )
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.0 )
+	mad? (
+		media-libs/libmad
+		sys-libs/zlib
+		media-libs/libid3tag
+	)
+	magic? ( sys-apps/file )
+	modplug? ( >=media-libs/libmodplug-0.7 )
+	musepack? (
+		media-sound/musepack-tools
+		media-libs/taglib
+	)
+	sid? ( >=media-libs/libsidplay-2.1.1 )
+	sndfile? ( >=media-libs/libsndfile-1.0.0 )
+	speex? ( >=media-libs/speex-1.0.0 )
+	timidity? (
+		>=media-libs/libtimidity-0.1.0
+		media-sound/timidity++
+	)
+	vorbis? (
+		>=media-libs/libogg-1.0
+		tremor? ( media-libs/tremor )
+		!tremor? ( >=media-libs/libvorbis-1.0 )
+	)
+	wavpack? ( >=media-sound/wavpack-4.31 )
+"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	local myconf=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		--without-rcc
+		$(use_enable debug)
+		$(use_enable cache)
+		$(use_with oss)
+		$(use_with alsa)
+		$(use_with jack)
+		$(use_with magic)
+		$(use_with unicode ncursesw)
+		$(use_with libsamplerate samplerate)
+		$(use_with aac)
+		$(use_with ffmpeg)
+		$(use_with flac)
+		$(use_with modplug)
+		$(use_with mad mp3)
+		$(use_with musepack)
+		$(use_with sid sidplay2)
+		$(use_with sndfile)
+		$(use_with speex)
+		$(use_with timidity)
+		$(use_with vorbis vorbis $(usex tremor tremor ""))
+		$(use_with wavpack)
+		$(use_with curl)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}